All Functions

JMP Version Added: 16

s = Format( Today(), "Format Pattern", "<YYYY></><MM></><DD> <hh24><:><mm>" );
x = Informat( "2020/02/10 14:54", "Format Pattern", "<YYYY></><MM></><DD> <hh24><:><mm>" );
Show( s, x );
                                                /*
Field Descriptors

Dates
(cannot be used with Duration field descriptors)
================================================================================
<YYYY>        Four-digit year. (Accepts 1-4 digits on input.)
<YY>          Two-digit year
<yyyy>        Four digit ISO year; corresponds to ISO weeks. (Accepts 1-4 digits
              on input.)
<yy>          Two digit ISO year; corresponds to ISO weeks.
<YYYY.>       Year with fractional year. Completely describes the date and time.
<M>           Month number (1..12)
<MM>          Month number, zero-padded (01..12)
<Month>       Long month name
<Mmm>         Abbreviated month name
<MMM>         "In-line" month name. Always three letters.
<WW1>         Two digit week number, zero-padded. Week 2 begins on first Sunday
              of year. Week 1 is partial week before first Sunday. (01..54)
<WW2>         Two digit week number, zero-padded. Week 1 begins on first Sunday
              of year. Week 0 is partial week before first Sunday. (00..53)
<ww>          Two digit ISO week number, zero-padded. Weeks begin on Monday.
              Week 1 is first week in that year with 4 or more days. There are
              no partial weeks, instead the first or last week can extend into
              the previous or next year, respectively. (01..53)
<D>           Day of the month (1..31)
<DD>          Day of the month, zero-padded (01..31)
<Q>           Quarter of the year (1..4)
<Q#>          "Q" followed by quarter of the year (1..4)
<DayOfWeek>   Name of the day of the week
<DW>          Day of week as a number. 1 = Sunday, 7 = Saturday
<dw>          Day of week as a number. 1 = Monday, 7 = Sunday
</>           The locale date separator. (Accepts most common separators on
              input.)
<->           The ISO date separator '-'. (Accepts most common separators on
              input.)
</?>          Optional date separator on the date input. The separator is never
              written on output.
<'T'>         The 'T' in ISO dates

Times
(some can be used with Duration field descriptors)
================================================================================
<hh>          Hour formatted according to the current locale. If a <ampm>
              descriptor is present, will use a 12 or 24 hour clock depending on
              locale. If a <AMPM> descriptor is present, will use a 12 hour
              clock. Otherwise, will use a 24 hour clock. (Cannot be used with
              duration field descriptors.)
<zhh>         Hour formatted according to the current locale and zero-padded. If
              a <ampm> descriptor is present, will use a 12 or 24 hour clock
              depending on locale. If a <AMPM> descriptor is present, will use a
              12 hour clock. Otherwise, will use a 24 hour clock. (Cannot be
              used with duration field descriptors.)
<hh24>        Hour in 24-hour format and zero-padded (00..23)
<mm>          Minute, zero-padded (00..59)
<ss>          Second, zero-padded (00..59)
<ampm>        AM/PM symbol for the current locale. (Cannot be used with duration
              field descriptors.)
<AMPM>        Locale-independent AM/PM symbol "AM" or "PM". (Cannot be used with
              duration field descriptors.)
<:>           The locale time separator.
<::>          The ISO time separator ':'. (Also accepts locale time separator on
              input.)
<:?>          Optional time separator on the date input. The separator is never
              written on output.

Durations
(cannot be used with Date field descriptors)
================================================================================
<Day>         Day count. Used as most significant field in durations. Cannot be
              used with any other "count".
<Hour>        Hour count. Used as most significant field in durations. Cannot be
              used with any other "count".
<Minute>      Minute count. Used as most significant field in durations. Cannot
              be used with any other "count".

Other
================================================================================
<<>           Replaced with a "<"
*/

Fourier Basis Coef

Syntax: coef = Fourier Basis Coef( x, Number Pairs, <Period = max(x)-min(x)+1> )

Description: Returns the matrix of Fourier Basis coefficients. Number Pairs is the number of sin() and cos() pairs for the basis. Optional parameter Period specifies the period for the trigonometric functions and defaults to max(x) - min(x) + 1.

JMP Version Added: 14

Fourier Basis Coef( [0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10] / 10, 2 );
Fourier Basis Coef( [0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10] / 10, 2, 2 );

Frechet Density

Syntax: y = Frechet Density( x, mu, sigma )

Description: Returns the density at x of a Fréchet distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = .5;
New Window( "Example: Frechet Density",
    y = Graph Box(
        Y Scale( 0, .06 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( Frechet Density( x, mu, sig ), x );
        Text( {0, .055}, "mu=", Round( mu, 2 ) );
        Text( {0, .045}, "sig=", Round( sig, 2 ) );
    ),
    H List Box( Slider Box( 0, 4, mu, y << reshow ), Text Box( "mu" ) ),
    H List Box( Slider Box( 0, 10, sig, y << reshow ), Text Box( "sig" ) ), 

);

Frechet Distribution

Syntax: p = Frechet Distribution( x, mu, sigma )

Description: Returns the probability at x of a Fréchet distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = .5;
New Window( "Example: Frechet Distribution",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( Frechet Distribution( x, mu, sig ), x );
        Text( {0.1, 0.9}, "mu=", Round( mu, 2 ) );
        Text( {0.1, 0.8}, "sig=", Round( sig, 2 ) );
    ),
    H List Box( Slider Box( 0, 4, mu, y << reshow ), Text Box( " mu" ) ),
    H List Box( Slider Box( 0, 10, sig, y << reshow ), Text Box( " sig" ) )
);

Frechet Quantile

Syntax: q = Frechet Quantile( p, mu, sigma )

Description: Returns the quantile at p of a Fréchet distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = .5;
qq = .5;
New Window( "Example: Frechet Quantile",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( Frechet Distribution( qq, mu, sig ), qq );
        Pen Color( "blue" );
        V Line( Frechet Quantile( qq, mu, sig ), 0, 1 );
        Text(
            {0.1, 0.9},
            " mu=",
            Round( mu, 2 ),
            " sig=",
            Round( sig, 2 ),
            " quantile=",
            Round( qq, 2 )
        );
    ),
    H List Box( Slider Box( 0, 4, mu, y << reshow ), Text Box( " mu" ) ),
    H List Box( Slider Box( 0, 10, sig, y << reshow ), Text Box( " sig" ) ),
    H List Box( Slider Box( 0.01, 0.99, qq, y << reshow ), Text Box( " quantile" ) )
);

Function

Syntax: y = Function( {arg1=val1, ...}, <{local1=val1, ...}>, expr )

Description: Defines a function with the specified arguments, default values, and optional local variables. Arguments with default values are optional on invocation of the function. If Return() is used within the function's script, the expression within is returned.

JMP Version Added: Before version 14

Example 1

exsqr = Function( {x}, x * x );
exsqr( 5 );

Example 2

// y is an optional argument
exmul = Function( {x, y = 3}, x * y );
a = exmul( 5 );
b = exmul( 5, 10 );
Show( a, b );

Example 3

posorneg = Function( {x},
    {},
    If(
        x > 0, Return( "positive" ),
        x == 0, Return( "zero" ),
        Return( "negative" )
    )
);
posorneg( -5.5 );

Future Value

Syntax: x = Future Value( rate, nper, pmt, <pv=0>, <type=0> )

Description: Returns the future value of an investment based on periodic, constant payments and a constant interest rate. The type argument is 0 for end-of-period payments and 1 for beginning-of-period payments. Equivalent to the FV function in Microsoft Excel.

JMP Version Added: Before version 14

Future Value( .03, 12, 100, 0, 1 );

G Inverse

Syntax: g = G Inverse( A )

Description: Returns the generalized (Moore-Penrose) matrix inverse.

JMP Version Added: Before version 14

Round( G Inverse( [11 22, 33 44] ), 2 );

Gamma

Syntax: y = Gamma( x, <limit> )

Description: Returns Gamma function of x, defined as the integral of z^(x-1)*exp(-z) dz from 0 to ∞. If limit is present, an incomplete Gamma is computed using that limit of integration.

JMP Version Added: Before version 14

Gamma( 5 );

Gamma Density

Syntax: y = Gamma Density( q, <alpha=1>, <scale=1>, <threshold=0> )

Description: Returns the density at q of a Gamma probability distribution, where the alpha shape parameter argument must be positive.

JMP Version Added: Before version 14

gdealpha = Log( 1.5 );
New Window( "Example: Gamma Density",
    gdey = Graph Box(
        Y Scale( 0, 0.5 ),
        X Scale( 0, 12 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Gamma Density( gdeq, Exp( gdealpha ) ), gdeq );
        Text( {9, 0.45}, "\!U03B1=", Round( Exp( gdealpha ), 2 ) );
    ),
    H List Box(
        Slider Box( Log( 0.1 ), Log( 12 ), gdealpha, gdey << reshow ),
        Text Box( " \!U03B1" )
    )
);

Gamma Distribution

Syntax: p = Gamma Distribution( q, <alpha=1>, <scale=1>, <threshold=0> )

Description: Returns the probability that a Gamma distributed random variable is less than q, where the alpha shape parameter argument must be positive. IGamma() is an alias name to Gamma Distribution(). The Gamma Distribution() function is equivalent to Gamma(alpha,q)/Gamma(alpha).

JMP Version Added: Before version 14

gdialpha = Log( 1.5 );
New Window( "Example: Gamma Distribution",
    gdiy = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0, 12 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Gamma Distribution( gdiq, Exp( gdialpha ) ), gdiq );
        Text( {1, 0.9}, "\!U03B1=", Round( Exp( gdialpha ), 2 ) );
    ),
    H List Box(
        Slider Box( Log( 0.1 ), Log( 12 ), gdialpha, gdiy << reshow ),
        Text Box( " \!U03B1" )
    )
);

Gamma Log CDistribution

Syntax: p = Gamma Log CDistribution( x, <alpha=1>, <scale=1>, <threshold=0> )

Description: Returns the log of 1 - Gamma distribution.

JMP Version Added: Before version 14

glcdialpha = Log( 1.5 );
New Window( "Example: Gamma Log CDistribution",
    glcdiy = Graph Box(
        Y Scale( -4, 0.05 ),
        X Scale( 0, 12 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Gamma Log CDistribution( glcdiq, Exp( glcdialpha ) ), glcdiq );
        Text( {1, -0.9}, "\!U03B1=", Round( Exp( glcdialpha ), 2 ) );
    ),
    H List Box(
        Slider Box( Log( 0.1 ), Log( 12 ), glcdialpha, glcdiy << reshow ),
        Text Box( " \!U03B1" )
    )
);

Gamma Log Density

Syntax: y = Gamma Log Density( x, <alpha=1>, <scale=1>, <threshold=0> )

Description: Returns the log of the Gamma probability density.

JMP Version Added: Before version 14

gldealpha = Log( 1.5 );
New Window( "Example: Gamma Log Density",
    gldey = Graph Box(
        Y Scale( -4, 0.05 ),
        X Scale( 0, 12 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Gamma Log Density( gldeq, Exp( gldealpha ) ), gldeq );
        Text( {9, -0.45}, "\!U03B1=", Round( Exp( gldealpha ), 2 ) );
    ),
    H List Box(
        Slider Box( Log( 0.1 ), Log( 12 ), gldealpha, gldey << reshow ),
        Text Box( " \!U03B1" )
    )
);

Gamma Log Distribution

Syntax: p = Gamma Log Distribution( x, <alpha=1>, <scale=1>, <threshold=0> )

Description: Returns the log of the Gamma distribution.

JMP Version Added: Before version 14

gldialpha = Log( 1.5 );
New Window( "Example: Gamma Log Distribution",
    gldiy = Graph Box(
        Y Scale( -4, 0.05 ),
        X Scale( 0, 12 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Gamma Log Distribution( gldiq, Exp( gldialpha ) ), gldiq );
        Text( {1, -0.9}, "\!U03B1=", Round( Exp( gldialpha ), 2 ) );
    ),
    H List Box(
        Slider Box( Log( 0.1 ), Log( 12 ), gldialpha, gldiy << reshow ),
        Text Box( " \!U03B1" )
    )
);

Gamma Poisson Distribution

Syntax: cumprob = Gamma Poisson Distribution( k, lambda, sigma )

Description: Returns the probability that a gamma Poisson distributed random variable is less than or equal to k, where lambda is the mean parameter, sigma is the overdispersion parameter, and k is the count of interest.

JMP Version Added: Before version 14

lambda = 20;
sigma = 2;
New Window( "Example: Gamma Poisson Distribution",
    ppy = Graph Box(
        Y Scale( 0, 1.01 ),
        X Scale( -1, 40 ),
        Pen Color( "red" ),
        Pen Size( 1 );
        For( k = 0, k <= 40, k++,
            H Line( k, k + 1, Gamma Poisson Distribution( k, lambda, sigma ) );
            V Line(
                k + 1,
                Gamma Poisson Distribution( k, lambda, sigma ),
                Gamma Poisson Distribution( k + 1, lambda, sigma )
            );
        );
        Text( {2, 0.95}, "\!U03BB=", Round( lambda, 2 ) );
        Text( {2, 0.87}, "\!U03C3=", Round( sigma, 2 ) );
    ),
    H List Box( Slider Box( 3, 40, lambda, ppy << reshow ), Text Box( " \!U03BB" ) ),
    H List Box( Slider Box( 1, 5, sigma, ppy << reshow ), Text Box( " \!U03C3" ) )
);

Gamma Poisson Probability

Syntax: prob = Gamma Poisson Probability( k, lambda, sigma )

Description: Returns the probability that a gamma Poisson distributed random variable is equal to k, where lambda is the mean parameter, sigma is the overdispersion parameter, and k is the count of interest.

JMP Version Added: Before version 14

lambda = 5;
sigma = 2;
New Window( "Poisson and Gamma Poisson",
    clty = Graph Box(
        Y Scale( 0, 0.3 ),
        X Scale( -1, 20.5 ),
        Pen Color( "red" ),
        Pen Size( 2 );
        For( x = 0, x <= 20, x++,
            Pen Color( "red" );
            V Line( x, 0, Poisson Probability( lambda, x ) );
            Pen Color( "blue" );
            V Line( x + 0.35, 0, Gamma Poisson Probability( x, lambda, sigma ) );
        );
        Text( {1, 0.25}, "\!U03BB=", Round( lambda, 8 ), " \!U03C3=", Round( sigma, 8 ) );
        Text( {0, 0.28}, "Red = Poisson, Blue = Gamma Poisson" );
    ),
    H List Box( Slider Box( 3, 10, lambda, clty << reshow ), Text Box( " \!U03BB" ) ),
    H List Box( Slider Box( 1, 5, sigma, clty << reshow ), Text Box( " \!U03C3" ) )
);

Gamma Poisson Quantile

Syntax: q = Gamma Poisson Quantile( lambda, sigma, cumprob )

Description: Returns the smallest integer quantile for which the cumulative probability of the Gamma Poisson( lambda, sigma ) distribution is larger than or equal to cumprob.

JMP Version Added: Before version 14

qexpl = 20;
qexps = 2;
qexpn = 40;
qexpq = 0.5;
New Window( "Example: Gamma Poisson Quantile",
    qexpy = Graph Box(
        Y Scale( 0, 1.05 ),
        X Scale( -1, 41 ),
        Pen Color( "red" ),
        Pen Size( 2 );
        For( qexpk = 0, qexpk < Round( qexpn ), qexpk++,
            H Line( qexpk, qexpk + 1, Gamma Poisson Distribution( qexpk, qexpl, qexps ) );
            V Line(
                qexpk + 1,
                Gamma Poisson Distribution( qexpk, qexpl, qexps ),
                Gamma Poisson Distribution( qexpk + 1, qexpl, qexps )
            );
        );
        Pen Color( "blue" );
        V Line( Gamma Poisson Quantile( qexpl, qexps, qexpq ), 0, 1 );
        Text( {1, 0.9}, " \!U03BB=", Round( qexpl, 2 ), " \!U03C3=", Round( qexps, 2 ) );
        Text(
            {1, 0.8},
            " q=",
            Round( qexpq, 2 ),
            " quantile=",
            Round( Gamma Poisson Quantile( qexpl, qexps, qexpq ) )
        );
    ),
    H List Box( Slider Box( 3, 40, qexpl, qexpy << reshow ), Text Box( " \!U03BB" ) ),
    H List Box( Slider Box( 1, 5, qexps, qexpy << reshow ), Text Box( " \!U03C3" ) ),
    H List Box( Slider Box( 0, 1, qexpq, qexpy << reshow ), Text Box( " q" ) )
);

Gamma Quantile

Syntax: q = Gamma Quantile( p, <alpha=1>, <scale=1>, <threshold=0> )

Description: Returns the quantile from a Gamma distribution, the value for which the probability is p that a random value would be lower.

JMP Version Added: Before version 14

Gamma Quantile( 0.75, 4 );

GenGamma Density

Syntax: y = GenGamma Density( x, mu, sigma, lambda )

Description: Returns the density at x of an extended generalized gamma probability distribution with parameters mu, sigma, and lambda.

JMP Version Added: Before version 14

mu = 0;
sigma = 1;
lambda = 1;
New Window( "Example: GenGamma Density",
    gdey = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -5, 10 ),
        XName( "y" ),
        Pen Color( "red" );
        Y Function( GenGamma Density( y, mu, sigma, lambda ), y );
        Text( {-4, 0.9}, "\!U03BC=", Round( mu, 4 ), " \!U03C3=", Round( sigma, 4 ) );
        Text( {-4, 0.8}, "\!U03BB=", Round( lambda, 4 ) );
    ),
    H List Box( Slider Box( -5, 5, mu, gdey << reshow ), Text Box( "\!U03BC" ) ),
    H List Box( Slider Box( 0, 4, sigma, gdey << reshow ), Text Box( "\!U03C3" ) ),
    H List Box( Slider Box( 0, 10, lambda, gdey << reshow ), Text Box( "\!U03BB" ) )
);

GenGamma Distribution

Syntax: p = GenGamma Distribution( x, mu, sigma, lambda )

Description: Returns the probability that an extended generalized gamma distributed random variable (with parameters mu, sigma, and lambda) is less than x.

JMP Version Added: Before version 14

mu = 0;
sigma = 1;
lambda = 1;
New Window( "Example: GenGamma Distribution",
    gdey = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -10, 20 ),
        XName( "y" ),
        Pen Color( "red" );
        Y Function( GenGamma Distribution( y, mu, sigma, lambda ), y );
        Text( {-9, 0.9}, "\!U03BC=", Round( mu, 4 ), " \!U03C3=", Round( sigma, 4 ) );
        Text( {-9, 0.8}, "\!U03BB=", Round( lambda, 4 ) );
    ),
    H List Box( Slider Box( -5, 5, mu, gdey << reshow ), Text Box( "\!U03BC" ) ),
    H List Box( Slider Box( 0, 4, sigma, gdey << reshow ), Text Box( "\!U03C3" ) ),
    H List Box( Slider Box( 0, 10, lambda, gdey << reshow ), Text Box( "\!U03BB" ) )
);

GenGamma Quantile

Syntax: q = GenGamma Quantile( p, mu, sigma, lambda )

Description: Returns the quantile from an extended generalized gamma distribution (with parameters mu, sigma, and lambda), the value for which the probability is p that a random value would be lower.

JMP Version Added: Before version 14

mu = 0;
sigma = 1;
lambda = 1;
p = 0.4;
New Window( "Example: GenGamma Quantile",
    gdey = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -10, 20 ),
        XName( "y" ),
        Pen Color( "red" );
        Y Function( GenGamma Distribution( x, mu, sigma, lambda ), x );
        Pen Color( "Blue" );
        V Line( GenGamma Quantile( p, mu, sigma, lambda ), 0, 1 );
        Text(
            {-9, 0.9},
            "\!U03BC=",
            Round( mu, 4 ),
            " \!U03C3=",
            Round( sigma, 4 ),
            " \!U03BB=",
            Round( lambda, 4 )
        );
        Text( {-9, 0.8}, "p=", Round( p, 3 ) );
        Text(
            {-9, 0.7},
            "quantile= ",
            Round( GenGamma Quantile( p, mu, sigma, lambda ), 2 )
        );
    ),
    H List Box( Slider Box( -2, 2, mu, gdey << reshow ), Text Box( "\!U03BC" ) ),
    H List Box( Slider Box( 0, 4, sigma, gdey << reshow ), Text Box( "\!U03C3" ) ),
    H List Box( Slider Box( 0, 10, lambda, gdey << reshow ), Text Box( "\!U03BB" ) ),
    H List Box( Slider Box( 0.01, 0.99, p, gdey << reshow ), Text Box( " p" ) )
);

Get Addin

Syntax: Get Addin( ID )

Description: Retrieves a registered add-in specified by its ID.

JMP Version Added: Before version 14

addin = Get Addin( "com.mycompany.myaddin" );

Get Addins

Syntax: Get Addins( )

Description: Returns a list of all registered add-ins.

JMP Version Added: Before version 14

addins = Get Addins();
addin ids = Get Addins() << id;
Show( addins, addin ids );

Get Addr Info

Syntax: Get Addr Info( string )

Description: Looks up the numeric address for a name. In most cases the name should be used for future IPV6 compatibility.

JMP Version Added: Before version 14

Get Addr Info( "www.jmp.com" )[3][4];

Get Class Names

Syntax: Get Class Names( < <class reference>, ... > )

Description: Returns a list of names of all currently defined classes.

JMP Version Added: 14

Define Class(
    "aa",
    {_init_ = Method( {} ), x = 1, m1 = Method( {a, b}, a * b )}
);
Define Class(
    "bb",
    {_init_ = Method( {} ), y = 1, m2 = Method( {a, b}, a / b )}
);
lcaa = New Object( aa() );
lcbb = New Object( bb() );
lcl = Get Class Names();
Show( lcl );
lcaa << Delete;
lcbb << Delete;
Delete Classes( "aa", "bb" );

Get Classes

Syntax: Get Classes( < <class reference>, ... > )

Description: Returns a list of references to all currently defined classes

JMP Version Added: Before version 14

Define Class(
    "aa",
    {_init_ = Method( {} ), x = 1, m1 = Method( {a, b}, a * b )}
);
Define Class(
    "bb",
    {_init_ = Method( {} ), y = 1, m2 = Method( {a, b}, a / b )}
);
lcaa = New Object( aa() );
lcbb = New Object( bb() );
lcl = Get Classes();
Show( lcl );
Clear Symbols( lcl );
lcaa << Delete;
lcbb << Delete;
Delete Classes( "aa", "bb" );

Get Clipboard

Syntax: Get Clipboard()

Description: Get the current contents of the clipboard

JMP Version Added: Before version 14

Get Clipboard();

Get Color Theme Detail

Syntax: script = Get Color Theme Detail(name)

Description: Returns the script for a given color theme name

JMP Version Added: Before version 14

Get Color Theme Detail( "JMP Default" );

Get Color Theme Names

Syntax: {list of names} = Get Color Theme Names(<kind>)

Description: Returns a list of color theme strings which match the optional parameter kind. kind is one of the following: "continuous", "categorical", "sequential", "diverging", "qualitative", or "chromatic".

JMP Version Added: Before version 14

Example 1

Get Color Theme Names();

Example 2

Get Color Theme Names( "sequential" );

Get Custom Functions

Syntax: Get Custom Functions(<{function 1 full name, function 2 full name, ...} | function full name>)

Description: Get a list of custom functions

JMP Version Added: 14

Example 1

Get Custom Functions();

Example 2

Get Custom Functions( {"custom:Add", "custom:Sub"} );

Get Data Table

Syntax: dt = Get Data Table( <Project(title|index|box|window)>, name|index )

Description: Returns a reference to the specified data table.

The search is limited to tables in the current project (or no project when not running the script in a project).

To specify a project, use the optional Project() argument with a title, index, display box, or window object. Use Project(0) to specify no project when running the script in a project.

JMP Version Added: 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
Open( "$SAMPLE_DATA/Cars.jmp" );
Get Data Table( 1 );

Get Data Table List

Syntax: tableList = Get Data Table List( <Project(title|index|box|window)> )

Description: Returns a list of all open data tables.

The list is limited to tables in the current project (or no project when not running the script in a project).

To specify a project, use the optional Project() argument with a title, index, display box, or window object. Use Project(0) to specify no project when running the script in a project.

JMP Version Added: 14

Example 1

Open( "$SAMPLE_DATA/Big Class.jmp" );
Open( "$SAMPLE_DATA/Cars.jmp" );
Get Data Table List();

Example 2

project = Open( "$SAMPLE_PROJECTS/Sports.jmpprj" );
Get Data Table List( Project( project ) );

Get Default Directory

Syntax: y = Get Default Directory()

Description: Returns the JMP default directory, which is used as a base for subsequent relative paths. This path is the directory containing the currently executing script if the script is saved.

JMP Version Added: Before version 14

Show( Get Default Directory() );
Set Default Directory( "$SAMPLE_DATA" );
Show( Get Default Directory() );

Get Environment Variable

Syntax: value = Get Environment Variable( string )

Description: Returns the value of the specified environment variable from the operating system.

NOTE: On the Macintosh operating system, the variable name is case-sensitive.

JMP Version Added: Before version 14

Get Environment Variable( "PATH" );

Get Excel Worksheets

Syntax: list = Get Excel Worksheets("filepath")

Description: Returns a list of worksheets within an Excel Workbook

JMP Version Added: Before version 14

sheetList = Get Excel Worksheets( "$SAMPLE_IMPORT_DATA\Team Results.xlsx" );
Show( sheetList );

Get Expr Location

Syntax: Get Expr Location(<expression>, [{"TokenStartLine"|"TokenStartCol"|"TokenStart"|"TokenLength"|"TreeStart"|"TreeEnd"|"TreeLength"}+]

Description: Retrieve the locations of the top token in a parsed expression. The default invocation returns {the source file, TokenStartLine, TokenStartCol, TokenLength}.

JMP Version Added: 17

Default output

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
e = Parse( ":height + 20" );
Get Expr Location( e );

Replace a substring

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
data = " :height + 20 ";
e = Parse( data );
positions = Get Expr Location( Arg( e, 2 ), {"TreeStart", "TreeLength"} );
Munger( data, positions[1], positions[2], "45" );

Select output

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
e = Parse( " :height + 20 " );
Get Expr Location( e, {"TreeStart", "TreeEnd"} );

Get File Search Path

Syntax: y = Get File Search Path()

Description: Returns the current list of directories to search for opening files.

JMP Version Added: Before version 14

Get File Search Path();

Get Locale Setting

Syntax: value = Get Locale Setting( settingName )

Description: Retrieves a locale setting such as decimal separator

JMP Version Added: 16

Get Locale Setting( "Decimal Separator" );

Get Log

Syntax: list = Get Log( <N> )

Description: Returns a list of lines from the log. If no argument is specified, all the lines from the log are returned. If the numeric argument N is positive, the first N lines from the log are returned. If N is negative, the last N lines from the log are returned. If N is zero, no lines are returned.

JMP Version Added: Before version 14

all contents = Get Log();
headcontents = Get Log( 10 );
tailcontents = Get Log( -5 );

Get Name Info

Syntax: Get Name Info( string )

Description: Looks up the name for a numeric address. In most cases the name should be used for future IPV6 compatibility.

JMP Version Added: Before version 14

Get Name Info( "149.173.5.120" )[3][4];

Get Namespace Names

Syntax: Get Namespace Names( < <namespace reference>, ... > )

Description: Returns a list of names of all currently defined namespaces.

JMP Version Added: 14

nsaa = New Namespace(
    "aa",
    {
        x = 1
    }
);
nsbb = New Namespace(
    "bb",
    {
        y = 1
    }
);
lns = Get Namespace Names();
Show( lns );
nsaa << Delete;
nsbb << Delete;

Get Namespaces

Syntax: Get Namespaces( < <namespace reference>, ... > )

Description: Returns a list of references to all currently defined namespaces

JMP Version Added: Before version 14

nsaa = New Namespace(
    "aa",
    {
        x = 1
    }
);
nsbb = New Namespace(
    "bb",
    {
        y = 1
    }
);
lns = Get Namespaces();
Show( lns );
Clear Symbols( lns );
nsaa << Delete;
nsbb << Delete;

Get Notebook List

Syntax: notebookList = Get Notebook List()

Description: Returns a list of all open notebooks.

JMP Version Added: 19

Get OAuth2 Grant Types

Syntax: Get OAuth2 Grant Types

Description: Gets the supported JMP OAuth2 grant types.

JMP Version Added: 15

/*
https://oauth.net/2/grant-types/
*/
grant_types = Get OAuth2 Grant Types();
Show( grant_types );

Get OpenID Connect Discovery

JMP Version Added: 15

url = "https://login.microsoftonline.com/common/v2.0/.well-known/openid-configuration";
aa = Get OpenID Connect Discovery( url );
Show( aa );

Get OpenIDC Discovery

JMP Version Added: 15

Get Path Variable

Syntax: value = Get Path Variable( name )

Description: Returns the value of a path variable, which is a name like SAMPLE_DATA that is substituted for when found in pathnames.

JMP Version Added: Before version 14

Example 1

Get Path Variable( "SAMPLE_DATA" );
/* try: SAMPLE_DATA, SAMPLE_IMPORT_DATA, SAMPLE_SCRIPTS
See full listing of Path Variables in the other example
See also Convert File Path() and Set Path Variable() */

Listing

// Run for a Path Variable listing
path vars = {"SAMPLE_DATA", "DESKTOP", "DOCUMENTS", "DOWNLOADS", "TEMP", "HOME",
"USER_APPDATA", "ALL_HOME", "BUILTIN_SCRIPTS", "SAMPLE_APPS", "SAMPLE_DASHBOARDS",
"SAMPLE_IMAGES", "SAMPLE_IMPORT_DATA", "SAMPLE_PROJECTS", "SAMPLE_SCRIPTS"};
path vars ||= Transform Each( {id}, Get Addins() << ID, Eval Insert( "ADDIN_HOME(^id^)" ) );
path vars = Filter Each( {var}, path vars, Directory Exists( Get Path Variable( var ) ) );

New Window( "Path Variables",
    <<Type( "Dialog" ),
    Outline Box( "Path Variables",
        H List Box(
            Button Box( "Open Paths",
                For Each( {row}, tbl << Get Selected Rows, {path},
                    path = tbl[String Col Box( 2 )] << Get( row );
                    Open( path );
                )
            ),
            Button Box( "Copy Paths",
                If( N Items( tbl << Get Selected Rows ),
                    Set Clipboard(
                        Concat Items(
                            Transform Each( {row}, tbl << Get Selected Rows, Output( "List" ),
                                tbl[String Col Box( 2 )] << Get( row )
                            ),
                            "\!N"
                        )
                    )
                )
            )
        ),
        window:tbl = Table Box(
            String Col Box( "Variable", path vars ),
            String Col Box( "Path",
                Transform Each( {var}, path vars, Get Path Variable( var ) )
            ),
            <<Set Selectable Rows
        )
    )
);

Get Platform Preference

Syntax: Get Platform Preferences( < platformName < ( optionName, ... ) > ... > )

Description: Gets platform preferences as specified.

JMP Version Added: Before version 14

Get Platform Preferences( Bivariate( Fit Line ), DOE );

Get Platform Preferences

Syntax: Get Platform Preferences( < platformName < ( optionName, ... ) > ... > )

Description: Gets platform preferences as specified.

JMP Version Added: Before version 14

Get Platform Preferences( Bivariate( Fit Line ), DOE );

Get Policies

Syntax: Get Policies( <Machine|User|Both> )

Description: Returns an associative array containing the current policy names and values.

JMP Version Added: 18

Get Policies();

Get Policy

Syntax: Get Policy( "PolicyName" )

JMP Version Added: 18

Get Preference

Syntax: Get Preferences( pref1, ... )

Description: Gets preferences as specified.

JMP Version Added: Before version 14

Get Preferences( Graph marker size );

Get Preferences

Syntax: Get Preferences( pref1, ... )

Description: Gets preferences as specified.

JMP Version Added: Before version 14

Get Preferences( Graph marker size );

Get Project

Syntax: project = Get Project( title|index|box|window )

Description: Returns a reference to a specific open project by title, index, or box.

JMP Version Added: Before version 14

Example 1

Open( "$SAMPLE_PROJECTS/Big Class.jmpprj" );
Open( "$SAMPLE_PROJECTS/Sports.jmpprj" );

Print( Get Project( 2 ) << Get Window Title() );

Example 2

Open( "$SAMPLE_PROJECTS/Big Class.jmpprj" );
Open( "$SAMPLE_PROJECTS/Sports.jmpprj" );

project = Get Project( "Big Class" );

Get Project List

Syntax: projectList = Get Project List()

Description: Returns a list of all open projects.

JMP Version Added: Before version 14

New Project();
Open( "$SAMPLE_PROJECTS/Big Class.jmpprj" );

Print( Get Project List() << Get Window Title() );

Get Punctuation Characters

Syntax: Get Punctuation Characters(<Exclude Chars(chars) | Include Chars(chars)>)

Description: Returns a string containing the punctuation characters that are typically used for delimiting words. These include ,:;.?!\/#@&~()[]<>"*`%$+=^|{} and some common Unicode punctuation.

JMP Version Added: 15

Example 1

Get Punctuation Characters();

Example 2

Get Punctuation Characters( Include Chars( "_" ) );

Example 3

Get Punctuation Characters( Exclude Chars( "$[]" ) );

Example 4

Collapse Whitespace(
    Substitute( "This...string..has..dots", Items( Get Punctuation Characters(), "" ), " " )
);

Get Session Script

Syntax: Get Session Script( win1, ... )

Description: Returns the session script for the specified windows. The session script is a JSL expression that will recreate the given windows, including data tables, script windows, journals, and reports. Reports created via JSL scripts have limited support, and will only attempt to recreate the display layout.

JMP Version Added: 17

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = dt << RunScript( "Bivariate" );
Get Session Script( Report( biv ) );

Get Whitespace Characters

Syntax: Get Whitespace Characters()

Description: Returns a string containing all of the whitespace characters that are typically used.

JMP Version Added: Before version 14

Get Whitespace Characters();

Get Window

Syntax: window = Get Window( <Project(title|index|box|window)>, <Type(string)>, title|index|box )

Description: Returns a reference to a specific open window by title, index, or box.

The search is limited to windows in the current project (or no project when not running the script in a project).

To specify a project, use the optional Project() argument with a title, index, display box, or window object. Use Project(0) to specify no project when running the script in a project.

Use the optional Type() argument with one of "Data Tables", "Journals", "Reports", or "Dialogs" to limit the search to windows of a particular type.

JMP Version Added: 14

Example 1

Open( "$SAMPLE_DATA\Big Class.jmp" );

window = Get Window( "Big Class" );

Example 2

project = Open( "$SAMPLE_PROJECTS\Big Class.jmpprj" );

window = Get Window( Project( project ), "Big Class" );

Get Window List

Syntax: windowList = Get Window List( <Project(title|index|box|window)>, <Type(string)> )

Description: Returns a list of all open windows.

The list is limited to windows in the current project (or no project when not running the script in a project).

To specify a project, use the optional Project() argument with a title, index, display box, or window object. Use Project(0) to specify no project when running the script in a project.

Use the optional Type() argument with one of "Data Tables", "Journals", "Reports", or "Dialogs" to limit the list to windows of a particular type.

JMP Version Added: 14

Example 1

Print( Get Window List() << Get Window Title() );

Example 2

project = Open( "$SAMPLE_PROJECTS\Big Class.jmpprj" );

Print( Get Window List( Project( project ) ) << Get Window Title() );

Example 3

project = Open( "$SAMPLE_PROJECTS\Big Class.jmpprj" );

Print( Get Window List( Project( project ), Type( "Data Tables" ) ) << Get Window Title() );

Global Box

Syntax: box = Global Box( name )

Description: Creates a display box showing the value of a global variable.

JMP Version Added: Before version 14

ex = .6;
New Window( "Example", Global Box( ex ) );

GLog Density

Syntax: y = GLog Density( q, mu, sigma, lambda )

Description: Returns the density at q of a generalized logarithm distribution with location mu, scale sigma, and shape lambda.

JMP Version Added: Before version 14

mu = 0;
sigma = 1;
lambda = 1;
New Window( "Example: GLog Density",
    gdey = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -10, 10 ),
        XName( "y" ),
        Pen Color( "red" );
        Y Function( GLog Density( y, mu, sigma, lambda ), y );
        Text( {-9, 0.9}, "\!U03BC=", Round( mu, 4 ), " \!U03C3=", Round( sigma, 4 ) );
        Text( {-9, 0.8}, "\!U03BB=", Round( lambda, 4 ) );
    ),
    H List Box( Slider Box( -5, 5, mu, gdey << reshow ), Text Box( " \!U03BC" ) ),
    H List Box( Slider Box( 0, 4, sigma, gdey << reshow ), Text Box( " \!U03C3" ) ),
    H List Box( Slider Box( 0, 10, lambda, gdey << reshow ), Text Box( " \!U03BB" ) )
);

GLog Distribution

Syntax: p = GLog Distribution( q, mu, sigma, lambda )

Description: Returns the probability that a generalized logarithm distributed random variable is less than q.

JMP Version Added: Before version 14

mu = 0;
sigma = 1;
lambda = 1;
New Window( "Example: Glog Distribution",
    gdey = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -20, 20 ),
        XName( "y" ),
        Pen Color( "red" );
        Y Function( GLog Distribution( y, mu, sigma, lambda ), y );
        Text( {-9, 0.9}, "\!U03BC=", Round( mu, 4 ), " \!U03C3=", Round( sigma, 4 ) );
        Text( {-9, 0.8}, "\!U03BB=", Round( lambda, 4 ) );
    ),
    H List Box( Slider Box( -5, 5, mu, gdey << reshow ), Text Box( " \!U03BC" ) ),
    H List Box( Slider Box( 0, 4, sigma, gdey << reshow ), Text Box( " \!U03C3" ) ),
    H List Box( Slider Box( 0, 10, lambda, gdey << reshow ), Text Box( " \!U03BB" ) )
);

GLog Quantile

Syntax: q = GLog Quantile( p, mu, sigma, lambda )

Description: Returns the quantile from a generalized logarithm distribution, the value for which the probability is p that a random value would be lower.

JMP Version Added: Before version 14

mu = 0;
sigma = 1;
lambda = 1;
p = 0.4;
New Window( "Example: GLog Quantile",
    gdey = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -20, 20 ),
        XName( "y" ),
        Pen Color( "red" );
        Y Function( GLog Distribution( x, mu, sigma, lambda ), x );
        Pen Color( "Blue" );
        V Line( GLog Quantile( p, mu, sigma, lambda ), 0, 1 );
        Text(
            {-9, 0.9},
            "\!U03BC=",
            Round( mu, 4 ),
            " \!U03C3=",
            Round( sigma, 4 ),
            " \!U03BB=",
            Round( lambda, 4 )
        );
        Text( {-9, 0.8}, "p=", Round( p, 3 ) );
        Text( {-9, 0.7}, "quantile= ", Round( GLog Quantile( p, mu, sigma, lambda ), 2 ) );
    ),
    H List Box( Slider Box( -2, 2, mu, gdey << reshow ), Text Box( " \!U03BC" ) ),
    H List Box( Slider Box( 0, 4, sigma, gdey << reshow ), Text Box( " \!U03C3" ) ),
    H List Box( Slider Box( 0, 10, lambda, gdey << reshow ), Text Box( " \!U03BB" ) ),
    H List Box( Slider Box( 0.01, 0.99, p, gdey << reshow ), Text Box( " p" ) )
);

Glue

Syntax: y = ( expr1; expr2; ... ); y = Glue( expr1, expr2, ... )

Description: Evaluates each argument and returns the last result.

JMP Version Added: Before version 14

ex1 = 1;
ex2 = 2;

Google Sheet Export

Syntax: Google Sheet Export(dt, Email(address), Spreadsheet(url|id) | New Spreadsheet(name), Sheet Name(name))

Description: Exports a Data Table to a new Google Spreadsheet or a new Sheet within an existing Google Spreadsheet.

JMP Version Added: 15

email = "youremail@gmail.com"; //Replace this with your email
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Google Sheet Export(
    dt,
    Email( email ),
    New Spreadsheet( "JSL Example" ),
    Sheet Name( "Example 1" )
);

Google Sheet Import

Syntax: Google Sheet Import(Email(address), Spreadsheet(url|id), <Sheets("sheetName1", ... "sheetNameN")>, <Sheet Settings( Has Column Headers(Boolean), Data Starts on Row(n), Cell Range(range), Import Cell Colors(Boolean), Supress Empty Columns(Boolean))>)

Description: Opens a Google Sheet file.

JMP Version Added: 15

email = "youremail@gmail.com"; //Replace this with your email
spreadsheet =
"https://docs.google.com/spreadsheets/d/1AqV2ZkzzMtFrk-devlFdQW2Sb09ipOQaCQ1p0iho-iE/"; 

Google Sheet Import(
    Email( email ),
    Spreadsheet( spreadsheet ),
    Sheets( "Sheet1", "Sheet2" ),
    Sheet Settings(
        Has Column Headers( 0 ),
        Data Starts on Row( 1 ),
        Cell Range( "A1:C2" ),
        Import Cell Colors( 0 ),
        Suppress Empty Columns( 1 )
    )
);

Gradient Function

Syntax: Gradient Function( zExpr, xName, yName, zLimits, zColor( color list or matrix ), < <<XGrid( min, max, incr )>, < <<YGrid( min, max, incr )>, < <<Transparency( t )> )

Description: Fills the graph with a gradient between two colors. The zExpr argument is a function in terms of the variables specified by xName and yName. The vector zLimits specifies the range of values for zExpr. The zColor argument is a vector or list that defines the two colors that are blended together to create the gradient. The Transparency is a single value applied to the entire grid.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Gradient Function(
            Log( a * a + b * b ),
            a,
            b,
            [2 10],
            Z Color( {"Green", "Orange"} )
        )
    )
);

Graph

Syntax: y = Graph Box( props, script )

Description: Returns a display box containing a graph with axes. Named property arguments can be title("title"), XScale(low,high), YScale(low,high), FrameSize(h,v), XName("x"), yName("y"), DoubleBuffer, and SuppressAxes.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Frame Size( 300, 300 ),
        Marker( Marker State( 3 ), [11 44 77], [75 25 50] );
        Pen Color( "Blue" );
        Line( [10 30 70], [88 22 44] );
    )
);

Graph 3D Box

Syntax: y = Graph 3D Box()

Description: (Experimental) Returns a display box with 3D content that can be used with other display boxes to create custom reports.

JMP Version Added: Before version 14

x3d = Graph 3D Box(
    framesize( 300, 300 ),
    Xname( "X Axis" ),
    Yname( "Y Axis" ),
    Zname( "Z Axis" )
);
New Window( "Graph3DBox Example", x3d );
x3d << addmarkers( /*x*/[20 20 20 20], /*y*/[20 20 20 20], /*z*/[10 20 30 40] );
x3d << AddVector(
    [60 60 60]/*from*/,
    [90 60 60, 60 90 60, 60 60 90]/*to*/,
    ShaftThickness( [.1] ),
    FromThickness( [.2] ),
    ToThickness( [.3] ),
    ShaftColor( [-255] ),
    FromColor( [-16711680] ),
    ToColor( [-65280] ),
    Facets( Round ),
    FromCap( Sphere ),
    toCap( Point )
);

Graph Box

Syntax: y = Graph Box( props, script )

Description: Returns a display box containing a graph with axes. Named property arguments can be title("title"), XScale(low,high), YScale(low,high), FrameSize(h,v), XName("x"), yName("y"), DoubleBuffer, and SuppressAxes.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Frame Size( 300, 300 ),
        Marker( Marker State( 3 ), [11 44 77], [75 25 50] );
        Pen Color( "Blue" );
        Line( [10 30 70], [88 22 44] );
    )
);

Greater

Syntax: z = x > y > ... ; z = Greater( x, y, ... )

Description: Returns 1 if each argument is greater than the next argument; returns 0 otherwise.

JMP Version Added: Before version 14

3 > 2 > 1;

Greater or Equal

Syntax: z = x >= y >= ... ; z = Greater or Equal( x, y, ... )

Description: Returns 1 if each argument is greater than or equal to the next argument; returns 0 otherwise.

JMP Version Added: Before version 14

3 >= 2 >= 2;

Gzip Compress

Syntax: blob = Gzip Compress( blob )

Description: Compresses a blob of data into a gzip blob.

JMP Version Added: 14

Gzip Compress(
    Char To Blob( "random data does not usually compress well and may get larger" )
);

Gzip Uncompress

Syntax: blob = Gzip Uncompress( blob )

Description: Uncompresses a blob of gzip data into a blob.

JMP Version Added: 14

Gzip Uncompress(/*typically this data might come from GzipCompress() but might also come from a .gz file using loadTextFile with the blob option*/
    Char To Blob(
        "~1F~8B~08~00~00~00~00~00~00~0A~0D~CA~C1~0D~00~21~08~04~C0V~B6~B5~CDA~FC~80~5C~00c~EC^~E7=~C9)~E1~106~21~A1~85~19~8DU~8Bf~07_~F8~9FZ~85~ADfx~13~CE~83~A1~0Dc~0E~CD~0B~94*~16~1E=~00~00~00",
        "ascii~hex"
    )
);

H Center Box

Syntax: y = H Center Box( <childbox> )

Description: Returns a display box with the childbox display box argument centered in the horizontal space defined by the maximum size of that child and all the other siblings of the center box.

JMP Version Added: Before version 14

New Window( "test",
    H List Box(
        V Center Box( Text Box( "V+V" ) ),
        V List Box(
            Text Box( "mmmmmmmmmmmmmmmmmmmmmmmmmmmmmm" ),
            H Center Box( Text Box( "H+H" ) ),
            Text Box( "mmmmmmmmmmmmmmmmmmmmmmmmmmmmmm" ),
            Text Box( "mmmmmmmmmmmmmmmmmmmmmmmmmmmmmm" ),
            Text Box( "mmmmmmmmmmmmmmmmmmmmmmmmmmmmmm" ),
            Text Box( "mmmmmmmmmmmmmmmmmmmmmmmmmmmmmm" )
        )
    )
);

H Direct Product

Syntax: y = H Direct Product( A, B )

Description: Returns the horizontal direct product, which is the direct product of each row of matrices A and B.

JMP Version Added: Before version 14

exA = [1 2, 3 4];
exB = [1 1 1, 2 2 2];
exProd = H Direct Product( exA, exB );
Show( exProd );

/* verify result */
Show( exProd[1, 1 :: 6] == Direct Product( exA[1, 1 :: 2], exB[1, 1 :: 3] ) );
Show( exProd[2, 1 :: 6] == Direct Product( exA[2, 1 :: 2], exB[2, 1 :: 3] ) );

H Line

Syntax: H Line( y ); H Line( x1, x2, y )

Description: Draws a horizontal line at y from x1 to x2 or through the entire frame.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Pen Size( 2 );
        H Line( 10, 50, 20 );
    )
);

H List Box

Syntax: y = H List Box( <Align( center|bottom )>, displayBox, ... )

Description: Returns a display box that arranges the display boxes provided by the arguments in a horizontal layout. The <<Hold message tells the sheet to own the report(s) that will be excerpted. The optional Align argument allows for bottom or center alignment of the contents inside the display box.

JMP Version Added: Before version 14

New Window( "Example",
    Outline Box( "Picker", H List Box( Text Box( "Label:" ), Text Edit Box( Char( 213 ) ) ) )
);

H Scroll Box

Syntax: y = H Scroll Box( <Size( x )>, displayBox )

Description: Returns a display box that positions a larger child box using a horizontal scroll bar.

JMP Version Added: Before version 14

New Window( "Example",
    Outline Box( "Picker",
        H Scroll Box(
            Size( 200 ),
            H List Box(
                H List Box( Text Box( "Label:" ), Text Edit Box( Char( 213 ) ) ),
                H List Box( Text Box( "Label:" ), Text Edit Box( Char( 213 ) ) ),
                H List Box( Text Box( "Label:" ), Text Edit Box( Char( 213 ) ) ),
                H List Box( Text Box( "Label:" ), Text Edit Box( Char( 213 ) ) ),
                H List Box( Text Box( "Label:" ), Text Edit Box( Char( 213 ) ) )
            ),
            <<Set Stretch( "Window", "Window" )
        )
    )
);

H Sheet Box

Syntax: y = H Sheet Box( <<Hold( rpt ), displayBox, ... )

Description: Returns a display box that arranges the display boxes provided by the arguments in a horizontal layout. The <<Hold message tells the sheet to own the report(s) that will be excerpted. The optional Align argument allows for right or center alignment of the contents inside the display box.

JMP Version Added: Before version 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "Example",
    V Sheet Box(
        <<Hold( Bivariate( Y( :weight ), X( :height ), Fit Line() ) ),
        <<Hold(
            Distribution(
                Automatic Recalc( 1 ),
                Continuous Distribution(
                    Column( :height ),
                    Horizontal Layout( 1 ),
                    Vertical( 0 ),
                    Outlier Box Plot( 0 )
                )
            )
        ),
        <<Hold( Treemap( Categories( :age ) ) ),
        <<Hold(
            Bubble Plot(
                X( :height ),
                Y( :weight ),
                Sizes( :age ),
                Coloring( :sex ),
                Circle Size( 6.226 ),
                All Labels( 0 )
            )
        ),
        H Sheet Box(
            Sheet Part( "weight by height", Excerpt Box( 1, {Picture Box( 1 )} ) ),
            Sheet Part( "height", Excerpt Box( 2, {Picture Box( 1 )} ) )
        ),
        H Sheet Box(
            Sheet Part( "", Excerpt Box( 3, {Picture Box( 1 )} ) ),
            Sheet Part( "height by weight", Excerpt Box( 4, {Picture Box( 1 )} ) )
        )
    )
);

H Size

Syntax: h = H Size()

Description: Returns the horizontal size of the graphics frame in pixels.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Pen Size( H Size() / 20 );
        Line( [10 30 90], [88 22 44] );
    )
);

H Splitter Box

Syntax: y = H Splitter Box( <Size(x,y)>, displayBox, ... )

Description: Returns a display box that arranges other display boxes horizontally, with interactive control of sizes. Child sizes are specified as a proportion of the width or height of the Splitter Box. The optional Size argument is only used for the top-most Splitter Box; lower level boxes are sized like any other child box.

JMP Version Added: Before version 14

New Window( "Splitter",
    V Splitter Box(
        Size( 800, 600 ),
        H Splitter Box( graph = Graph Box(), Script Box(), <<Sizes( {0.6, 0.4} ) ),
        H Splitter Box(
            pict = Picture Box( Open( "$SAMPLE_IMAGES/tile.jpg", jpg ) ),
            spacer = Spacer Box(),
            <<Sizes( {0.4, 0.6} )
        )
    )
);
graph[FrameBox( 1 )] << Set Stretch( "Window", "Window" );
pict << Set Min Size( 100, 100 );
pict << Set Max Size( 500, 500 );
pict << Set Stretch( "Window", "Window" );
spacer << Set Fill( 1 );
spacer << Color( "Red" );
spacer << Set Stretch( "Window", "Window" );

Hadamard

Syntax: y = Hadamard( n, <normalize = 0> )

Description: Creates a Hadamard matrix of order n.

JMP Version Added: 15

Show( Hadamard( 12 ), Hadamard( 12, 1 ) );

Handle

Syntax: Handle( xPos, yPos, dragScript, <mouseUpScript> )

Description: Draws a square marker at the coordinates specified by xPos and yPos and repeatedly evaluates the dragScript expression when the mouse is pressed over the marker. Before running the script, the globals x and y are set to the mouse value and are restored to their original values afterward. The mouseUpScript expression is run after the mouse button is released.

JMP Version Added: Before version 14

New Window( "Example",
    exx = 20;
    exy = 50;,
    Graph Box(
        Frame Size( 200, 200 ),
        Handle(
            exx,
            exy,
            exx = x;
            exy = y;
        );
        Circle( {0, 0}, Sqrt( exx * exx + exy * exy ) );
    )
);

Head

Syntax: y = Head( x )

Description: Returns the head of the evaluated expression, without its arguments.

JMP Version Added: Before version 14

Head( Expr( Sum( a, b, c ) ) );

Head Expr

Syntax: y = Head Expr( expr )

Description: Returns the head of the expression, without its arguments. This function is deprecated. Please use Head() instead.

JMP Version Added: Before version 14

Example 1

// See Example 2 for the deprecated Head Expr() equivalent
Head( Expr( Sum( a, b, c ) ) );

Example 2

// Deprecated
Head Expr( Sum( a, b, c ) );

Head Name

Syntax: y = Head Name( x )

Description: Returns the head of the evaluated expression as a string, without its arguments.

JMP Version Added: Before version 14

Head Name( Expr( Sum( a, b, c ) ) );

Head Name Expr

Syntax: y = Head Name Expr( expr )

Description: Returns the head of the expression as a string, without its arguments. This function is deprecated. Please use Head Name() instead.

JMP Version Added: Before version 14

Example 1

// See Example 2 for the deprecated Head Name Expr() equivalent
Head Name( Expr( Sum( a, b, c ) ) );

Example 2

// Deprecated
Head Name Expr( Sum( a, b, c ) );

Heat Color

Syntax: y = Heat Color( x ); y = Heat Color( x, < <<theme> )

Description: Returns a color corresponding to a value between 0 and 1. Default theme is "Blue to Gray to Red". Any theme supported by Cell Plot is supported here. Matrix arguments supported.

JMP Version Added: Before version 14

New Window( "Color Bar",
    Graph(
        For( z = 0, z < 1, z += .1,
            x = 10 + 80 * z;
            Fill Color( Heat Color( z, <<"Green to Black to Red" ) );
            Rect( x - 5, 45, x + 5, 55, 1 );
        )
    )
);

Hex

Syntax: h = Hex( value, <"integer">|<encoding="utf-8">|<Base(number)>,<Pad To(number)> )

Description: Returns the hexadecimal (or other base number system) text corresponding to the given value and encoding, which can be a number a string or a blob. If the value is a number, IEEE 754 64-bit encoding is used unless one of the optional arguments, integer or Base, is provided. If Base is specified, the function returns the text corresponding to the specified number in that base number system instead of hexadecimal. The base must be an integer value between 2 and 36 inclusive. Supported encodings include utf-8, utf-16le, utf-16be, us-ascii, iso-8859-1, ascii~hex, shift_jis and euc-jp.

JMP Version Added: Before version 14

Hex( 1024, "integer" ) || " " || Hex( "Café", "utf-16be" ) || " " ||
Hex( 11, Base( 2 ), Pad To( 8 ) );

Hex To Blob

Syntax: blob = Hex To Blob( hex string )

Description: Makes a BLOB (Binary Large OBject) from the given string of hexadecimal codes, which can also include spaces, commas, carriage returns, and line feeds.

JMP Version Added: Before version 14

Hex To Blob( "FF78CE" );

Hex To Char

Syntax: s = Hex To Char( hextext, <encoding="utf-8"> )

Description: Returns the text corresponding to the hexadecimal text, using the specified encoding. Supported encodings include utf-8, utf-16le, utf-16be, us-ascii, iso-8859-1, ascii~hex, shift_jis, and euc-jp.

JMP Version Added: Before version 14

Hex To Char( "436166C3A9" ) || Hex To Char( "00430061006600E9", "utf-16be" );

Hex To Number

Syntax: x = Hex To Number( hextext, <Base(number)> )

Description: Returns the number corresponding to the hexadecimal (or other base number system) text. 16 hex digits are converted as IEEE 754 64-bit floating point numbers; otherwise the input is treated as a hex integer. If Base is specified, the text is treated as a string representing the number in that base. Base must be an integer between 2 and 36 inclusive.

JMP Version Added: Before version 14

Hex To Number( "11110000", Base( 2 ) );

Hidden

Syntax: y = Hidden( <rs> ); Hidden( <Row State( <r> )> ) = y

Description: Returns the hidden component of the specified row state value, 0 or 1. If Hidden is used as an L-value, it changes the hidden state of the current (or rth) row in the current data table.

JMP Version Added: Before version 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
Row State( 3 ) = Hidden State( 1 );
Hidden( Row State( 3 ) );
Row() = 3;
Hidden();

Hidden State

Syntax: rs = Hidden State( x )

Description: Returns a row state value with the hidden component set to the specified value.

JMP Version Added: Before version 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
Row State( 3 ) = Hidden State( 1 );
Hidden( Row State( 3 ) );

Hier Box

Syntax: y = Hier Box( text, Hier Box( ... ), Hier Box( ... ), ... )

Description: Returns a display box for hierarchy trees. The text argument is the node's name and can be a Text Edit Box.

JMP Version Added: Before version 14

New Window( "Example",
    Hier Box(
        Text Edit Box( "Cause 1" ),
        Hier Box( Text Edit Box( "Subcause 1.1" ), <<direction( 1 ) ),
        Hier Box( Text Box( "Subcause 1.2" ) ),
        <<Change Type( Fishbone ),
        <<direction( 1 )
    )
);

Hier Clust

Syntax: {c1, c2, c3, c4, c5} = Hier Clust( x )

Description: Returns the clustering history for a hierarchical clustering using Ward's method (without standardizing data), where x is a data matrix.

JMP Version Added: Before version 14

exdt = Open( "$SAMPLE_DATA/Body Measurements.jmp" );
ex = exdt << get as matrix();
exhc = Hierarchical Cluster(
    Y( Eval( exdt << Get Column Names ) ),
    Method( Ward ),
    Standardize( 0 ),
    Dendrogram Scale( Even Spacing ),
    Number of Clusters( 3 )
);
Report( exhc )["Dendrogram"] << Close( 1 );
Report( exhc )["Clustering History"] << Close( 0 );
exhistory = Hier Clust( ex );
exhistory[3, 1];

Hist Seg

Syntax: b = Hist Seg([data], <[freq data]>,<[weight data]>, <vertical=0|1>, <Row States()>)

Description: Returns a hist seg

JMP Version Added: Before version 14

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
xx = Column( "height" ) << Get Values;
rows = N Row( xx );
New Window( "Hist Seg Example",
    g = Graph Box(
        Frame Size( 300, 120 ),
        X Scale( Min( xx ) - 5, Max( xx ) + 5 ),
        Y Scale( 0, .2 ),
        Hist Seg( xx, J( rows, 1 ), J( rows, 1 ), 1, Row States( dt ) )
    )
);

HLS Color

Syntax: y = HLS Color( h, l, s ); y = HLS Color( {h, l, s} )

Description: Returns a color number from the hue, lightness, and saturation components, all between 0 and 1.

JMP Version Added: Before version 14

New Window( "Color Wheel",
    Graph(
        frameSize( 200, 200 ),
        For( hue = 0, hue < 360, hue += 30,
            y = 50 - 40 * Cos( hue * 2 * Pi() / 360 );
            x = 50 + 40 * Sin( hue * 2 * Pi() / 360 );
            Fill Color( HLS Color( hue / 360, 0.5, 1 ) );
            Oval( x - 10, y - 10, x + 10, y + 10, 1 );
        )
    )
);

Host is

Syntax: y = Host is( "Mac"|"Windows"|"Bits32"|"Bits64"|"x86_64"|"arm64" )

Description: Returns 1 if the JMP application matches the argument; returns 0 otherwise. The arguments Windows or Mac test for the specified operating system, and the arguments Bits32 or Bits64 test for the specified 32-bit or 64-bit JMP application. Only one argument can be tested at a time.

JMP Version Added: Before version 14

If( Host is( "Mac" ),
    Show( "On Mac" ),
    Show( "Not on Mac" )
);
If( Host is( "Bits64" ),
    Show( "64 bit" )
);
If(
    Host is( "x86_64" ), Show( "On x86_64" ),
    Host is( "arm64" ), Show( "On arm64" )
);

Hough Line Transform

Syntax: accum = Hough Line Transform( matrix, <NAngle(number)> <NRadius(number)> )

Description: Returns the Hough transform for detecting lines in image data

JMP Version Added: Before version 14

Example 1

xx = .4;
yy = .4;
angleDegrees = (1 :: 180)`;
angle = Pi() * angleDegrees / (180);
New Window( "Hough Transform Demo 1",
    Border Box( Left( 20 ), Top( 20 ), Right( 15 ), Bottom( 15 ),
        V List Box(
            Text Box( "Click and drag the circle in a straight line." ),
            Graph Box(
                X Scale( -1, 1 ),
                Y Scale( -1, 1 ),
                Circle( {xx, yy}, .05 );
                Text( {xx + .1, yy + .1}, Char( xx, 4 ) || " " || Char( yy, 4 ) );
                Mousetrap(
                    xx = x;
                    yy = y;
                    gb << reshow;
                );
            ),
            Text Box( "For angle 1 to 180 , x*Cos(angle)+y*Sin(angle)" ),
            Text Box( "What position stays constant as you move?" ),
            gb = Graph Box(
                X Scale( 0, 180 ),
                XName( "Angle" ),
                Y Scale( -1.5, 1.5 ),
                YName( "Distance to Line" ),
                Line( angleDegrees, xx * Cos( angle ) + yy * Sin( angle ) )
            )
        )
    )
);

Example 2

nRow = 35;
nCol = 35;

// Make a wafer template missing outside a radius
waferTemplate = J( nRow, nCol, 0 );
If( 0,
    For( i = 1, i <= nRow, i++,
        For( j = 1, j <= nCol, j++,
            If( (i - nrow / 2) ^ 2 + (j - nCol / 2) ^ 2 > ((nRow + nCol) / 4) ^ 2,
                waferTemplate[i, j] = .
            )
        )
    )
);
wafer = waferTemplate;
wafer[5, 22] = 1;
lightGray = RGB Color( .9, .9, .9 );
showWafer = Expr(
    For( i = 1, i <= nRow, i++,
        For( j = 1, j <= nCol, j++,
            z = wafer[i, j];
            If( Is Missing( z ),
                Continue()
            );
            Fill Color( If( z == 0, lightGray, 3 ) );
            Rect( i - nrow / 2, j - nCol / 2, i - nrow / 2 - 1, j - nCol / 2 + 1, 1 );
        )
    )
);
showHough = Expr(
    accum = Hough Line Transform( wafer );
    maxAccum = Max( Max( accum ), 1 );
    accumHeat = Heat Color( accum / maxAccum );
    nr = N Row( accum );
    nc = N Col( accum );
    For( i = 1, i <= nr, i++,
        For( j = 1, j <= nc, j++,
            z = accumHeat[i, j];
            Fill Color( z );
            Rect( j - 1, nr - i, j, nr - i + 1, 1 );
        )
    );
    //Marginals
    radiusDensity = V Max( accum` );
    radiusScale = 3 * Max( radiusDensity ) / Mean( radiusDensity );
    radiusColor = Heat Color( radiusDensity / radiusScale );
    If( 1,
        angleDensity = V Max( accum );
        angleScale = 3 * Max( angleDensity ) / Mean( angleDensity );
        angleColor = Heat Color( angleDensity / angleScale );
    ,
        angle1 = angleDensity - Mean( angleDensity );
        angle1 = angle1 :* (angle1 > 0);
        angleColor = Heat Color( angle1 / Max( angle1 ) );
    );
    For( j = 1, j <= nc, j++,
        Fill Color( angleColor[j] );
        Rect( j - 1, -5, j, -8, 1 );
    );
    For( i = 1, i <= nr, i++,
        Fill Color( radiusColor[i] );
        Rect( 185, nr - i, 190, nr - i + 1, 1 );
    );
);
mouseAction = Expr(
    i = Floor( x + nrow / 2 + .5 );
    j = Floor( y + ncol / 2 + .5 );
    If( i > 0 & i <= nRow & j > 0 & j <= nCol,
        wafer[i, j]
        ++);
    bothBox << reshow;
);
New Window( "Hough Transform Demo 2",
    Border Box( Left( 15 ), Top( 15 ), Right( 10 ), Bottom( 10 ),
        bothBox = V List Box(
            Text Box( "Click to add points in the top frame along a slanted line." ),
            Text Box( "The Hough transform is shown below with marginal densities." ),
            Text Box( "" ),
            H List Box(
                Button Box( "Clear",
                    wafer = waferTemplate;
                    bothBox << Reshow;
                ),
                Button Box( "Add Random",
                    wafer = wafer | J( nRow, nCol, Random Uniform() < .05 );
                    bothBox << Reshow;
                )
            ),
            waferBox = Graph Box(
                X Scale( -18, 18 ),
                Y Scale( -18, 18 ),
                FrameSize( 300, 300 ),
                XName( "Angle" ),
                YName( "Radius" ),
                Mousetrap( mouseAction ),
                showWafer
            ),
            houghBox = Graph Box(
                X Scale( 0, 190 ),
                Y Scale( -10, 50 ),
                FrameSize( 500, 200 ),
                showHough
            )
        )
    )
);

Hour

Syntax: hr = Hour( datetime, <12> )

Description: Returns the hours part of a date-time value, in 12-hour mode (12, 1 - 11) or 24-hour mode (0 - 23).

JMP Version Added: Before version 14

Hour( Today() );

HP Time

Syntax: t = HP Time()

Description: Returns a High Precision time value in microseconds. Only useful relative to another HP Time() value. The time value represents the number of microseconds since the start of the JMP session.

JMP Version Added: Before version 14

bt = HP Time();
Open( "$SAMPLE_DATA/Big Class.jmp" );
et = HP Time();
it = et - bt;
Show( it );

Hue State

Syntax: rs = Hue State( x )

Description: Returns a row state value with the color hue component set to the specified value. Needs to be combined with a Shade State() value to produce a valid color.

JMP Version Added: Before version 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
Row State( 3 ) = Combine States( Hue State( 5 ), Shade State( 1 ) );

Hypergeometric Distribution

Syntax: cumprob = Hypergeometric Distribution( N, K, n, x, <r> )

Description: Returns the probability that a hypergeometrically distributed random variable is less than or equal to x, where N is the population size, K is the number of items in the category of interest, n is the sample size, x is the count of interest, and r is the optional odds ratio.

JMP Version Added: Before version 14

exhdK = 10;
exhdn = 10;
New Window( "Example: Hypergeometric Distribution",
    exy = Graph Box(
        Y Scale( 0, 1.05 ),
        X Scale( -1, 21 ),
        Pen Color( "red" ),
        Pen Size( 2 );
        For( exhdx = 0, exhdx < Round( exhdn ), exhdx++,
            H Line(
                exhdx,
                exhdx + 1,
                Hypergeometric Distribution( 20, Round( exhdK ), Round( exhdn ), exhdx )
            );
            V Line(
                exhdx + 1,
                Hypergeometric Distribution( 20, Round( exhdK ), Round( exhdn ), exhdx ),
                Hypergeometric Distribution( 20, Round( exhdK ), Round( exhdn ), exhdx + 1 )
            );
        );
        Text( {10, 0.17}, "N=", 20, " K=", Round( exhdK ), " n=", Round( exhdn ) );
    ),
    H List Box( Slider Box( 0, 20, exhdK, exy << reshow ), Text Box( " K" ) ),
    H List Box( Slider Box( 0, 20, exhdn, exy << reshow ), Text Box( " n" ) )
);

Hypergeometric Probability

Syntax: prob = Hypergeometric Probability( N, K, n, x, <r> )

Description: Returns the probability that a hypergeometrically distributed random variable is equal to x, where N is the population size, K is the number of items in the category of interest, n is the sample size, x is the count of interest, and r is the optional odds ratio.

JMP Version Added: Before version 14

exhdK = 10;
exhdn = 10;
New Window( "Example: Hypergeometric Probability",
    exhdy = Graph Box(
        Y Scale( 0, 1.05 ),
        X Scale( -1, 21 ),
        Pen Color( "red" ),
        Pen Size( 2 );
        For( exhdx = 0, exhdx <= Round( exhdn ), exhdx++,
            V Line(
                exhdx,
                0,
                Hypergeometric Probability( 20, Round( exhdK ), Round( exhdn ), exhdx )
            )
        );
        Text( {10, 0.17}, "N=", 20, " K=", Round( exhdK ), " n=", Round( exhdn ) );
    ),
    H List Box( Slider Box( 0, 20, exhdK, exhdy << reshow ), Text Box( " K" ) ),
    H List Box( Slider Box( 0, 20, exhdn, exhdy << reshow ), Text Box( " n" ) )
);

Icon Box

Syntax: Box = Icon Box( "Name" )

Description: Constructs a display box containing an icon, where the name argument can be a JMP icon name or a path to a an image.

JMP Version Added: Before version 14

Example 1

New Window( "Example",
    ex1 = Icon Box( "Popup" ),
    ex2 = Icon Box( "Locked" ),
    ex3 = Icon Box( "Labeled" ),
    ex4 = Icon Box( "Sub" ),
    ex5 = Icon Box( "Excluded" ),
    ex6 = Icon Box( "Hidden" ),
    ex7 = Icon Box( "Continuous" ),
    ex8 = Icon Box( "Nominal" ),
    ex9 = Icon Box( "Ordinal" )
);

Example 2

New Window( "Example with Path", ex = Icon Box( "$SAMPLE_IMAGES/pi.gif" ) );

Identity

Syntax: y = Identity( n )

Description: Creates an n-by-n identity matrix, with ones on diagonal, zeros elsewhere.

JMP Version Added: Before version 14

Identity( 2 );

If

Syntax: y = If( condition1, result1, <condition2, result2>, ..., <elseResult> )

Description: Evaluates the first of each pair of arguments and returns the evaluation of the result expression associated with the first condition argument that evaluates to a nonzero result. The condition arguments are evaluated in order. If all of the condition arguments evaluate to zero, the optional elseResult is evaluated and the result is returned. If no elseResult is specified, and none of the conditions are true, a missing value is returned. If all of the condition arguments evaluate to missing, a missing value is returned.

JMP Version Added: Before version 14

If( Random Uniform() < 0.5,
    "heads",
    "tails"
);

If Box

Syntax: box = If Box( 0|1, displayBoxArgs )

Description: Returns a display box that conditionally displays the specified display box arguments.

JMP Version Added: Before version 14

New Window( "Example",
    H List Box(
        englishBox = If Box( 1, Text Box( "Good day" ) ),
        frenchBox = If Box( 0, Text Box( "Bon Jour" ) )
    )
);
Wait( 5 );
englishBox << Set( 0 );
frenchBox << Set( 1 );

If Seg

Syntax: seg = If Seg(<state=0|1>)

Description: Returns a display seg that shows or hides display seg children.

JMP Version Added: Before version 14

lines = [30 20 80 70, 10 90 90 10, 40 20 60 30];
New Window( "Lines Seg Example",
    g = Graph Box( If Seg( true, <<append( Lines Seg( lines ) ) ) )
);

IfMax

Syntax: y = IfMax( expr1, result1, expr2, result2, ..., <allMissingResult> )

Description: Evaluates the first of each pair of arguments, and returns the evaluation of the result expression associated with the maximum of the expressions. If there are ties, it returns the first maximum. If all expressions are missing, it returns Empty if an even number of arguments, or the last argument if odd. The test expressions must evaluate to numeric, but the result expressions can be anything.

JMP Version Added: Before version 14

TomScore = 45;
JonScore = 47;
TimScore = 46;
highestScorer = IfMax( TomScore, "Tom", JonScore, "Jon", TimScore, "Tim", "Noone" );

IfMin

Syntax: y = IfMin( expr1, result1, expr2, result2, ..., <allMissingResult> )

Description: Evaluates the first of each pair of arguments, and returns the evaluation of the result expression associated with the minimum of the expressions. If there are ties, it returns the first minimum. If all expressions are missing, it returns Empty if an even number of arguments, or the last argument if odd. The test expressions must evaluate to numeric, but the result expressions can be anything.

JMP Version Added: Before version 14

TomScore = 45;
JonScore = 47;
TimScore = 46;
lowestScorer = IfMin( TomScore, "Tom", JonScore, "Jon", TimScore, "Tim", "Noone" );

IfMZ

Syntax: y = IfMZ( condition1, result1, <condition2, result2>, ..., <elseResult> )

Description: Evaluates the first of each pair of arguments and returns the evaluation of the result expression associated with the first condition argument that evaluates to a nonzero result. The condition arguments are evaluated in order. If all condition arguments evaluate to zero or missing, the optional elseResult is evaluated and the result is returned. If no elseResult is specified, and none of the conditions are true, a missing value is returned. (IfMZ() is equivalent to If() where missing values for evaluated condition arguments are treated as zero.)

JMP Version Added: Before version 14

x = 1;
Show( IfMZ( x == 1, 10, x == 2, 20, 30 ) );
x = .;
Show( IfMZ( x == 1, 10, x == 2, 20, 30 ) );
x = .;
Show( If( x == 1, 10, x == 2, 20, 30 ) );

IGamma

Syntax: p = Gamma Distribution( q, <alpha=1>, <scale=1>, <threshold=0> )

Description: Returns the probability that a Gamma distributed random variable is less than q, where the alpha shape parameter argument must be positive. IGamma() is an alias name to Gamma Distribution(). The Gamma Distribution() function is equivalent to Gamma(alpha,q)/Gamma(alpha).

JMP Version Added: Before version 14

gdialpha = Log( 1.5 );
New Window( "Example: Gamma Distribution",
    gdiy = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0, 12 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Gamma Distribution( gdiq, Exp( gdialpha ) ), gdiq );
        Text( {1, 0.9}, "\!U03B1=", Round( Exp( gdialpha ), 2 ) );
    ),
    H List Box(
        Slider Box( Log( 0.1 ), Log( 12 ), gdialpha, gdiy << reshow ),
        Text Box( " \!U03B1" )
    )
);

In Days

Syntax: y = In Days( <x=1> )

Description: Converts x from a number of days to the equivalent number of seconds.

JMP Version Added: Before version 14

In Days( 1.5 );

In Hours

Syntax: y = In Hours( <x=1> )

Description: Converts x from a number of hours to the equivalent number of seconds.

JMP Version Added: Before version 14

In Hours( 0.5 );

In Minutes

Syntax: y = In Minutes( <x=1> )

Description: Converts x from a number of minutes to the equivalent number of seconds.

JMP Version Added: Before version 14

In Minutes( 1 );

In Path

Syntax: b = In Path( x, y, pathMatrix|pathText )

Description: Returns 1 if the point (x,y) is in the given path, otherwise returns 0.

JMP Version Added: Before version 14

New Window( "Example",
    window:p = "M10 10 L52 10 L37 52 Z M20 16 L40 20 L35 40 Z";
    Graph Box(
        Fill Color( "light blue" );
        Path( window:p, 1 );
        For Each( {x}, 5 :: 55 :: 5,
            For Each( {y}, 5 :: 55 :: 5,
                Marker(
                    Marker State( If( In Path( x, y, window:p ), "x", "circle" ) ),
                    {x, y}
                )
            )
        );
    );
);

In Polygon

Syntax: b = In Polygon( x, y, xMatrix, <yMatrix> )

Description: Returns 1 if the point (x,y) is in the polygon defined by the vector arguments, otherwise returns 0.

JMP Version Added: Before version 14

In Polygon( 11, 22, [10 20 30], [10 30 20] );

In Weeks

Syntax: y = In Weeks( <x=1> )

Description: Converts x from a number of weeks to the equivalent number of seconds.

JMP Version Added: Before version 14

In Weeks( 1 );

In Years

Syntax: y = In Years( <x=1> )

Description: Converts x from a number of years to the equivalent number of seconds.

JMP Version Added: Before version 14

In Years( 1 );

Include

Syntax: y = Include( filepath, < <<Parse Only>, < <<New Context>, < <<Names Default to Here> )

Description: Executes the JSL in the specified file. If Parse Only is specified, the script is parsed rather than executed. If New Context is specified, the included JSL is executed in its own unique namespace. If both the parent and included scripts use the global namespace, then specify both New Context and Names Default to Here to avoid name collisions.

JMP Version Added: Before version 14

Include( "$SAMPLE_SCRIPTS/chaosGame.jsl" );

Include File List

Syntax: y = Include File List()

Description: Returns a list of included files at the point of execution.

JMP Version Added: Before version 14

y = Include File List();

Index

Syntax: ii = n1::n2; ii = n1::n2::n3; ii = Index( n1, n2, <n3=1>)

Description: Returns a row matrix that contains the sequence of values from n1 to n2 by increments of n3.

JMP Version Added: Before version 14

1 :: 10;

Informat

Syntax: dt = In Format( s, formatString, < <<Use Locale(b=1)>, < <<Restrict > )dt = In Format( s, "Format Pattern", pattern, < <<Use Locale(b=1)> )

Description: Parses a string of a given format. If the format is a date-time format, the value is expressed as if surrounded by As Date(), returning the date in ddMonyyyy format. The optional <<Restrict used with the "Best" formatString only allows conversion using integer, decimal, and scientific formats.

JMP Version Added: Before version 14

Example 1

Informat( "07152000", "MMDDYYYY" );

Example 2

Informat( "07.15.2000", "Format Pattern", "<MM>.<DD>.<YYYY>" );

Example 3

Informat( "86.8287° W", "Longitude DDD" );

Example 4

Informat( "123.45%", "Percent" );

Example 5

Show(
    Informat( "1.23e4", "Best" ),
    Informat( "1.23e4", "Best", <<Restrict ),
    Informat( "1989-10-04", "Best" ),
    Informat( "1989-10-04", "Best", <<Restrict )
);

Inner Product BLAS

Syntax: y = Inner Product BLAS( A, B, ... )

JMP Version Added: 17

a = [1, 2, 3, -2, 0, -1, 0, 1, 1];
b = [4, 5, 6, -2, 0, -1, 0, 7, 2];
y = Inner Product BLAS( a, b );

Insert

Syntax: z = Insert( x, y, <i> )

Description: Returns a copy of list x with y inserted at the ith position or appended to the end if the optional i argument is not specified.

JMP Version Added: Before version 14

z = {11, 22, 33};
z = Insert( z, 99, 2 );

Insert Into

Syntax: Insert Into( x, y, <i> )

Description: Modifies list, associative array, or display box x with y inserted into the collection. Lists and display boxes support an optional i to specify the position, or the items will be appended if the position is not specified. Note that the x argument must be a variable.

JMP Version Added: Before version 14

Example 1

ex = {11, 22, 33};
Insert Into( ex, 99 );
ex;

Example 2

ex = ["a" => 10, "b" => 3, => 0];
Insert Into( ex, "c", 12 );
ex;

Example 3

New Window( "boxes", hlist = H List Box( Button Box( "a" ), Button Box( "b" ) ) );
Wait( 1 );
Insert Into( hlist, Button Box( "c" ) );

Integrate

Syntax: y = Integrate( expr, varname, lowLimit, upLimit, <<Tolerance(1e-10), <<StoreInfo(list), <<StartingValue(val) )

Description: Integrates an expression with respect to a scalar value, using adaptive quadrature method from Gander and Gautschi (2000). If the variable specified with varname has a value assigned to it or the <<StartingValue() optional argument specifies a starting value, that value is used as a typical value to improve the accuracy of the integral. To specify infinite ranges of integration, set lowLimit, upLimit, or both to missing. If <<StoreInfo() is specified, the argument of <<StoreInfo() will contain diagnostics of the numerical integration routine. If <<Tolerance() is specified, the argument of <<Tolerance() is used as the tolerance level in the autointegration function used to evaluate the integral. Smaller values result in longer run time but more precise results.

JMP Version Added: Before version 14

Example 1

Integrate( Exp( -x ), x, 0, . );

Example 2

x = 100;
Integrate( Normal Density( x - 100 ), x, ., . );

Interest Payment

Syntax: x = Interest Payment( rate, per, nper, pv, <fv=0>, <type=0> )

Description: Returns the interest payment for a given period for an investment based on periodic, constant payments and a constant interest rate. The type argument is 0 for end-of-period payments and 1 for beginning-of-period payments. Equivalent to the IPMT function in Microsoft Excel.

JMP Version Added: Before version 14

Payment( .05 / 12, 30 * 12, 100000 ) - Interest Payment( .05 / 12, 13, 30 * 12, 100000 )
-Principal Payment( .05 / 12, 13, 30 * 12, 100000 );

Interest Rate

Syntax: x = Interest Rate( nper, pmt, pv, <fv=0>, <type=0>, <guess=0.1> )

Description: Returns the interest rate per period of an annuity. The type argument is 0 for end-of-period payments and 1 for beginning-of-period payments. Equivalent to the RATE function in Microsoft Excel.

JMP Version Added: Before version 14

Interest Rate( 30 * 12, Payment( .05 / 12, 30 * 12, 100000 ), 100000 );

Internal Rate of Return

Syntax: x = Internal Rate of Return( values, <guess=0.1> );x = Internal Rate of Return( guess, value1, value2, <value3, ...> )

Description: Returns the internal rate of return for a series of cash flows represented by the numbers in the values argument. Equivalent to the IRR function in Microsoft Excel. The second prototype of the function accepts all scalar arguments.

JMP Version Added: Before version 14

Internal Rate of Return( [-10000, 1000, 900, 950] );
Internal Rate of Return( .01, -10000, 1000, 900, 950 );

Interpolate

Syntax: y = Interpolate(x|xmatrix|xlist, x1, y1, x2, y2);y = Interpolate(x | xmatrix | xlist, xmatrix, ymatrix);z = Interpolate({ x, y }, xvector, yvector, zmatrix)

Description: Finds the xi arguments that x is between and linearly interpolates the corresponding yi arguments. Note that the xi arguments must be specified in order.

JMP Version Added: Before version 14

Example 1

New Window( "Interpolate",
    window:x = (2 :: 9) * 10;
    window:y = 50 + Sin( (2 :: 9) ) * 40;
    Graph Box(
        Pen Color( "blue" );
        Marker( window:x, window:y );
        Y Function( Interpolate( a, window:x, window:y ), a );
    );
)
;

Example 2

Interpolate( 2.5, [1 2 3], [15, 20, 30] );

Example 3

Interpolate( {.5, .8}, [0 1], [0 1], [10 20, 12 18] );

Example 4

xd = Transpose( Index( 1, 6 * Pi(), 0.3 ) );
yd = Sin( xd );

xd2 = xd + 0.15;
yd2 = Interpolate( xd2, xd, yd );

New Window( "Interpolated values are blue",
    Graph Box(
        X Scale( 1, 6 * Pi() ),
        Y Scale( -1, 1 ),
        For( i = 0, i < N Rows( xd ), i++,
            Pen Color( "red" );
            Circle( {xd[i], yd[i]}, 0.01 );
            Pen Color( "blue" );
            Circle( {xd2[i], yd2[i]}, 0.01 );
        )
    )
);

Inv

Syntax: y = Inverse( x ); y = Inv( x )

Description: Returns the inverse of the x argument, which must be a square non-singular matrix.

JMP Version Added: Before version 14

Round( Inverse( [11 22, 33 44] ), 2 );

Inv Update

Syntax: y = Inv Update( S, X, <w=1> )

Description: Returns an updated inverse matrix, where the first argument S is a symmetric positive definite matrix with the same number of columns as X, the second argument X is a matrix that contains the rows to add or delete, and the third argument w determines whether to add or delete rows (use 1 to add rows and -1 to delete rows). This function evaluates as S-wSX*Inv(I+w*X*S*X)XS, where I is an identity matrix and Inv(A) means an inverse matrix of A.

JMP Version Added: Before version 14

/* Generate a design matrix */
exX = [1 0 4 2,
1 0 5 1,
1 0 2 4,
5 4 4 5,
0 1 4 3,
0 1 9 1,
0 1 2 4,
0 1 1 9,
0 1 5 2,
0 1 2 1,
0 1 4 5];
S = Inverse( exX` * exX );
Show( "----------Adding Rows (w=1) --------" );
X = [5 4 3 3, 4 3 2 1, 9 1 2 5];
w = 1;
y = Inv Update( S, X, w );
Show( "Result of Inv Update" );
Show( y );
Show( "Result of updating formula" );
Show( S - w * S * X` * Inv( Identity( N Row( X ) ) + w * X * S * X` ) * X * S );
Show( "Result of direct calculation" );
Show( Inverse( (exX |/ X)` * (exX |/ X) ) );
Show( "----------Deleting Rows (w=-1) --------" );
X = [0 1 5 2, 0 1 2 1, 0 1 4 5];
w = -1;
y = Inv Update( S, X, w );
Show( "Result of Inv Update" );
Show( y );
Show( "Result of updating formula" );
Show( S - w * S * X` * Inv( Identity( N Row( X ) ) + w * X * S * X` ) * X * S );
Show( "Result of direct calculation" );
p = N Row( exX ) - 3;
Show( Inverse( exX[Index( 1, p ), 0]` * exX[Index( 1, p ), 0] ) );

Inverse

Syntax: y = Inverse( x ); y = Inv( x )

Description: Returns the inverse of the x argument, which must be a square non-singular matrix.

JMP Version Added: Before version 14

Round( Inverse( [11 22, 33 44] ), 2 );

Invert Expr

Syntax: y = Invert Expr( expr, xname, yname )

Description: Inverts the expr expression argument, unfolding around the single occurrence of xname.

JMP Version Added: Before version 14

Invert Expr( Sqrt( Log( x ) ), x, y );

IRT Ability

Syntax: y = IRT Ability( Q1, ..., Qn, parmMatrix )

Description: Produces scores for the latent variable in an item response theory model with n binary items and a matrix of known parameters, specified by parmMatrix. The parameter matrix should contain as many rows as there are parameters in the model and as many columns as there are items in the analysis.

JMP Version Added: Before version 14

Example 1

dt = Open( "$SAMPLE_DATA/MathScienceTest.jmp" );
obj = dt << Item Analysis( Y( :Q1, :Q2, :Q3, :Q4, :Q5 ), Model( "Logistic 2PL" ) );
obj << Save Ability Formula;
Column( dt, N Cols( dt ) ) << Get Formula;

Example 2

dt = Open( "$SAMPLE_DATA/MathScienceTest.jmp" );
mth = (dt << get as matrix)[0, Index( 2, 6 )];
mthlst = {};
i = Floor( Random Uniform( 1, N Rows( mth ) ) );
mthlst[1] = mth[i, 1] |/ mth[i, 2] |/ mth[i, 3] |/ mth[i, 4] |/ mth[i, 5];
mthlst[2] = IRT Ability(
    mth[i, 1],
    mth[i, 2],
    mth[i, 3],
    mth[i, 4],
    mth[i, 5],
    [0.28 1.93 1.9 1.67 1, -0.06 -0.55 0.5 -1.89 0.04]
);
mthlst;

Is Alt Key

Syntax: y = Is Alt Key()

Description: Returns 1 if the Alt key is being pressed; returns 0 otherwise. Intended to be used in graphics callback scripts. On the Mac, Alt means Option key.

JMP Version Added: Before version 14

New Window( "Show me the key",
    Graph Box(
        Rect( 45, 55, 55, 45, 1 );
        If( Is Shift Key(),
            Text( {50, 60}, "Shift Key" )
        );
        If( Is Control Key(),
            Text( {60, 50}, "Control Key" )
        );
        If( Is Alt Key(),
            Text( {50, 35}, "Alt Key" )
        );
        Mousetrap( {} );
    )
);

Is Associative Array

Syntax: y = Is Associative Array( x )

Description: Returns 1 is the x argument is an associative array, otherwise returns 0.

JMP Version Added: Before version 14

Is Associative Array( [1 => 2] );

Is Class

Syntax: isns = Is Class( class reference )

Description: Returns 1 if the class argument is a class. Otherwise, a 0 is returned.

JMP Version Added: Before version 14

Define Class(
    "complex",
    real = 0;
    imag = 0;
    _init_ = Method( {a, b},
        real = a;
        imag = b;
    );
    Add = Method( {y},
        New Object( complex( real + y:real, imag + y:imag ) )
    );
    Sub = Method( {y},
        New Object( complex( real - y:real, imag - y:imag ) )
    );
    Mul = Method( {y},
        New Object( complex( real * y:real - imag * y:imag, imag * y:real + real * y:imag ) )
    );
    Div = Method( {y},
        t = New Object( complex( 0, 0 ) );
        mag2 = y:Magsq();
        t:real = real * y:real + imag * y:imag;
        t:imag = imag * y:real + real * y:imag;
        t:real = t:real / mag2;
        t:imag = t:imag / mag2;
        t;
    );
    Magsq = Method( {},
        real * real + imag * imag
    );
    Mag = Method( {},
        Sqrt( real * real + imag * imag )
    );
    _to string_ = Method( {},
        Char( real ) || " + " || Char( imag ) || "i"
    );
    _show_ = _to string_;
);
cl = New Object( complex( 1, 2 ) );
iscl = Is Class( cl );
Show( iscl );
cl << Delete;
Delete Classes( "complex" );

Is Command Key

Syntax: y = Is Command Key()

Description: Returns 1 if the Command key is being pressed; returns 0 otherwise. Intended to be used in graphics callback scripts.

JMP Version Added: Before version 14

New Window( "Show me the key",
    Graph Box(
        Rect( 45, 55, 55, 45, 1 );
        If( Is Shift Key(),
            Text( {50, 60}, "Shift Key" )
        );
        If( Is Command Key(),
            Text( {60, 50}, "Command Key" )
        );
        If( Is Alt Key(),
            Text( {50, 35}, "Alt Key" )
        );
        Mousetrap( {} );
    )
);

Is Context Key

Syntax: y = Is Context Key()

Description: Returns 1 if the Context key is being pressed; returns 0 otherwise. Intended to be used in graphics callback scripts.

JMP Version Added: Before version 14

New Window( "Show me the key",
    Graph Box(
        Rect( 45, 55, 55, 45, 1 );
        If( Is Shift Key(),
            Text( {50, 60}, "Shift Key" )
        );
        If( Is Context Key(),
            Text( {60, 50}, "Context Key" )
        );
        If( Is Alt Key(),
            Text( {50, 35}, "Alt Key" )
        );
        Mousetrap( {} );
    )
);

Is Control Key

Syntax: y = Is Control Key()

Description: Returns 1 if the Control key is being pressed; returns 0 otherwise. Intended to be used in graphics callback scripts. On the Mac, Control means Command key.

JMP Version Added: Before version 14

New Window( "Show me the key",
    Graph Box(
        Rect( 45, 55, 55, 45, 1 );
        If( Is Shift Key(),
            Text( {50, 60}, "Shift Key" )
        );
        If( Is Control Key(),
            Text( {60, 50}, "Control Key" )
        );
        If( Is Alt Key(),
            Text( {50, 35}, "Alt Key" )
        );
        Mousetrap( {} );
    )
);

Is Directory

Syntax: rc = Is Directory( path )

Description: Determine if the given path is a directory. Returns 0 when path is invalid or does not exist.

JMP Version Added: Before version 14

rc0 = Is Directory( "$SAMPLE_DATA" );
rc1 = Is Directory( "$SAMPLE_DATA/Big Class.jmp" );
Char( rc0 ) || " " || Char( rc1 );/* 1 0 */

Is Directory Writable

Syntax: rc = Is Directory Writable( path )

Description: Determine if the given directory path is writable. Returns 0 when path is invalid or does not exist.

JMP Version Added: Before version 14

Is Directory Writable( "$SAMPLE_DATA" );

Is Empty

Syntax: y = Is Empty( name )

Description: Returns 1 if the variable is undefined or holds the Empty() value.

JMP Version Added: Before version 14

Example 1

Is Empty( x );

Example 2

x = Empty();
Is Empty( x );

Example 3

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
Wait( 1 );
If( Is Empty( dt ),
    Print( "There is no open data table." ),
    Print( "This data table is open: " || (dt << Get Name()) )
);
Wait( 1 );
Close( DT, "nosave" );
Wait( 1 );
If( Is Empty( dt ),
    Print( "There is no open data table." ),
    Print( "This data table is open: " || (dt << Get Name()) )
);

Is Expr

Syntax: y = Is Expr( x )

Description: Returns 1 if the x argument is an expression, 0 otherwise.

JMP Version Added: Before version 14

Is Expr( Expr( x ) );

Is File

Syntax: rc = Is File( path )

Description: Determine if the given path is a file. Returns 0 when path is invalid or does not exist.

JMP Version Added: Before version 14

rc0 = Is File( "$SAMPLE_DATA" );
rc1 = Is File( "$SAMPLE_DATA/Big Class.jmp" );
Char( rc0 ) || " " || Char( rc1 );/* 0 1 */

Is File Writable

Syntax: rc = Is File Writable( path )

Description: Determine if the given file path is writable. Returns 0 when path is invalid or does not exist.

JMP Version Added: Before version 14

Is File Writable( "$SAMPLE_DATA/Big Class.jmp" );

Is JMP Live URL Enabled

Syntax: Is JMP Live URL Enabled(url)

Description: Determines if the specified URL can be used in this JMP session. URLs can be enabled and/or disabled using the jmpStartAdmin.jsl script. This does not determine if it is a valid URL, nor if the user is able to login. It only determines if the URL is blocked by JMP.

JMP Version Added: 15

url = "http://public.jmp.com";
Show( Is JMP Live URL Enabled( url ) );

Is Leap Year

Syntax: v = Is Leap Year(year)

Description: Return whether a given year is a leap year.

JMP Version Added: 15

v = Is Leap Year( 2016 );

Is List

Syntax: y = Is List( x )

Description: Returns 1 if the x argument is a list, 0 otherwise.

JMP Version Added: Before version 14

Is List( {1, 2, 3} );

Is Log Open

Syntax: Is Log Open()

Description: Return result to indicate whether the log window is open

JMP Version Added: Before version 14

Example 1

If( Is Log Open(),
    Close Log()
);

Example 2

If( !Is Log Open(),
    Open Log()
);

Is Matrix

Syntax: y = Is Matrix( x )

Description: Returns 1 if the argument is a matrix, 0 otherwise.

JMP Version Added: Before version 14

Is Matrix( [11 22 33] );

Is Missing

Syntax: y = Is Missing( x )

Description: Returns 1 if the x argument is a missing value; returns 0 otherwise.

JMP Version Added: Before version 14

Is Missing( . );

Is Name

Syntax: y = Is Name( x )

Description: Returns 1 if the x argument is a name, 0 otherwise.

JMP Version Added: Before version 14

Is Name( Name Expr( n ) );

Is Namespace

Syntax: isns = Is Namespace( namespace reference )

Description: Returns 1 if the namespace argument is a namespace; otherwise a 0 is returned.

JMP Version Added: Before version 14

ns = New Namespace(
    "complex",
    {
        make = Function( {a, b},
            Index( a, b, b - a )
        ),
        add = Function( {x, y}, x + y ),
        sub = Function( {x, y}, x - y ),
        mul = Function( {x, y},
            local:z = J( 1, 2 );
            local:z[1] = x[1] * y[1] - x[2] * y[2];
            local:z[2] = x[1] * y[2] + x[2] * y[1];
            local:z;
        ),
        div = Function( {x, y},
            local:z = J( 1, 2 );
            local:d = (y[1] ^ 2 + y[2] ^ 2);
            local:z[1] = (x[1] * y[1] + x[2] * y[2]) / local:d;
            local:z[2] = (x[2] * y[1] - x[1] * y[2]) / local:d;
            local:z;
        ),
        write = Function( {x},
            Write( x[1], " + ", x[2], "i\!n" )
        )
    }
);
isns = Is Namespace( ns );
Show( isns );
ns << Delete;

Is Number

Syntax: y = Is Number( x )

Description: Returns 1 if the x argument is a number, 0 otherwise.

JMP Version Added: Before version 14

Is Number( 213 );

Is Option Key

Syntax: y = Is Option Key()

Description: Returns 1 if the Option key is being pressed; returns 0 otherwise. Intended to be used in graphics callback scripts.

JMP Version Added: Before version 14

New Window( "Show me the key",
    Graph Box(
        Rect( 45, 55, 55, 45, 1 );
        If( Is Shift Key(),
            Text( {50, 60}, "Shift Key" )
        );
        If( Is Option Key(),
            Text( {60, 50}, "Option Key" )
        );
        If( Is Alt Key(),
            Text( {50, 35}, "Alt Key" )
        );
        Mousetrap( {} );
    )
);

Is Same Color

Syntax: x = Is Same Color( color1, color2, ... )

Description: Compares colors for equality.

JMP Version Added: 18

Example 1

Is Same Color( "black", 0 );

Example 2

Is Same Color( "red", "green", "blue" );

Example 3

Is Same Color( "red", To Color Space( "hls", "red" ) );

Example 4

Is Same Color( To Color Space( "LUV", "red" ), "red" );

Is Scriptable

Syntax: tf = Is Scriptable( x )

Description: Returns 1 if the x argument is a scriptable object, 0 otherwise.

JMP Version Added: Before version 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
Is Scriptable( Bivariate( Y( :weight ), X( :height ) ) );

Is Shift Key

Syntax: y = Is Shift Key()

Description: Returns 1 if the Shift key is being pressed; returns 0 otherwise. Intended to be used in graphics callback scripts.

JMP Version Added: Before version 14

New Window( "Show me the key",
    Graph Box(
        Rect( 45, 55, 55, 45, 1 );
        If( Is Shift Key(),
            Text( {50, 60}, "Shift Key" )
        );
        If( Is Control Key(),
            Text( {60, 50}, "Control Key" )
        );
        If( Is Alt Key(),
            Text( {50, 35}, "Alt Key" )
        );
        Mousetrap( {} );
    )
);

Is String

Syntax: y = Is String( x )

Description: Returns 1 if the x argument is a string, 0 otherwise.

JMP Version Added: Before version 14

Is String( "abc" );

ISO Year

Syntax: yr = ISO Year( datetime )

Description: Returns the ISO Year of a date-time value. ISO Years correspond to ISO Weeks; they begin on the Monday of the first week containing at least four days.

JMP Version Added: 16

ISO Year( Today() );

Item

Syntax: w = Item( n|[first last], s, <delim>, <Unmatched(result string)>, <Include Boundary Delimiters(0|1)>)

Description: Returns the nth item of the s argument, where items are the (possibly empty) sub-strings separated by exactly one of any of the characters specified in the delim argument. If delim is absent, the space character is used. If delim is the empty string, each character is treated as a separate item.

JMP Version Added: Before version 14

Example 1

Item( 5, "http://www.jmp.com", ":/." );

Example 2

Item( [2 -1], "This is a sentence" );

Example 3

Item( 4, "Apple+Banana Tree,,Pear,,Peach,,Grape", Get Punctuation Characters() );

Example 4

Item( 5, "a b c d", Unmatched( "None" ) );

Example 5

Item( 2, "abcd", "" );

Example 6

Item( 2, ",abcd", ",", Include Boundary Delimiters );

Items

Syntax: wl = Items(<[first last]>, s, <delim>, <Include Boundary Delimiters(0|1)>)

Description: Returns a list of (possibly empty) sub-strings separated by exactly one of any of the characters specified in the delim argument. If delim is absent, the space character is used. If delim is the empty string, each character is treated as a separate item.

JMP Version Added: 15

Example 1

Eval List( {Items( "http://www.jmp.com", ":/." ), Items( "hello", "" )} );

Example 2

Items( ",Apple,Banana Tree,Peach", Get Punctuation Characters() );

Example 3

Items(
    ",Apple,Banana Tree,Peach",
    Get Punctuation Characters(),
    Include Boundary Delimiters
);

Example 4

Items( [1 2], ",Apple,Banana Tree,Peach", Get Punctuation Characters() );

J

Syntax: y = J( nr, <nc>, <v> ); y = J( nr, nc ); y = J( n )

Description: Creates a matrix (nr by nc) of values that are determined by the third argument. The default value of the second argument equals the first argument. The default value of the third argument is 1. But the third argument can be a number, a variable name of a number, or JSL code. If the third argument is code, the code is evaluated and assigned the return value to every element in the matrix, element by element, row by row.

JMP Version Added: Before version 14

// Produce a 2x3 matrix, filled with 15.
m = J( 2, 3, 15 );
// Produce a default 4x4 matrix, filled with 1.
m = J( 4 );
// Produce a 2x3 matrix, filled with a number determined by a variable.
a = 3.14;
m = J( 2, 3, a );
// Produce a vector of random numbers from the Uniform distribution.
m = J( 1, 100, Random Uniform() );
// Produce a 2x3 matrix, filled with a sequence of integers.
a = 0;
m = J( 2, 3, a = a + 1 );
// This is a fun example to illustrate what is possible for the third argument.
i = 1;
J(
    10,
    1,
    Print(
        Eval Insert(
            "For the ^i^^if(i < 4, words(\!"st,nd,rd\!",\!",\!")[i], \!"th\!")^ time, I'm not a loop!"
        )
    );
    Round( 1 / Sqrt( 5 ) * ((1 + Sqrt( 5 )) / 2) ^ i++ );
);

JMP Product Name

Syntax: y = JMP Product Name()

Description: Returns "Standard" or "Pro" based on the version of the product that has been licensed.

JMP Version Added: Before version 14

JMP Product Name();

JMP Version

Syntax: y = JMP Version()

Description: Returns the JMP version (release.revision{.fix}); not available before 6.0.

JMP Version Added: Before version 14

JMP Version();

Johnson Sb Density

Syntax: y = Johnson Sb Density( q, gamma, delta, theta, sigma )

Description: Returns the density at q of a Johnson Sb distribution, where q is in the interval theta to theta + sigma, delta>0 and gamma between -∞ and +∞ are shape parameters, sigma>0 is a scale parameter, and theta between -∞ and +∞ is a threshold parameter. Note: theta is the lower endpoint of the distribution and sigma is the range of the support of the distribution.

JMP Version Added: Before version 14

gamma = 0.5;
delta = 0.5;
theta = 0.5;
sigma = 1;
New Window( "Example: Johnson Sb Density",
    jsbp = Graph Box(
        Y Scale( 0, 5.5 ),
        X Scale( 0.2, 1.8 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Johnson Sb Density( q, gamma, delta, theta, sigma ), q );
        Text(
            {0.5, 4.5},
            "\!U03B3=",
            Round( gamma, 2 ),
            " \!U03B4=",
            Round( delta, 2 ),
            " \!U03B8=",
            Round( theta, 2 ),
            " \!U03C3=",
            Round( sigma, 2 )
        );
    ),
    H List Box( Slider Box( 0, 1, gamma, jsbp << reshow ), Text Box( " \!U03B3" ) ),
    H List Box( Slider Box( 0, 2, delta, jsbp << reshow ), Text Box( " \!U03B4" ) ),
    H List Box( Slider Box( -2, 2, theta, jsbp << reshow ), Text Box( " \!U03B8" ) ),
    H List Box( Slider Box( 0, 10, sigma, jsbp << reshow ), Text Box( " \!U03C3" ) )
);

Johnson Sb Distribution

Syntax: p = Johnson Sb Distribution( q, gamma, delta, theta, sigma )

Description: Returns the probability that a Johnson Sb distributed random variable is less than q. (Note: see the Johnson Sb Density() function for parameter descriptions.)

JMP Version Added: Before version 14

gamma = 0.5;
delta = 0.5;
theta = 0.5;
sigma = 3;
New Window( "Example: Johnson Sb Distribution",
    jsbc = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0.2, 3.8 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Johnson Sb Distribution( q, gamma, delta, theta, sigma ), q );
        Text(
            {0.3, 0.8},
            "\!U03B3=",
            Round( gamma, 2 ),
            " \!U03B4=",
            Round( delta, 2 ),
            " \!U03B8=",
            Round( theta, 2 ),
            " \!U03C3=",
            Round( sigma, 2 )
        );
    ),
    H List Box( Slider Box( 0, 1, gamma, jsbc << reshow ), Text Box( " \!U03B3" ) ),
    H List Box( Slider Box( 0, 1, delta, jsbc << reshow ), Text Box( " \!U03B4" ) ),
    H List Box( Slider Box( 0, 1, theta, jsbc << reshow ), Text Box( " \!U03B8" ) ),
    H List Box( Slider Box( 0, 4, sigma, jsbc << reshow ), Text Box( " \!U03C3" ) )
);

Johnson Sb Quantile

Syntax: q = Johnson Sb Quantile( p, gamma, delta, theta, sigma )

Description: Returns the quantile from a Johnson Sb distribution, the value for which the probability is p that a random value would be lower. (Note: p is the first parameter. See the Johnson Sb Density() function for parameter descriptions.)

JMP Version Added: Before version 14

Johnson Sb Quantile( 0.5, 0.5, 1, 1, 1 );

Johnson Sl Density

Syntax: y = Johnson Sl Density( q, gamma, delta, theta, <sigma=1> )

Description: Returns the density at q of a Johnson Sl distribution, where q is in the interval theta to +∞, delta>0 and gamma between -∞ and +∞ are shape parameters, sigma equal to +1 or -1 is a scale parameter, and theta between -∞ and +∞ is a threshold parameter. Note: When sigma = 1, theta is the lower bound on the distribution, and when sigma=-1, theta is the upper bound. Also, positive sigma implies positive skew, and negative sigma implies negative skew.

JMP Version Added: Before version 14

gamma = 0.5;
delta = 1;
theta = 0;
sigma = 1;
New Window( "Example: Johnson Sl Density",
    jslp = Graph Box(
        Y Scale( 0, 1.5 ),
        X Scale( -5, 5 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Johnson Sl Density( q, gamma, delta, theta, sigma ), q );
        Text(
            {-1, 1.1},
            "\!U03B3=",
            Round( gamma, 2 ),
            " \!U03B4=",
            Round( delta, 2 ),
            " \!U03B8=",
            Round( theta, 2 )
        );
    ),
    jslpcb = Check Box(
        {"\!U03C3 = +1 (Note: When unchecked \!U03C3 = -1)"},
        <<set( 1 ),
        sigma = [-1, 1][((jslpcb << get()) + 1)];
        jslp << reshow;
    ),
    H List Box( Slider Box( -15, 15, gamma, jslp << reshow ), Text Box( " \!U03B3" ) ),
    H List Box( Slider Box( 0, 10, delta, jslp << reshow ), Text Box( " \!U03B4" ) ),
    H List Box( Slider Box( -5, 5, theta, jslp << reshow ), Text Box( " \!U03B8" ) )
);

Johnson Sl Distribution

Syntax: p = Johnson Sl Distribution( q, gamma, delta, theta, <sigma=1> )

Description: Returns the probability that a Johnson Sl distributed random variable is less than q. (Note: see the Johnson Sl Density() function for parameter descriptions.)

JMP Version Added: Before version 14

gamma = 0.5;
delta = 1;
theta = 0;
sigma = 1;
New Window( "Example: Johnson Sl Distribution",
    jslc = Graph Box(
        Y Scale( 0, 1.05 ),
        X Scale( -5, 5 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Johnson Sl Distribution( q, gamma, delta, theta, sigma ), q );
        Text(
            {-1, 0.9},
            "\!U03B3=",
            Round( gamma, 2 ),
            " \!U03B4=",
            Round( delta, 2 ),
            " \!U03B8=",
            Round( theta, 2 )
        );
    ),
    jslccb = Check Box(
        {"\!U03C3 = +1 (Note: When unchecked \!U03C3 = -1)"},
        <<set( 1 ),
        sigma = [-1, 1][((jslccb << get()) + 1)];
        jslc << reshow;
    ),
    H List Box( Slider Box( -15, 15, gamma, jslc << reshow ), Text Box( " \!U03B3" ) ),
    H List Box( Slider Box( 0, 10, delta, jslc << reshow ), Text Box( " \!U03B4" ) ),
    H List Box( Slider Box( -5, 5, theta, jslc << reshow ), Text Box( " \!U03B8" ) )
);

Johnson Sl Quantile

Syntax: q = Johnson Sl Quantile( p, gamma, delta, theta, <sigma=1> )

Description: Returns the quantile from a Johnson Sl distribution, the value for which the probability is p that a random value would be lower. (Note: p is the first parameter. See the Johnson Sl Density() function for parameter descriptions.)

JMP Version Added: Before version 14

Johnson Sl Quantile( 0.5, 0.5, 1, 1, 1 );

Johnson Su Density

Syntax: y = Johnson Su Density( q, gamma, delta, theta, sigma )

Description: Returns the density at q of a Johnson Su distribution, where q is between -∞ and +∞, delta>0 and gamma between -∞ and +∞ are shape parameters, sigma>0 is a scale parameter, and theta between -∞ and +∞ is a threshold parameter.

JMP Version Added: Before version 14

gamma = 0.5;
delta = 1;
theta = 1;
sigma = 1;
New Window( "Example: Johnson Su Density",
    y = Graph Box(
        Y Scale( 0, 1.5 ),
        X Scale( -2, 2 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Johnson Su Density( q, gamma, delta, theta, sigma ), q );
        Text(
            {-1, 1.3},
            "\!U03B3=",
            Round( gamma, 2 ),
            " \!U03B4=",
            Round( delta, 2 ),
            " \!U03B8=",
            Round( theta, 2 ),
            " \!U03C3=",
            Round( sigma, 2 )
        );
    ),
    H List Box( Slider Box( 0, 1, gamma, y << reshow ), Text Box( " \!U03B3" ) ),
    H List Box( Slider Box( 0, 2, delta, y << reshow ), Text Box( " \!U03B4" ) ),
    H List Box( Slider Box( 0, 2, theta, y << reshow ), Text Box( " \!U03B8" ) ),
    H List Box( Slider Box( 0, 2, sigma, y << reshow ), Text Box( " \!U03C3" ) )
);

Johnson Su Distribution

Syntax: p = Johnson Su Distribution( q, gamma, delta, theta, sigma )

Description: Returns the probability that a Johnson Su distributed random variable is less than q. (Note: see the Johnson Su Density() function for parameter descriptions.)

JMP Version Added: Before version 14

gamma = 0.5;
delta = 1;
theta = 1;
sigma = 1;
New Window( "Example: Johnson Su Distribution",
    jsuc = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -2, 2 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Johnson Su Distribution( q, gamma, delta, theta, sigma ), q );
        Text(
            {-1, 0.9},
            "\!U03B3=",
            Round( gamma, 2 ),
            " \!U03B4=",
            Round( delta, 2 ),
            " \!U03B8=",
            Round( theta, 2 ),
            " \!U03C3=",
            Round( sigma, 2 )
        );
    ),
    H List Box( Slider Box( 0, 1, gamma, jsuc << reshow ), Text Box( " \!U03B3" ) ),
    H List Box( Slider Box( 0, 2, delta, jsuc << reshow ), Text Box( " \!U03B4" ) ),
    H List Box( Slider Box( 0, 2, theta, jsuc << reshow ), Text Box( " \!U03B8" ) ),
    H List Box( Slider Box( 0, 2, sigma, jsuc << reshow ), Text Box( " \!U03C3" ) )
);

Johnson Su Quantile

Syntax: q = Johnson Su Quantile( p, gamma, delta, theta, sigma )

Description: Returns the quantile from a Johnson Su distribution, the value for which the probability is p that a random value would be lower. (Note: p is the first parameter. See the Johnson Su Density() function for parameter descriptions.)

JMP Version Added: Before version 14

Johnson Su Quantile( 0.5, 0.5, 1, 1, 1 );

Journal Box

Syntax: y = Journal Box( journalText )

Description: Constructs a display box from instructions that would be stored in a journal.

JMP Version Added: Before version 14

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
sample = Distribution( Y( :height ) );
sampjourn = sample << Get Journal;
New Window( "Distribution of Height",
    Text Box( "Here is the result of the distribution platform for Height." ),
    Journal Box( sampjourn )
);

JSL Encrypted

Syntax: y = JSL Encrypted(script)

Description: Embeds an encrypted script within another script. Create an encrypted script by selecting Edit > Encrypt Script from the main menu of a script editor. Enter your passwords and the encrypted text will appear in a new window. Copy this text into a JSL Encrypted("") command to embed the encrypted script in another script.

JMP Version Added: Before version 14

JSL Encrypted(
    "//-e6.0.2\!NWUSXEHSB?SRAMXPSY?;KDGMNGPQFZP;?><JLEXCQZYIGWSI@<FOPBLDKJ?HEUPTOGSZDYWFDMB;NEVB;HFP=VQ@N;LCVQPWRHIXEIPFKGO=H?DWS?KFQRIPBEPSAE<AM?YG=C@VFRENPEW>@;ND=JA<?=WOZZOG>FZBZKZLMFOX?YF@LWA=B=SJXDGVW>VYLBRJT<I<MFE<Q??QCUOZM?RY>RXLBJRH=BH<EGVSEMABSS<IE=CAPID;XM;;?XIU<FA=SCE<CB;AGOCZWHZXK;*"
);

JSL Quote

Syntax: y = JSL Quote(script)

Description: Store a JSL script in a variable, including all comments and formatting.

JMP Version Added: Before version 14

x = JSL Quote(/* Begin quote. */
    For (i = 1, i <= 5, i++,
        // Print the value of i.
        Print(i);
    );
    // End expression.
);
New Window( "editor", Script Box( x ) );

JSON Literal

Syntax: l = JSON Literal( string )

Description: Returns a valid JSON Boolean or null constant value depending on the specification of the parameter.

JMP Version Added: 14

myJSON =
"{ \!"myChar\!": \!"Character Value\!", \!"myNum\!": 12345, \!"myBool\!": true, \!"myOtherChar\!": \!"Another char value\!", \!"myNull\!": null, \!"x\!": 54321, \!"myOtherBool\!": false, \!"y\!": \!"Hello\!" }";
parsed = Parse JSON( myJSON );
x = parsed["myBool"];
Show( x );
If( x == JSON Literal( true ),
    Show( "Worked" ),
    Show( "Didn't work" )
);

JSON To Data Table

Syntax: dt = JSON To Data Table( jsonstring, <Invisible( boolean ) | Private( boolean )>, <Guess(Stack(Boolean)|"Tall"|"Wide")>, <JSON Settings(...)> )

Description: Convert JSON text to a JMP data table

JMP Version Added: 14

dt = JSON To Data Table(
    "[ { \!"name\!": \!"KATIE\!", \!"age\!": 12, \!"sex\!": \!"F\!", \!"height\!": 59, \!"weight\!": 95 }, { \!"name\!": \!"LOUISE\!", \!"age\!": 12, \!"sex\!": \!"F\!", \!"height\!": 61, \!"weight\!": 123 }, { \!"name\!": \!"JANE\!", \!"age\!": 12, \!"sex\!": \!"F\!", \!"height\!": 55, \!"weight\!": 74 } ]"
);

JSON To List

Syntax: l = JSON To List( jsonstring )

Description: Convert JSON text to a JSL list representing the structure specified by the JSON data.

JMP Version Added: Before version 14

l = JSON To List(
    "[ { \!"name\!": \!"KATIE\!", \!"age\!": 12, \!"sex\!": \!"F\!", \!"height\!": 59, \!"weight\!": 95 }, { \!"name\!": \!"LOUISE\!", \!"age\!": 12, \!"sex\!": \!"F\!", \!"height\!": 61, \!"weight\!": 123 }, { \!"name\!": \!"JANE\!", \!"age\!": 12, \!"sex\!": \!"F\!", \!"height\!": 55, \!"weight\!": 74 } ]"
);
Show( l );

JSS Context Box

Syntax: y = JSS Context Box( displayBox )

JMP Version Added: 19

New Window( "JSS Context",
    JSS Context Box(
        V List Box(
            Panel Box( "Panel", Text Box( "Hi" ), Button Box( "Press Me" ), ),
            Button Box( "Outside" ),

        ),
        <<Set JSS(
            Expr(
                Type( TextBox ) << Background Color( "Red" );
                Type( ButtonBox ) << Background Color( "Green" );
                Descend( Type( PanelBox ), Type( ButtonBox ) ) << Background Color( "Blue" );
            )
        )
    )
);

KDE

Syntax: {Estimates, Bins, Counts, ActualBandwidth, Error} = KDE( Vector, <<weights, <<bandwidth( 0 ), <<bandwidth scale( 1 ), <<bandwidth selection( 0 ), <<kernel )

Description: Returns a kernel density estimator with automatic bandwidth selection. The optional weights argument must be a vector of the same length as the Vector argument. The optional bandwidth argument must be a nonnegative real number or zero, which forces the use of the value of the bandwidth selection argument. The optional bandwidth scale argument must be a positive real number. The optional bandwidth selection argument must be either 0, 1, 2, or 3, corresponding to Sheather and Jones, Normal Reference, Silverman rule of thumb, or Oversmoother, respectively. The optional kernel argument accepts the values 0, 1, 2, 3, or 4, corresponding to Gaussian, Epanechnikov, Biweight, Triangular, or Rectangular, respectively.

JMP Version Added: Before version 14

// generate sample dataset from a mixture of 3 normal distributions
ndata3 = 25;
Random Reset( 113 );
channel = J( 1, ndata3 * 3, 0 );
For( i = 1, i <= ndata3, i++,
    channel[1, i] = Random Normal() - 3;
    channel[1, ndata3 + i] = Random Normal() / 2;
    channel[1, ndata3 + ndata3 + i] = Random Normal() + 3;
);

// use kernel density estimator to estimate the underlying distribution
bw = .; // automatic bandwidth
bscl = 1; // bandwidth multiplier
bsel = 0; // Sheather and Jones bandwith selection

// Create data table with estimates from all smoothing KDEs and Bins
dt = New Table( "KDE Smoothing",
    New Column( "Kernel", "Character" ),
    New Column( "Bin" ),
    New Column( "Density Estimate" ),
    New Column( "Counts" )
);

kernels = {"Gaussian", "Epanechnikov", "Biweight", "Triangular", "Rectangular"};
For( kernel = 0, kernel < N Items( kernels ), kernel++,
    res = KDE(
        channel,
        <<bandwidth( bw ),
        <<bandwidth scale( bscl ),
        <<bandwidth selection( bsel ),
        <<kernel( kernel )
    );
    nbin = N Items( res["Bins"] );
    rows = (N Rows( dt ) + 1) :: (N Rows( dt ) + nbin);
    dt << Add Rows( nbin );
    dt[rows, "Kernel"] = kernels[kernel + 1];
    dt[rows, "Bin"] = res["Bins"]`;
    dt[rows, "Density Estimate"] = res["Estimates"]`;
    dt[rows, "Counts"] = res["Counts"]`;
);

dt << Graph Builder(
    Size( 1000, 376 ),
    Show Control Panel( 0 ),
    Legend Position( "Bottom" ),
    Variables(
        X( :Bin ),
        Y( :Density Estimate, Side( "Right" ) ),
        Y( :Counts, Position( 1 ) ),
        Overlay( :Kernel )
    ),
    Elements(
        Bar( X, Y( 2 ), Overlay( 0 ), Legend( 2 ), Bar Style( "Needle" ) ),
        Line( X, Y( 1 ), Legend( 3 ) )
    )
);

KDTable

Syntax: tab = KDTable( [ 1 1 1, 1 2 1, 1 2 2, 2 2 2, 3 3 3, 4 5 6 ] )

Description: Returns a table for efficiently looking up near neighbors. The matrix arguments are k-dimensional points. There is no built in limit on the number of dimensions or points.

JMP Version Added: Before version 14

tab = KDTable( [1 1 1, 1 2 1, 1 2 2, 2 2 2, 3 3 3, 4 5 6] );
{rows, dist} = tab << K nearest rows( 2, 1 );
"2 nearest rows to row 1 are " || Char( rows );

Labeled

Syntax: y = Labeled( <rs> ); Labeled( <Row State( <r> )> ) = y

Description: Returns the labeled component of the specified row state value, 0 or 1. If Labeled is used as an L-value, it changes the labeled state of the current (or rth) row in the current data table.

JMP Version Added: Before version 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
Row State( 3 ) = Labeled State( 1 );
Labeled( Row State( 3 ) );
Row() = 3;
Labeled();

Labeled State

Syntax: rs = Labeled State( x )

Description: Returns a row state value with the labeled component set to the specified value.

JMP Version Added: Before version 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
Row State( 3 ) = Labeled State( 1 );
Labeled( Row State( 3 ) );

Lag

Syntax: y = Lag( <x>, <n=1> )

Description: Returns the value of the x argument with the current row set to Row() - n. Being dependent on Row(), Lag() is mainly useful in column formulas.

JMP Version Added: Before version 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
Row() = 3;
Lag( :height, 2 );

Last Modification Date

Syntax: date = Last Modification Date( path )

Description: Returns the last modification date of a file or directory. Throws an error when path is invalid or does not exist.

JMP Version Added: Before version 14

Format( Last Modification Date( "$SAMPLE_DATA/Big Class.jmp" ), "ddmonyyyy:h:m:s" );

Least Squares Solve

Syntax: {Beta, VarBeta} = Least Squares Solve(y, X, <<noIntercept, <<weights(optionalWeightVector), <<method("Sweep"|"GInv"))

Description: Returns a list that contains a vector of estimates, Beta = Inverse(X'X)X'y, and the estimated variance matrix of Beta. The optional <<noIntercept argument specifies a no-intercept model. The optional <<weights argument specifies a vector of weights to perform weighted least squares. The optional <<method argument enables you to choose between the default Sweep method and a generalized inverse ("GInv") method for solving the normal equations.

JMP Version Added: Before version 14

/*Simple Linear Regression*/
y = [3, 5, 7, 5];
X = [1, 2, 3, 4];
{Beta, VarBeta} = Least Squares Solve( y, X );

Left

Syntax: sub = Left( s, n, <filler> )

Description: Returns a truncated or padded version of the original string or list s. The result contains the left n characters or list items, padded with any filler on the right if the length of s is less than n.

JMP Version Added: Before version 14

exurl = "http://www.jmp.com";
Left( exurl, Contains( exurl, ":" ) - 1 );

Length

Syntax: l = Length( x )

Description: Returns the length of the given string (in characters), list (in items), associative array (in number of keys), blob (in bytes), matrix (in elements), or namespace/class (in number of functions and variables).

JMP Version Added: Before version 14

Example 1

Length( "Café" );

Example 2

Length( {1, 2 + 3, [11 22]} );

Example 3

Length( ["a" => 10, "b" => 3, => 0] );

Example 4

Length( Char To Blob( "Café" ) );

LenthPSE

Syntax: y = LenthPSE( x )

Description: Returns Lenth's pseudo-standard error of the values within a single vector x.

JMP Version Added: Before version 14

Eval List( {LenthPSE( [1, 2, 3, 4, 5] ), Std Dev( [1, 2, 3, 4, 5] )} );

Less

Syntax: z = x < y < ... ; z = Less( x, y, ... )

Description: Returns 1 if each argument is less than the next argument; returns 0 otherwise.

JMP Version Added: Before version 14

[1 1 1] < [0 1 2];

Less LessEqual

Syntax: z = x < y <= ... ; z = Less LessEqual( x, y, ... )

Description: Returns 1 if the first argument is less than the second argument and each argument except the first is less than or equal to the next argument; returns 0 otherwise.

JMP Version Added: Before version 14

1 < 2 <= 2;

Less or Equal

Syntax: z = x <= y <= ... ; z = Less or Equal( x, y, ... )

Description: Returns 1 if each argument is less than or equal to the next argument; returns 0 otherwise.

JMP Version Added: Before version 14

1 <= 2 <= 2;

LessEqual Less

Syntax: z = x <= y < ... ; z = LessEqual Less( x, y, ... )

Description: Returns 1 if the first argument is less than or equal to the second argument and each argument except the first is less than the next argument; returns 0 otherwise.

JMP Version Added: Before version 14

2 <= 2 < 3;

LEV Density

Syntax: y = LEV Density( x, mu, sigma )

Description: Returns the density at x of a largest extreme distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 10;
sig = 5;
New Window( "Example: LEV Density",
    y = Graph Box(
        Y Scale( 0, .08 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( LEV Density( x, mu, sig ), x );
        Text( {0, .055}, "mu=", Round( mu, 2 ) );
        Text( {0, .045}, "sig=", Round( sig, 2 ) );
    ),
    H List Box( Slider Box( 0, 100, mu, y << reshow ), Text Box( "mu" ) ),
    H List Box( Slider Box( 0, 10, sig, y << reshow ), Text Box( "sig" ) ), 

);

LEV Distribution

Syntax: p = LEV Distribution( x, mu, sigma )

Description: Returns the probability at x of a largest extreme distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 10;
sig = 5;
New Window( "Example: LEV Distribution",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( LEV Distribution( x, mu, sig ), x );
        Text( {0.1, 0.9}, "mu=", Round( mu, 2 ) );
        Text( {0.1, 0.8}, "sig=", Round( sig, 2 ) );
    ),
    H List Box( Slider Box( 0, 100, mu, y << reshow ), Text Box( " mu" ) ),
    H List Box( Slider Box( 0, 10, sig, y << reshow ), Text Box( " sig" ) )
);

LEV Quantile

Syntax: q = LEV Quantile( p, mu, sigma )

Description: Returns the quantile at p of a largest extreme distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 10;
sig = 5;
qq = .5;
New Window( "Example: LEV Quantile",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( LEV Distribution( qq, mu, sig ), qq );
        Pen Color( "blue" );
        V Line( LEV Quantile( qq, mu, sig ), 0, 1 );
        Text(
            {0.1, 0.9},
            " mu=",
            Round( mu, 2 ),
            " sig=",
            Round( sig, 2 ),
            " quantile=",
            Round( qq, 2 )
        );
    ),
    H List Box( Slider Box( 0, 80, mu, y << reshow ), Text Box( " mu" ) ),
    H List Box( Slider Box( 0, 10, sig, y << reshow ), Text Box( " sig" ) ),
    H List Box( Slider Box( 0.01, 0.99, qq, y << reshow ), Text Box( " quantile" ) )
);

Level Color

Syntax: y = Level Color( i ); y = Level Color( i, n ); y = Level Color( i, n, <theme> ); y = Level Color( i, <theme> )

Description: Returns a category color, where i is the category level; n is the number of categories (optional); and theme are the color themes in the Column Info dialog's Value Color combo box. ("JMP Default" is the default theme.) The category index must be >= 1 and <= the number of categories specified in the call or defined by the theme. If the second argument is a character, it is the color theme and n is unspecified.

JMP Version Added: Before version 14

New Window( "Color Bar",
    Graph(
        For( x = 1, x <= 100, x += 5,
            Fill Color( Level Color( x, 100, "Green to Black to Red" ) );
            Rect( x - 5, 45, x + 5, 55, 1 );
        )
    )
);

LGamma

Syntax: y = LGamma( x )

Description: Returns the natural logarithm of the Gamma function of x. Useful when Gamma(x) is too large to use directly.

JMP Version Added: Before version 14

LGamma( 5 );

Line

Syntax: Line( {x1, y1}, {x2, y2}, ..., < <<Value Space( 0|1 ) >, < <<Smooth( tension, domain, min response, max response ) > ); Line( xMatrix, yMatrix, < <<Value Space(0 | 1) >, < <<Smooth( tension, domain, min response, max response ) > )

Description: Draws a line or connected lines. In the default case, the line is drawn linearly between the endpoints. If the Value Space option is set, the line follows the projection specified by the underlying axis scales. If the Smooth option is set, connections are smoothed, constrained by tension, domain dimension, min response, and max response.

JMP Version Added: Before version 14

Constrained smoothing

New Window( "Constrained smoothing",
    Graph Box(
        Pen Color( "gray" );
        H Line( 90 );
        H Line( 92 );
        H Line( 10 );
        H Line( 8 );
        Pen Color( "red" );
        Line( Index( 10, 90, 10 ), [20 10 90 90 60 70 10 10 40], <<Smooth( . ) );
        Pen Color( "blue" );
        Line( Index( 10, 90, 10 ), [20 10 90 90 60 70 10 10 40], <<Smooth( ., "X", 8, 92 ) );
    )
);

Polyline

New Window( "Example", Graph Box( Line( [10 30 90], [88 22 44] ) ) );

Smoothing

New Window( "Smoothing",
    Graph Box(
        XAxis( Min( 0 ), Max( 10 ), Inc( 2 ) ),
        YAxis( Min( -1.1 ), Max( 1.1 ), Inc( 1 ) ),
        Pen Color( "gray" );
        H Line( 1 );
        H Line( -1 );
        H Line( 0 );
        Line( 0 :: 10, Sin( 0 :: 10 ) );
        Pen Color( "red" );
        Line( 0 :: 10, Sin( 0 :: 10 ), <<Smooth( . ) );
        Pen Color( "blue" );
        Line( 0 :: 10, Sin( 0 :: 10 ), <<Smooth( 0.25 ) );
    )
);

Value space interpolation

New Window( "Interpolate in value space",
    Graph Box(
        XAxis( Scale( "Log" ), Min( 10 ), Max( 100 ) ),
        YAxis( Scale( "Log" ), Min( 10 ), Max( 100 ) ),
        Line( [10 30 90], [88 22 44], <<Value Space( 1 ) )
    )
);

Line Seg

Syntax: ls = Line Seg(x values, y values, <Row States( dt | dt,[rows] | dt,{{rows}, ...} | {states} ) >, < Sizes( s ) > )>)

Description: Returns a display seg with lines connecting all of the x and y values.

JMP Version Added: Before version 14

Example 1

x = [10, 50, 90];
y = [10, 90, 10];
New Window( "Line Seg Example", g = Graph Box( Line Seg( x, y ) ) );
frame = g[FrameBox( 1 )];
seg = (frame << Find Seg( "Line Seg" ));

Example 2

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
x = [10, 50, 90];
y = [10, 90, 10];
New Window( "Line Seg Example", g = Graph Box( Line Seg( x, y, RowStates( dt ) ) ) );
frame = g[FrameBox( 1 )];
seg = (frame << Find Seg( "Line Seg" ));

Example 3

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
x = [10, 50, 90];
y = [10, 90, 10];
New Window( "Line Seg Example",
    g = Graph Box( Line Seg( x, y, RowStates( dt, {1, 3, 5} ) ) )
);
frame = g[FrameBox( 1 )];
seg = (frame << Find Seg( "Line Seg" ));

Line Style

Syntax: Line Style( x )

Description: Sets the current line style, which can be one of: 0 (Solid), 1 (Dotted), 2 (Dashed), 3 (DashDot), or 4 (DashDotDot).

JMP Version Added: Before version 14

New Window( "Line Style Example",
    Graph Box(
        Frame Size( 500, 400 ),
        named line styles = {"Solid", "Dotted", "Dashed", "Dash Dot", "Dash Dot Dot",
        "Dash Dash Dot", "Dash Dash Dot Dot", "Long Dash", "Long Dash Dash", "Dense Dash",
        "Sparse Dash", "Sparse Dot", "Sparse Dash Dot"};
        For Each( {istyle, i}, named line styles, {x = 5 :: 75, y = 12 * Sin( x / 12 )},
            Text( {x[N Items( x )] + 1, y[N Items( y )] + 92 - 6 * i - 1.5}, istyle );
            Line Style( istyle );
            Pen Size( 2 );
            Line( x, y + 92 - 6 * i );
        );
    )
);

Linear Regression

Syntax: {Estimates, Std_Error, Diagnostics} = Linear Regression(y, X, <<noIntercept, <<printToLog, <<weight(WeightVector), <<freq(FrequencyVector)

Description: Fits a linear regression for the assumed model y = X * beta + error. The optional <<noIntercept argument specifies a no-intercept model. The optional <<printToLog argument specifies that a summary of fit is printed to the log window. The optional weight argument specifies a vector of weights to perform weighted least squares, and the optional freq argument specifies a vector of frequencies. Returns a list containing a vector of the estimates, a vector of the standard errors, and a list of diagnostics. The list of diagnostics contains vectors of the t statistics and p-values for the estimates, as well as the R-Square and adjusted R-Square values for the regression fit.

JMP Version Added: 14

Example 1

/*Simple Linear Regression: y = intercept + beta * x + error*/
y = [3, 5, 7, 5];
X = [1, 2, 3, 4];
{Estimates, Std_Error, Diagnostics} = Linear Regression( y, X, <<printToLog ); 
/*
t_ratio = Diagnostics["t_ratio"]; 
p_value = Diagnostics["p_value"]; 
RSquare = Diagnostics["RSquare"]; 
RSquare Adj = Diagnostics["RSquare Adj"];
*/

Example 2

/*Model: y = beta_1*x + beta_2*x^2 + error*/
y = [3, 5, 7, 5];
X = [1 1, 2 4, 3 9, 4 16];
{Estimates, Std_Error, Diagnostics} = Linear Regression( y, X, <<noIntercept, <<printToLog );

Example 3

/*Categorical Variable Example*/
/*Model: y = beta_1*boy + beta_2*girl + beta_3*x + error*/
y = [3, 5, 7, 5];
x = [1, 2, 3, 4];
gender = {"boy", "girl", "girl", "boy"};
designMat = Design( gender ) || x;
{Estimates, Std_Error, Diagnostics} = Linear Regression(
    y,
    designMat,
    <<noIntercept,
    <<printToLog
);

Lines Seg

Syntax: ls = Lines Seg([x1 y1 x2 y2,...])

Description: Returns a display seg with a sequence of line segments for the passed in x and y values.

JMP Version Added: Before version 14

lines = [30 20 80 70, 10 90 90 10, 40 20 60 30];
New Window( "Lines Seg Example", g = Graph Box( Lines Seg( lines ) ) );
frame = g[FrameBox( 1 )];
seg = (frame << Find Seg( "Lines Seg" ));

Lineup Box

Syntax: y = Lineup Box( <NCol( nc )>, <Spacing( pixels, <vspace> )>, displayBoxArgs, ... )

Description: Returns a display box to show an alignment of boxes in nc columns. The optional Spacing argument specifies the horizontal and vertical space around the display boxes. If the vspace argument is used, vspace is the vertical space and pixels is the horizontal space.

JMP Version Added: Before version 14

New Window( "Example",
    Lineup Box( N Col( 1 ), spacing( 10 ),
        Text Box( "Quadratic Formula" ),
        Border Box( Left( 10 ), Right( 10 ), bottom( 10 ), top( 10 ), sides( 15 ),
            Expr As Picture( Expr( (-b + Sqrt( b ^ 2 - 4 * a * c )) / (2 * a) ) )
        )
    )
);

Lineup Ruler Box

Syntax: y = Lineup Box( <Widths( {width1, width2, ...} )>, displayBoxArgs, ... )

Description: Returns a display box that sets the column widths of the Lineup Boxes that it contains.

JMP Version Added: 16

New Window( "Lineup Ruler",
    lrb = Lineup Ruler Box(
        Widths( {120, 200} ),
        Outline Box( "Customer 1",
            Lineup Box( N Col( 2 ),
                Text Box( "First Name:" ),
                Text Edit Box(),
                Text Box( "Last Name:" ),
                Text Edit Box(), 

            )
        ),
        Outline Box( "Customer 2",
            Lineup Box( N Col( 2 ),
                Text Box( "First Name:" ),
                Text Edit Box(),
                Text Box( "Last Name:" ),
                Text Edit Box(), 

            )
        )
    )
);

List

Syntax: y = {a, b, ...}; y = List( a, b, ... )

Description: Creates a list of items without evaluating them.

JMP Version Added: Before version 14

{1, 2 + 3, [11 22]};

List Box

Syntax: y = List Box( {item, ...}, <width( pixels )>, <maxSelected( 9999 )>, <nlines( 12 )>, <script> )

Description: Returns a display box to show a list box of selection items. If item itself is a two-item list containing the item name and a string specifying a modeling type or sorting order, such as "Ordinal" or "Ascending", the appropriate icon will show up next to that item in the list box.

JMP Version Added: Before version 14

Example 1

New Window( "Example", b = List Box( {"single", "double", "triple"}, nlines( 10 ) ) );

Example 2

New Window( "Example",
    lb = List Box(
        {{"First Item", "continuous"}, {"Second Item", "ordinal"}, {"Third Item", "nominal"}},
        width( 200 ),
        max selected( 2 ),
        nlines( 6 )
    )
);

Ln

Syntax: y = Ln( x )

Description: Returns the natural logarithm of x.

JMP Version Added: Before version 14

Ln( Exp( 2 ) );

Load DLL

Syntax: dll = Load DLL( file path | Base Name( file path without extension ), < AutoDeclare( bool | Quiet | Verbose) | Quiet | Verbose )> )

Description: Loads a DLL pointed to by the specified path.

JMP Version Added: Before version 14

Cross platform using Base Name()

dll = Load DLL( Base Name( "/path/to/dll/financial" ) );
// Loads "financial.dll" on Windows and "libfinancial.dylib" on Mac
// Declarations for "irr" and "npv" are auto-loaded
myirr = dll << irr( 0.1, -51000, 1000, 900, 950 );
mynpv = dll << npv( 0.05, -51000, 1000, 900, 9500 );
dll << UnloadDLL();

Windows only

If( Host is( "Windows" ),
    dll = Load DLL( "C:/Windows/System32/User32.DLL" );
    dll << CallDLL( "MessageBeep", "n", 0 );
    Wait( 1 );
    dll << CallDLL( "MessageBeep", "n", 0 );
    dll << UnloadDLL();
);

Load Text File

Syntax: text = Load Text File( path, <Charset("best guess", <force("throw" | "alert" | "silent")>)>, <LineSeparator("!N")>, <XMLParse>|<SASODSXML>|<JSON>|<BLOB( <readOffsetFromBegin(0)>|<readOffsetFromEnd(42)>, <readLength(2147483647)>, <base64Compressed( 1 / 0: ascii~hex /)> )> )

Description: Reads a whole text file into a JSL variable. Load Text File() prompts for a file name. Load Text File( path ) returns a string. The XMLParse option converts XML into an expression tree. The SASODSXML parses as SAS ODS default XML. The [{JSON}] option converts JSON into an expression tree. The BLOB argument returns binary data in a JSL Blob variable; optional named parameters to BLOB enable reading a substring from the file.

JMP Version Added: Before version 14

ex = Load Text File(
    Get Path Variable( "sample_import_data" ) || "/animals.txt"
/*, Charset("ascii")*/
/*, LineSeparator("\!r\!n")*/
/*, BLOB*/
);
Word( 4, ex, " \!t\!n\!r" );

Loc

Syntax: y = Loc( m ); y = Loc( v, x )

Description: Returns a matrix of the positions of the matrix m that are nonzero.If two arguments are specified, Loc(v, x) returns a matrix of the positions of the list or matrix v that are equal to the value x. Prefer Where instead where possible.

JMP Version Added: Before version 14

Example 1

/*more examples, above*/
Show( Loc( [1 0 1 0 1 0] ) );
Show( Loc( {"A", 2, 3, 2, 5, 2, 4, [1 5]}, 2 ) );
Show( Loc( {"A", 2, 3, 2, 5, 2, 4, [1 5]}, [1 5] ) );

Example 2

Loc( [0, -2, 3, 0, 5, ., -7, ., 9] ) /*missing is not zero or non-zero*/;

Example 3

Loc( [5, 7, 5, ., 5], 5 );

Example 4

Loc( [5, 7, 5, ., 5] == 5 ) /*[5,7,5, . ,5]==5   ==>   [1, 0, 1, ., 1]*/;

Example 5

Loc( {"a", "fred", "b", "fred"}, "fred" );

Loc Max

Syntax: y = Loc Max( x )

Description: Returns the first position in x of the maximum value.

JMP Version Added: Before version 14

Loc Max( [11 22 33 22 33 11] );

Loc Min

Syntax: y = Loc Min( x )

Description: Returns the first position in x of the minimum value.

JMP Version Added: Before version 14

Loc Min( [11 22 33 22 33 11] );

Loc Nonmissing

Syntax: y = Loc Nonmissing( matrixArg,...,{listArg},... )

Description: Returns a vector of row numbers in argument matrix rows that have no missing values, or for lists, those that are nonmissing numbers or nonempty character.

JMP Version Added: Before version 14

Loc Nonmissing( [1 2 3, 4 . 6, 7 8 ., 8 7 6] );

Loc Sorted

Syntax: idx = Loc Sorted( x, y )

Description: Creates a column vector of subscript positions where the values of x have values less than or equal to the values in y based on a binary search. x must be a matrix sorted in ascending order without missing values.

JMP Version Added: Before version 14

Show(
    Loc Sorted( [11 22 33 44 55], [11 33 55] ),
    Loc Sorted( [11 22 33 44 55], [1] ),
    Loc Sorted( [11 22 33 44 55], [500] )
);

Local

Syntax: y = Local( {name=value, ...}, expression )

Description: Resolves names to local variables.

JMP Version Added: Before version 14

Local( {a = 1, b},
    b = 2;
    a + b;
);

Local Here

Syntax: y = Local Here( expression )

Description: Executes expression with local Names Default To Here(1)

JMP Version Added: Before version 14

y = Local Here(
    a = 1;
    b = 2;
    c = a + b;
    c;
);

Lock Globals

Syntax: Lock Globals( name, ... )

Description: Locks specified global names, preventing them from being modified or being cleared by the Clear Globals function.

JMP Version Added: Before version 14

exalpha = 0.05;
exdelta = 0.5;
Watch( exalpha, exdelta );
Wait( 3 );
Lock Globals( exalpha );
Wait( 3 );
Try( exalpha = 0.06, Show( "invalid - exalpha is locked" ) );
Try( exdelta = 0.6, Show( "invalid - exdelta is locked" ) );
Wait( 3 );
Unlock Globals( exalpha );
Wait( 3 );
Try( exalpha = 0.06, Show( "invalid - exalpha is locked" ) );

Lock Symbols

Syntax: Lock Symbols( name, ... )

Description: Locks specified global names, preventing them from being modified or being cleared by the Clear Symbols function.

JMP Version Added: Before version 14

exalpha = 0.05;
exdelta = 0.5;
Watch( exalpha, exdelta );
Wait( 3 );
Lock Symbols( exalpha );
Wait( 3 );
Try( exalpha = 0.06, Show( "invalid - exalpha is locked" ) );
Try( exdelta = 0.6, Show( "invalid - exdelta is locked" ) );
Wait( 3 );
Unlock Symbols( exalpha );
Wait( 3 );
Try( exalpha = 0.06, Show( "invalid - exalpha is locked" ) );

Log

Syntax: y = Log( x, <b> )

Description: Returns the base-b logarithm of x or the natural logarithm of x if b is not specified.

JMP Version Added: Before version 14

Log( 256, 2 );

Log Capture

Syntax: string = Log Capture( expr )

Description: Evaluates the expr argument and captures the output that would have appeared in the JMP log window and returns it in a string instead.

JMP Version Added: Before version 14

"captured:" || Log Capture(
    For( i = 1, i <= 3, i++,
        Write( Char( i ) );
        Write( " " );
    )
);

Log Table Messages

Syntax: Log Table Messages( <On|Off>, <Enable(subject, ...)>, <Disable(subject, ...)>, <Include(msgname, ...)>, <Exclude(msgname, )>

Description: Control logging of data table messages (such as DtMsgClose). By default logging is off, but all subjects are enabled. (If you turn logging on, you do not need to enable the subjects you're interested in.) Only a subset of all messages are logged. Not available in retail builds.

JMP Version Added: 17

Turn off logging

Log Table Messages( Off );

Turn on logging

Log Table Messages( On );

Turn on logging, and include all messages except "DtMsgClose"

Log Table Messages( On, Exclude( "DtMsgClose" ) );

Turn on logging, and include only the "DtMsgClose" message

Log Table Messages( On, Include( "DtMsgClose" ) );

Turn on logging, but ignore column messages

Log Table Messages( On, Disable( "Column" ) );

Turn on logging, but ignore table messages

Log Table Messages( On );
Log Table Messages( Disable( "Table" ) );

Log10

Syntax: y = Log10( x )

Description: Returns the base 10 logarithm of x.

JMP Version Added: Before version 14

Log10( 100 );

Log1P

Syntax: y = Log1P( x )

Description: Returns a more accurate calculation of Log(1 + x) when x is very small.

JMP Version Added: Before version 14

Log1P( 1e-6 );

LogGenGamma Density

Syntax: y = LogGenGamma Density( x, mu, sigma, lambda )

Description: Returns the density at x of a log generalized gamma probability distribution with parameters mu, sigma, and lambda.

JMP Version Added: Before version 14

mu = 0;
sigma = 1;
lambda = 1;
New Window( "Example: LogGenGamma Density",
    gdey = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -10, 10 ),
        XName( "y" ),
        Pen Color( "red" );
        Y Function( LogGenGamma Density( y, mu, sigma, lambda ), y );
        Text( {-9, 0.9}, "\!U03BC=", Round( mu, 4 ), " \!U03C3=", Round( sigma, 4 ) );
        Text( {-9, 0.8}, "\!U03BB=", Round( lambda, 4 ) );
    ),
    H List Box( Slider Box( -5, 5, mu, gdey << reshow ), Text Box( "\!U03BC" ) ),
    H List Box( Slider Box( 0, 4, sigma, gdey << reshow ), Text Box( "\!U03C3" ) ),
    H List Box( Slider Box( 0, 10, lambda, gdey << reshow ), Text Box( "\!U03BB" ) )
);

LogGenGamma Distribution

Syntax: p = LogGenGamma Distribution( x, mu, sigma, lambda )

Description: Returns the probability that a log generalized gamma distributed random variable (with parameters mu, sigma, and lambda) is less than x.

JMP Version Added: Before version 14

mu = 0;
sigma = 1;
lambda = 1;
New Window( "Example: LogGenGamma Distribution",
    gdey = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -20, 20 ),
        XName( "y" ),
        Pen Color( "red" );
        Y Function( LogGenGamma Distribution( y, mu, sigma, lambda ), y );
        Text( {-9, 0.9}, "\!U03BC=", Round( mu, 4 ), " \!U03C3=", Round( sigma, 4 ) );
        Text( {-9, 0.8}, "\!U03BB=", Round( lambda, 4 ) );
    ),
    H List Box( Slider Box( -5, 5, mu, gdey << reshow ), Text Box( "\!U03BC" ) ),
    H List Box( Slider Box( 0, 4, sigma, gdey << reshow ), Text Box( "\!U03C3" ) ),
    H List Box( Slider Box( 0, 10, lambda, gdey << reshow ), Text Box( "\!U03BB" ) )
);

LogGenGamma Quantile

Syntax: q = LogGenGamma Quantile( p, mu, sigma, lambda )

Description: Returns the quantile from a log generalized gamma distribution (with parameters mu, sigma, and lambda), the value for which the probability is p that a random value would be lower.

JMP Version Added: Before version 14

mu = 0;
sigma = 1;
lambda = 1;
p = 0.4;
New Window( "Example: LogGenGamma Quantile",
    gdey = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -20, 20 ),
        XName( "y" ),
        Pen Color( "red" );
        Y Function( LogGenGamma Distribution( x, mu, sigma, lambda ), x );
        Pen Color( "Blue" );
        V Line( LogGenGamma Quantile( p, mu, sigma, lambda ), 0, 1 );
        Text(
            {-19, 0.9},
            "\!U03BC=",
            Round( mu, 4 ),
            " \!U03C3=",
            Round( sigma, 4 ),
            " \!U03BB=",
            Round( lambda, 4 )
        );
        Text( {-19, 0.8}, "p=", Round( p, 3 ) );
        Text(
            {-19, 0.7},
            "quantile= ",
            Round( LogGenGamma Quantile( p, mu, sigma, lambda ), 2 )
        );
    ),
    H List Box( Slider Box( -2, 2, mu, gdey << reshow ), Text Box( "\!U03BC" ) ),
    H List Box( Slider Box( 0, 4, sigma, gdey << reshow ), Text Box( "\!U03C3" ) ),
    H List Box( Slider Box( 0, 10, lambda, gdey << reshow ), Text Box( "\!U03BB" ) ),
    H List Box( Slider Box( 0.01, 0.99, p, gdey << reshow ), Text Box( " p" ) )
);

Logist

Syntax: y = Logist( x )

Description: Returns 1 / (1 + Exp( -x )), which converts a number in the domain -∞...+∞ into range 0...1. The Logist() function is useful in logistic regression.

JMP Version Added: Before version 14

Logist( 2 );

Logist Percent

Syntax: y = Logist Percent( x )

Description: Logist function with result scaled 0 to 100.

JMP Version Added: Before version 14

Logist Percent( 10 );

Logistic Density

Syntax: y = Logistic Density( x, mu, sigma )

Description: Returns the density at x of a logistic distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = .2;
New Window( "Example: Logistic Density",
    y = Graph Box(
        Y Scale( 0, 2 ),
        X Scale( -10, 10 ),
        Pen Color( "red" );
        Y Function( Logistic Density( x, mu, sig ), x );
        Text( {0, 1.8}, "mu=", Round( mu, 2 ) );
        Text( {0, 1.6}, "sig=", Round( sig, 2 ) );
    ),
    H List Box( Slider Box( -4, 4, mu, y << reshow ), Text Box( "mu" ) ),
    H List Box( Slider Box( 0.01, 2, sig, y << reshow ), Text Box( "sig" ) ), 

);

Logistic Distribution

Syntax: p = Logistic Distribution( x, mu, sigma )

Description: Returns the probability at x of a logistic distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = .2;
New Window( "Example: Logistic Distribution",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -10, 10 ),
        Pen Color( "red" );
        Y Function( Logistic Distribution( x, mu, sig ), x );
        Text( {0.1, 0.9}, "mu=", Round( mu, 2 ) );
        Text( {0.1, 0.8}, "sig=", Round( sig, 2 ) );
    ),
    H List Box( Slider Box( -4, 4, mu, y << reshow ), Text Box( " mu" ) ),
    H List Box( Slider Box( 0.01, 2, sig, y << reshow ), Text Box( " sig" ) )
);

Logistic Quantile

Syntax: q = Logistic Quantile( p, mu, sigma )

Description: Returns the quantile at p of a logistic distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = .2;
qq = .5;
New Window( "Example: Logistic Quantile",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -10, 10 ),
        Pen Color( "red" );
        Y Function( Logistic Distribution( qq, mu, sig ), qq );
        Pen Color( "blue" );
        V Line( Logistic Quantile( qq, mu, sig ), 0, 1 );
        Text(
            {0.1, 0.9},
            " mu=",
            Round( mu, 2 ),
            " sig=",
            Round( sig, 2 ),
            " quantile=",
            Round( qq, 2 )
        );
    ),
    H List Box( Slider Box( -4, 4, mu, y << reshow ), Text Box( " mu" ) ),
    H List Box( Slider Box( 0.01, 2, sig, y << reshow ), Text Box( " sig" ) ),
    H List Box( Slider Box( 0.01, 0.99, qq, y << reshow ), Text Box( " quantile" ) )
);

Logit

Syntax: y = Logit( p )

Description: Returns the logit of p, which is defined as log(p / (1 - p)).

JMP Version Added: Before version 14

Logit( 0.95 );

Logit Percent

Syntax: y = Logit Percent( p )

Description: Logit function with argument 0 to 100, rather than 0 to 1.

JMP Version Added: Before version 14

Logit Percent( 95.0 );

Loglogistic Density

Syntax: y = Loglogistic Density( x, mu, sigma )

Description: Returns the density at x of a loglogistic distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = .2;
New Window( "Example: Loglogistic Density",
    y = Graph Box(
        Y Scale( 0, .06 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( Loglogistic Density( x, mu, sig ), x );
        Text( {0, .055}, "mu=", Round( mu, 2 ) );
        Text( {0, .045}, "sig=", Round( sig, 2 ) );
    ),
    H List Box( Slider Box( 0, 4, mu, y << reshow ), Text Box( "mu" ) ),
    H List Box( Slider Box( 0, 10, sig, y << reshow ), Text Box( "sig" ) ), 

);

Loglogistic Distribution

Syntax: p = Loglogistic Distribution( x, mu, sigma )

Description: Returns the probability at x of a loglogistic distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = .2;
New Window( "Example: Loglogistic Distribution",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( Loglogistic Distribution( x, mu, sig ), x );
        Text( {0.1, 0.9}, "mu=", Round( mu, 2 ) );
        Text( {0.1, 0.8}, "sig=", Round( sig, 2 ) );
    ),
    H List Box( Slider Box( 0, 4, mu, y << reshow ), Text Box( " mu" ) ),
    H List Box( Slider Box( 0, 10, sig, y << reshow ), Text Box( " sig" ) )
);

Loglogistic Quantile

Syntax: q = Loglogistic Quantile( p, mu, sigma )

Description: Returns the quantile at p of a loglogistic distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = .2;
qq = .5;
New Window( "Example: Loglogistic Quantile",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( Loglogistic Distribution( qq, mu, sig ), qq );
        Pen Color( "blue" );
        V Line( Loglogistic Quantile( qq, mu, sig ), 0, 1 );
        Text(
            {0.1, 0.9},
            " mu=",
            Round( mu, 2 ),
            " sig=",
            Round( sig, 2 ),
            " quantile=",
            Round( qq, 2 )
        );
    ),
    H List Box( Slider Box( 0, 4, mu, y << reshow ), Text Box( " mu" ) ),
    H List Box( Slider Box( 0, 10, sig, y << reshow ), Text Box( " sig" ) ),
    H List Box( Slider Box( 0.01, 0.99, qq, y << reshow ), Text Box( " quantile" ) )
);

Lognormal Density

Syntax: y = Lognormal Density( x, mu, sigma )

Description: Returns the density at x of a lognormal distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = 1;
New Window( "Example: Lognormal Density",
    y = Graph Box(
        Y Scale( 0, .15 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( Lognormal Density( x, mu, sig ), x );
        Text( {0, .14}, "mu=", Round( mu, 2 ) );
        Text( {0, .12}, "sig=", Round( sig, 2 ) );
    ),
    H List Box( Slider Box( 0, 4, mu, y << reshow ), Text Box( "mu" ) ),
    H List Box( Slider Box( 0, 2, sig, y << reshow ), Text Box( "sig" ) ), 

);

Lognormal Distribution

Syntax: p = Lognormal Distribution( x, mu, sigma )

Description: Returns the probability at x of a lognormal distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = 1;
New Window( "Example: Lognormal Distribution",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( Lognormal Distribution( x, mu, sig ), x );
        Text( {0.1, 0.9}, "mu=", Round( mu, 2 ) );
        Text( {0.1, 0.8}, "sig=", Round( sig, 2 ) );
    ),
    H List Box( Slider Box( 0, 4, mu, y << reshow ), Text Box( " mu" ) ),
    H List Box( Slider Box( 0, 2, sig, y << reshow ), Text Box( " sig" ) )
);

Lognormal Quantile

Syntax: q = Lognormal Quantile( p, mu, sigma )

Description: Returns the quantile at p of a lognormal distribution with location mu and scale sigma.

JMP Version Added: Before version 14

mu = 0;
sig = 1;
qq = .5;
New Window( "Example: Lognormal Quantile",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( 0, 60 ),
        Pen Color( "red" );
        Y Function( Lognormal Distribution( qq, mu, sig ), qq );
        Pen Color( "blue" );
        V Line( Lognormal Quantile( qq, mu, sig ), 0, 1 );
        Text(
            {0.1, 0.9},
            " mu=",
            Round( mu, 2 ),
            " sig=",
            Round( sig, 2 ),
            " quantile=",
            Round( qq, 2 )
        );
    ),
    H List Box( Slider Box( 0, 4, mu, y << reshow ), Text Box( " mu" ) ),
    H List Box( Slider Box( 0, 3, sig, y << reshow ), Text Box( " sig" ) ),
    H List Box( Slider Box( 0.01, 0.99, qq, y << reshow ), Text Box( " quantile" ) )
);

Long Date

Syntax: s = Long Date( datetime, <format> )

Description: Returns a long locale-specific representation of a date-time value.

JMP Version Added: Before version 14

Long Date( Today() );

Low Rank Symmetric Update BLAS

Syntax: y = Low Rank Symmetric Update BLAS( A, U, s )

JMP Version Added: 17

A = [2 0, 0 2];
U = [2 4, 3 5];
s = 2.5;
AUpdate = Low Rank Symmetric Update BLAS( A, U, s );

Lowercase

Syntax: sl = Lowercase( s )

Description: Converts uppercase letters to lowercase letters in the specified string. Rules for upper and lower case are locale dependent.

JMP Version Added: Before version 14

Lowercase( "CAFÉ #23" );

LPSolve

Syntax: {x, z} = LPSolve( A, b, c, L, U, neq, nle, nge, <slackVars=0> )

Description: Minimizes the objective function subject to the given constraints and returns a list of two items. The first list item, x, contains the decision variables (and slack variable values if slackVars=1). The second list item, z, contains optimal objective function value (if one exists). The first five arguments are matrices. The A argument is the matrix of constraint coefficients. The b argument is the column of right hand side values of the constraints. The c argument is the vector of cost coefficients of the objective function. The L and U arguments are the lower and upper bounds for the variables, respectively. The neq, nle, and nge arguments are the number of equality constraints, less than or equal constraints, and greater than or equal constraints, respectively. Note that the constraints must be listed as equality first, less than or equal next, and greater than or equal last.

JMP Version Added: Before version 14

A = [5 -2 6, 2 4 0, 3 8 -4];
b = [17, 19, 14];
c = [9 6 -4];
L = [. 0 .];
U = [0 . .];
{x, z} = LPSolve( A, b, c, L, U, 1, 1, 1, 1 );
Show( x, z );

Mail

Syntax: Mail( "address", "subject", "message", <"attachment filepath"> | { "attachment filepath", ...} )

Description: Creates an outgoing e-mail message as specified if the operating system allows doing so. Not all options will work on all operating system versions. See Help for details.

JMP Version Added: Before version 14

Mail( "test@example.com", "revelation", "JMP is great.", "$SAMPLE_DATA/Big Class.jmp" );

Main Menu

Syntax: menu = Main Menu( command, <window name> )

Description: Executes the specified main menu command.

JMP Version Added: Before version 14

Example 1

Main Menu( "Sample Index" );

Example 2

Main Menu( "Help:Sample Index" );

Make KFold Formula

Syntax: y = Make KFold Formula( folds, Y Columns( cols ), <<Stratification Columns( cols ), <<Grouping Columns( cols ) )

Description: Generates a validation column with folds levels when used in a column formula. This JSL function is primarily used by the Make Validation Column platform to generate formula columns.

JMP Version Added: 17

Example 1

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << New Column( "KFold Validation",
    "Numeric",
    "Nominal",
    Formula( Make KFold Formula( 5, <<Y Columns( :height ) ) )
);

Example 2

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << New Column( "Stratified KFold",
    "Numeric",
    "Nominal",
    Formula(
        Make KFold Formula( 4, <<Y Columns( :height ), <<Stratification Columns( :sex ) )
    )
);

Make Validation Formula

Syntax: y = Make Validation Formula( rates, <<Stratification Columns( cols ), <<Grouping Columns( cols ), <<Cutpoint Column ( col ), <<Cutpoint Batch ID( col ), <<Determine cutpoints using( "Proportions"|"Numbers of Rows"|"Fixed Time or Date"|"Elapsed Time" ), <<Assign Extra Rows( "To Training"|"To Validation"|"To Test" ) )

Description: Generates a two-level or three-level validation column when used in a column formula. The rates argument is a 3 by 1 matrix that contains the training, validation, and test rates, respectively. This JSL function is primarily used by the Make Validation Column platform to generate formula columns.

JMP Version Added: 15

Example 1

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << New Column( "Validation",
    "Numeric",
    "Nominal",
    Formula( Make Validation Formula( [.6, .4, 0] ) ),
    Set Property( "Value Labels", {0 = "Training", 1 = "Validation"} )
);

Example 2

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << New Column( "Validation",
    "Numeric",
    "Nominal",
    Formula( Make Validation Formula( [.6, .2, .2], <<Stratification Columns( :age ) ) ),
    Set Property( "Value Labels", {0 = "Training", 1 = "Validation", 2 = "Test"} )
);

Example 3

dt = Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "Validation",
    "Numeric",
    "Nominal",
    Formula(
        Make Validation Formula(
            [20, 10, 4],
            <<Cutpoint Column( :Week of Year ),
            <<Cutpoint Batch ID( :ID ),
            <<Determine cutpoints using( "Numbers of Rows" )
        )
    ),
    Set Property( "Value Labels", {0 = "Training", 1 = "Validation", 2 = "Test"} )
);

Mandelbrot

Syntax: v = Mandelbrot( n, radius, x, y )

Description: calculates the value of the Mandelbrot function at x,y, stopping after n iterations or when radius exceeded

JMP Version Added: Before version 14

grid = 50;
rmax = 0/*zero for smooth*/;
nmax = 50;// http://wikipedia.org/wiki/Mandelbrot_set 
New Window( "Mandelbrot - use magnifier to zoom in",
    g = Graph Box(
        X Scale( -3, 3 ),
        Y Scale( -2, 2 ),
        framesize( 600, 400 ),
        Gradient Function(
            Mandelbrot( nmax, rmax, a, b ), // return value: number of iterations before something interesting happened
            a, // standard GradientFunction stuff...
            b,
            Matrix( {0, nmax} ), // range to map the colors onto
            Z Color(
                {RGB Color( 0, 0, 0 ), RGB Color( 1, 0, 0 ), RGB Color( 1, 1, 0 ),
                RGB Color( 0, 1, 0 ), RGB Color( 0, 1, 1 ), RGB Color( 0, 0, 1 ),
                RGB Color( .3, .3, .4 )}
            ),
            <<xgrid(
                X Origin(), X Origin() + X Range(),
                X Range() / (Floor( grid * H Size() / V Size() ))
            ),
            <<ygrid( Y Origin(), Y Origin() + Y Range(), Y Range() / (Floor( grid )) ), 

        )
    ),
    H List Box( Slider Box( 2, 500, nmax, g << reshow ), Global Box( nmax ) ),
    H List Box( Slider Box( 0, 5, rmax, g << reshow ), Global Box( rmax ) ),
    H List Box( Slider Box( 2, 500, grid, g << reshow ), Global Box( grid ) ), 

);
g << Set X Axis(
    {Format( "Best", 15 ), Show Major Ticks( 0 ), Rotated Labels( "Parallel" )}
);
g << Set Y Axis(
    {Format( "Best", 15 ), Show Major Ticks( 0 ), Rotated Labels( "Parallel" )}
);

Map Value

Syntax: Map Value(string | number, {key1, value1...|{key1...},{value1...}}, <Unmatched(value)>)

Description: Evaluate the initial value and return the mapped result or a default.

JMP Version Added: 15

Example 1

Map Value( "celry", {"celry", "celery"} );

Example 2

Map Value( "carrot", {"celry", "celery"}, Unmatched( "not found" ) );

Example 3

Map Value( 10, {10, "celery", 11, "banana"} );

Example 4

Map Value( 10, {{1, 2, 3}, {100, 200, 300}} );

Marker

Syntax: Marker( <rs>, {x1, y1}, {x2, y2}, ... ); Marker( <rs>, xMatrix, yMatrix )

Description: Draws markers at the indicated coordinates.

JMP Version Added: Before version 14

New Window( "Example", Graph Box( Marker( Marker State( 3 ), [11 44 77], [75 25 50] ) ) );

Marker Of

Syntax: y = Marker Of( <rs> ); Marker Of( <Row State( <r> )> ) = y

Description: Returns the marker component of the specified row state value. If Marker Of is used as an L-value, it changes the marker of the current (or rth) row in the current data table.

JMP Version Added: Before version 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
Row State( 3 ) = Marker State( 5 );
Marker Of( Row State( 3 ) );
Row() = 3;
Marker Of();

Marker Seg

Syntax: me = Marker Seg( x, y, < Row States( dt | dt,[rows] | dt,{{rows}, ...} | {states} ) >, < Sizes( s ) > )

Description: Returns a display seg with markers for all of the x and y values.

JMP Version Added: Before version 14

Example 1

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
xx = Column( "height" ) << Get Values;
sz = Column( "age" ) << get values;
aa = [=> 0];
yy = J( N Rows( xx ), 1, 0 );
For( ii = 1, ii <= N Rows( xx ), ii++,
    aa[xx[ii]]++;
    yy[ii] = aa[xx[ii]];
);
New Window( "Marker Seg Example",
    g = Graph Box(
        Frame Size( 300, 120 ),
        X Scale( Min( xx ) - 5, Max( xx ) + 5 ),
        Y Scale( 0, 10 ),
        Marker Seg( xx, yy, Row States( dt ), sizes( sz ) )
    )
);

Example 2

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
xx = [1 2 3 4 5];
yy = [2 3 4 5 6];
New Window( "Marker Seg Example",
    g = Graph Box(
        Frame Size( 300, 120 ),
        X Scale( Min( xx ) - 5, Max( xx ) + 5 ),
        Y Scale( 0, 10 ),
        Marker Seg( xx, yy, Row States( dt, {3, 4, 11, 7, 13} ) )
    )
);

Example 3

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
xx = [1 2 3 4 5];
yy = [2 3 4 5 6];
New Window( "Marker Seg Example",
    g = Graph Box(
        Frame Size( 300, 120 ),
        X Scale( Min( xx ) - 5, Max( xx ) + 5 ),
        Y Scale( 0, 10 ),
        Marker Seg( xx, yy, Row States( dt, 11 :: 15 ) )
    )
);

Example 4

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
xx = [1 2 3 4 5];
yy = [2 3 4 5 6];
New Window( "Marker Seg Example",
    g = Graph Box(
        Frame Size( 300, 120 ),
        X Scale( Min( xx ) - 5, Max( xx ) + 5 ),
        Y Scale( 0, 10 ),
        Marker Seg(
            xx,
            yy,
            Row States( dt, {{1, 2, 3}, {4, 5}, {6}, {7, 12, 15, 9}, {21, 8}} )
        )
    )
);

Example 5

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
xx = [1 2 3 4 5];
yy = [2 3 4 5 6];
New Window( "Marker Seg Example",
    g = Graph Box(
        Frame Size( 300, 120 ),
        X Scale( Min( xx ) - 5, Max( xx ) + 5 ),
        Y Scale( 0, 10 ),
        Marker Seg(
            xx,
            yy,
            Row States(
                {Color State( "Blue" ), Color State( "Orange" ), Color State( "Green" ),
                Color State( "Purple" ), Color State( "Red" )}
            )
        )
    )
);

Marker Size

Syntax: Marker Size( n )

Description: Sets the size markers are drawn in the graphics frame. 0 = dot, 1 = small, ....

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Marker Size( 5 );
        Marker( Marker State( 3 ), [11 44 77], [75 25 50] );
    )
);

Marker State

Syntax: rs = Marker State( marker )

Description: Returns a row state value with the marker component set to the specified value. The marker argument specifies a marker and can be a positive integer, a character, a positive integer for Unicode character, or a hex character for Unicode character.

JMP Version Added: Before version 14

Open( "$SAMPLE_DATA/Big Class.jmp" );
Row State( 3 ) = Marker State( 5 );
Marker Of( Row State( 3 ) );

Match

Syntax: y = Match( x, v1, expr1, v2, expr2, ..., exprElse )

Description: Evaluates and returns the exprN argument corresponding to the first vN argument that equals x or evaluates and returns the exprElse argument if no value equals x.

JMP Version Added: Before version 14

Match( Year( Today() ), 2013, "snake", 2014, "horse", 2015, "goat", "other" );

MatchMZ

Syntax: y = MatchMZ( x, v1, expr1, v2, expr2, ..., exprElse )

Description: Evaluates and returns the exprN argument corresponding to the first vN argument that equals x or evaluates and returns the exprElse argument if no value equals x. (The MatchMZ() function behaves the same as the Match() function, except that missing values are treated as 0.)

JMP Version Added: Before version 14

MatchMZ( Year( Today() ), 2013, "snake", 2014, "horse", 2015, "goat", "other" );

Matrix

Syntax: y = Matrix( {{x11, ..., x1m}, {...}, {xn1, ..., xnm}} )y = Matrix( {x1, ..., xn} )y = Matrix( n, m )

Description: Constructs an n-by-m matrix. If you specify a list of n lists that each contain m row values, the matrix is formed by vertically concatenating the evaluated lists. If you specify a single list of n items, the return value is an n-by-1 column vector. If you specify two integer arguments, the return value is a matrix of zeros that contains n rows and m columns.

JMP Version Added: Before version 14

Example 1

Matrix( {{11, 22, 33}, {44, 55, 66}} );

Example 2

Matrix( {{[1 2 3], 4, 5, 6, 7, 8, 9}} );

Example 3

Matrix( {2, 3 + 7} );

Example 4

Matrix( 2, 3 );

Matrix Box

Syntax: y = Matrix Box( matrix, < <<Column Names( "c1", "c2", ... )>, < <<Row Names( "r1", "r2", ... )> )

Description: Returns a display box to show a matrix of numbers.

JMP Version Added: Before version 14

New Window( "Example", Matrix Box( [11 22 33, 44 55 66], <<RowNames( "First", "Second" ) ) );

Matrix Mult

Syntax: y = Matrix Mult( A, B, ... ); y = A * B

Description: Performs matrix multiplication. The matrix arguments must be conformable: NCol(a)==NRow(b). Note that A * B also works.

JMP Version Added: Before version 14

exMatA = [1 2 3, -2 0 -1, 0 1 1];
exMatB = [1 2, 1 2, 1 2];
exMatM1 = exMatA * exMatB;
exMatM2 = Matrix Mult( exMatA, exMatB );
exMatC = [1 2, 1 2];
exMatM3 = Matrix Mult( exMatA, exMatB, exMatC );
Show( exMatM1 );
Show( exMatM2 );
Show( exMatM3 );

Matrix Mult BLAS

Syntax: y = Matrix Mult BLAS( A, B, ... )

Description: Performs matrix multiplication. The matrix arguments must be conformable: NCol(A)==NRow(B).

JMP Version Added: 17

exMatA = [1 2 3, -2 0 -1, 0 1 1];
exMatB = [1 2, 1 2, 1 2];
exMatM2 = Matrix Mult BLAS( exMatA, exMatB );

Matrix Rank

Syntax: r = Matrix Rank( X )

Description: Returns the rank of the matrix X.

JMP Version Added: 14

Matrix Rank( [1 0 0, 0 1 0, 0 1 0] );

Matrix To Blob

Syntax: m = Matrix To Blob( matrix, type, bytesEach, endian )

Description: Makes a blob from a matrix by converting the matrix elements to 1, 2, or 4 byte signed or unsigned integers or 4 or 8 byte floating point numbers.

JMP Version Added: Before version 14

Matrix To Blob( [3.14, 1.414], "float", 4, "big" );

Max

Syntax: y = Max( x1, ... ); y = Maximum( x1, ... )

Description: Returns the maximum value among the arguments or of the values within a single matrix or list argument.

JMP Version Added: Before version 14

Eval List( {Max( Pi(), e() ), Max( [33 44 22] )} );

Maximize

Syntax: Maximize( expr, {x1, x2, ...} );Maximize( expr, {x1( low1, up1 ), x2( low2, up2 ), ...}, <<MaxIter( 250 ), <<Tolerance( .00000001 ), <<details(both | returnDetails | displaySteps), <<gradient(), <<hessian(), method(NR | SR1), <<useNumericDeriv(True))

Description: Finds values for the function's arguments, given in the list {x1, x2, ...}, that maximize the expr expression. You can specify lower and upper bounds for each argument in parentheses following the argument's name. If expr is not a concave function, Maximize might find a local maximum rather than the global maximum. If this is a concern, try multiple starting values. Also, Maximize works best for functions with a continuous second derivative. Additional arguments for the Maximize function enable you to set the maximum number of iterations, tolerance for convergence, and view more details about the optimization. Click the Topic Help button for more information about the optional arguments.

JMP Version Added: Before version 14

Example 1

/*Simple example*/ 
x = 0;
y = 0;
maxf = Maximize( ((2 * x ^ 2 + 12 * x * y - y * 3)), {x, y} );
Eval List( {x, y, maxf} );

Example 2

/*Find the MLE for a Normal Distribution with a random sample of 3 observations*/
x = [3 4 5]; /* observed values*/ 
n = 3;
logDens = Expr(
    (-n / 2) * Log( 2 * Pi() * sigSq ) - Summation( i = 1, 3, ((x[i] - mu) ^ 2) ) / (2 *
    sigSq)
);
mu = 3;
sigSq = 1;/*initial values*/ 
{maxReached, iters, gradient, hessian} = Maximize(
    logDens,
    {mu, sigSq( 0, . )},
    <<details( both )
);

Example 3

/*Simple example with all optional arguments*/ 
x = 0;
y = 0;
{objVal, iters, gradient, hessian} = Maximize(
    ((2 * x ^ 2 + 12 * x * y - y * 3)),
    {x( -1, 1 ), y( -1, 1 )},
    <<maxIter( 200 ),
    <<tolerance( 10 ^ -6 ),
    <<details( both )
);

Maximum

Syntax: y = Max( x1, ... ); y = Maximum( x1, ... )

Description: Returns the maximum value among the arguments or of the values within a single matrix or list argument.

JMP Version Added: Before version 14

Eval List( {Max( Pi(), e() ), Max( [33 44 22] )} );

MDYHMS

Syntax: s = MDYHMS( datetime, <format> )

Description: Returns a representation of a date-time value with the ordering: month, day, year, hour, minute, second.

JMP Version Added: Before version 14

MDYHMS( Today() );

Mean

Syntax: y = Mean( x1, ... )

Description: Returns the arithmetic mean of the arguments or of the values within a single matrix or list argument.

JMP Version Added: Before version 14

Eval List( {Mean( Pi(), e() ), Mean( [33 44 22 20 30] )} );

Median

Syntax: y = Median( x1, ... )

Description: Returns the median of the combined arguments, which can be scalar, matrix or list arguments.

JMP Version Added: 15

Median( [1.2, 1.5, 10, 25, 31, 40, 50, 99, 1000, 5000, 25000, 100000] );

Method

Syntax: m = Method( { arg1 = val1, ... }, expression* )

Description: Create a Method within a Class

JMP Version Added: Before version 14

Define Class(
    "complex",
    real = 0;
    imag = 0;
    _init_ = Method( {a, b},
        real = a;
        imag = b;
    );
    Add = Method( {y},
        New Object( complex( real + y:real, imag + y:imag ) )
    );
    Sub = Method( {y},
        New Object( complex( real - y:real, imag - y:imag ) )
    );
    Mul = Method( {y},
        New Object( complex( real * y:real - imag * y:imag, imag * y:real + real * y:imag ) )
    );
    Div = Method( {y},
        t = New Object( complex( 0, 0 ) );
        mag2 = y:Magsq();
        t:real = real * y:real + imag * y:imag;
        t:imag = imag * y:real + real * y:imag;
        t:real = t:real / mag2;
        t:imag = t:imag / mag2;
        t;
    );
    Magsq = Method( {},
        real * real + imag * imag
    );
    Mag = Method( {},
        Sqrt( real * real + imag * imag )
    );
    _to string_ = Method( {},
        Char( real ) || " + " || Char( imag ) || "i"
    );
    _show_ = _to string_;
);
cl = New Object( complex( 1, 2 ) );
cl << Delete;
Delete Classes( "complex" );

Mimic

Syntax: mimic obj = Mimic(Box|PlatformRef)

Description: Creates a GUI automation object that mimics a real user. ONLY AVAILABLE IN INTERNAL JMP BUILDS.

JMP Version Added: 18

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
obj = dt << Oneway( Y( :height ), X( :age ) );
outline = Report( obj )[Outline Box( 1 )];
mc = Mimic( obj );
mc << Mark( outline );
mc << Mouse Click( Offset( TopLeft( outline ), [25 15] ) );

Min

Syntax: y = Min( x1, ... ); y = Minimum( x1, ... )

Description: Returns the minimum value among the arguments or of the values within a single matrix or list argument.

JMP Version Added: Before version 14

Eval List( {Min( Pi(), e() ), Min( [33 44 22] )} );

Minimize

Syntax: Minimize( expr, {x1, x2, ...} );Minimize( expr, {x1( low1, up1 ), x2( low2, up2 ), ...}, <<MaxIter( 250 ), <<Tolerance( .00000001 ), <<details(both | returnDetails | displaySteps), <<gradient(), <<Hessian(), <<method(NR | SR1), <<useNumericDeriv(True))

Description: Finds values for the function's arguments, given in the list {x1, x2, ...}, that minimize the expr expression. You can specify lower and upper bounds for each argument in parentheses following the argument's name. If expr is not a convex function, Minimize might find a local minimum rather than the global minimum. If this is a concern, try multiple starting values. Also, Minimize works best for functions with a continuous second derivative. Additional arguments for the Minimize function enable you to set the maximum number of iterations, tolerance for convergence, and view more details about the optimization. Click the Topic Help button for more information about the optional arguments.

JMP Version Added: Before version 14

Example 1

/*Simple Example*/
x = 0;
y = 0;
minFun = Minimize( (y * 3 - 2 * x ^ 2 - 12 * x * y), {x, y} );
Eval List( {x, y, minFun} );

Example 2

/*Nonlinear Sums of Squares Example*/
x = [1.309, 1.471, 1.49, 1.565, 1.611, 1.68];
y = [2.138, 3.421, 3.597, 4.34, 4.882, 5.66];
sseExpr = Expr(
    Summation( i = 1, 6, (y[i] - b1 * x[i] ^ b2) ^ 2 )
);
b1 = 1;
b2 = 5;
{objVal, iters, gradient, hessian} = Minimize(
    sseExpr,
    {b1, b2},
    <<details( both ),
    <<tolerance( 10 ^ -16 )
);

Example 3

/*Simple example with some optional arguments*/
x = 0;
y = 0;
{objVal, iters, gradient, hessian} = Minimize(
    ((2 * x ^ 2 + 12 * x * y - y * 3)),
    {x( -1, 1 ), y( -1, 1 )},
    <<maxIter( 200 ),
    <<tolerance( 10 ^ -6 ),
    <<details( both )
);

Example 4

/*Example with gradient, hessian, and method(nr) options*/
xx = [1.309, 1.471, 1.49, 1.565, 1.611, 1.68];
yy = [2.138, 3.421, 3.597, 4.34, 4.882, 5.66];
tmp3 = Expr(
    Summation( i = 1, 6, (yy[i] - b1 * xx[i] ^ b2) ^ 2 )
);
b1 = 1;
b2 = 5;
Minimize(
    tmp3,
    {b1, b2},
    <<details( both ),
    <<tolerance( 10 ^ -10 ),
    <<Method( nr ),
    <<gradient(
        {Summation( i = 1, 6, -2 * xx[i] ^ b2 * (yy[i] - b1 * xx[i] ^ b2) ),
        Summation(
            i = 1,
            6,
            2 * (b1 * Ln( xx[i] ) * xx[i] ^ b2) * (b1 * xx[i] ^ b2 - yy[i])
        )}
    ),
    <<hessian(
        {{Summation( i = 1, 6, 2 * xx[i] ^ (2 * b2) ),
        Summation( i = 1, 6, 2 * Ln( xx[i] ) * xx[i] ^ b2 * (2 * b1 * xx[i] ^ b2 - yy[i]) )},
        {Summation(
            i = 1,
            6,
            2 * b1 * Ln( xx[i] ) ^ 2 * xx[i] ^ b2 * (2 * b1 * xx[i] ^ b2 - yy[i])
        )}}
    )
);

Example 5

/*Example with usNumericDeriv and method(sr1) options*/
xx = [1.309, 1.471, 1.49, 1.565, 1.611, 1.68];
yy = [2.138, 3.421, 3.597, 4.34, 4.882, 5.66];
tmp3 = Expr(
    Summation( i = 1, 6, (yy[i] - b1 * xx[i] ^ b2) ^ 2 )
);
b1 = 1;
b2 = 5;
{objValue, iter, gradient, hessian} = Minimize(
    tmp3,
    {b1, b2},
    <<details( both ),
    <<tolerance( 10 ^ -16 ),
    <<Method( sr1 ),
    <<useNumericDeriv( True )
);

Minimum

Syntax: y = Min( x1, ... ); y = Minimum( x1, ... )

Description: Returns the minimum value among the arguments or of the values within a single matrix or list argument.

JMP Version Added: Before version 14

Eval List( {Min( Pi(), e() ), Min( [33 44 22] )} );

Minus

Syntax: y = -x; y = Minus( x )

Description: Negates x, which can be a number, matrix, or list of numbers.

JMP Version Added: Before version 14

-Pi();

Minute

Syntax: min = Minute( datetime )

Description: Returns the minutes part of a date-time value, 0 - 59.

JMP Version Added: Before version 14

Minute( Today() );

Mod

Syntax: z = Modulo( x, y )

Description: Returns the remainder from dividing x by y. The remainder has the same sign as x.

JMP Version Added: Before version 14

Modulo( 10, 3 );

Mode

Syntax: y = Mode( list or matrix )

Description: Picks the 'most frequent' item from a matrix or list, the lower value for ties

JMP Version Added: Before version 14

Show( Mode( [1, 2, 3, 2, 1] ), Mode( {"a", "b", "c", "b", "a", "b"} ) );

Modified Internal Rate of Return

Syntax: x = Modified Internal Rate of Return( values, finance_rate, reinvest_rate );x = Modified Internal Rate of Return( finance_rate, reinvest_rate, value1, value2, <value3, ...> )

Description: Returns the modified internal rate of return for a series of periodic cash flows, taking into account both the cost of the investment and the interest received on reinvestment of cash. Equivalent to the MIRR function in Microsoft Excel. The second prototype of the function accepts all scalar arguments.

JMP Version Added: Before version 14

Modified Internal Rate of Return( [-10000, 1000, 900, 950], .1, -.12 );
Modified Internal Rate of Return( .1, -.12, -10000, 1000, 900, 950 );

Modulo

Syntax: z = Modulo( x, y )

Description: Returns the remainder from dividing x by y. The remainder has the same sign as x.

JMP Version Added: Before version 14

Modulo( 10, 3 );

Month

Syntax: mon = Month( datetime )

Description: Returns the month part of a date-time value, 1 - 12.

JMP Version Added: Before version 14

Month( Today() );

MouseBox

Syntax: box = MouseBox( displayBoxArgs )

Description: Returns a box that can make JSL callbacks for mouse actions

JMP Version Added: Before version 14

New Window( "Example",
    MouseBox(/*first sibling*/Text Box( "drag from here" ),
        <<setDragText( "hello" ),
        <<setTooltip( "source" ),
        <<setDragEnable( 1 ),
        <<setDragBegin(/* decide if a drag is allowed */
            Function( {this, clickpt},
                "magic text";/* 0.0 to prevent the drag.  1.0 is the same as 'this<<getDragText' */
            )
        ),
        <<setDragEnd(/* clean up after a drag finishes or cancels */
            Function( {this, clickpt, how}, /* how=move,copy,ignore */
                If(
                    how != "ignore" & !Is Empty( this << getDestBox ) & this << getDestBox
                     == this << sib, /* the getDestBox check makes sure the destination of the drag-and-drop was my sibling and not some other program beyond our control */
                    (this << child) << setText(
                        "done!" /* 'move' suggests clearing the source */
                    )
                )
            )
        )
    ),
    MouseBox(/*second sibling*/Text Box( "drag to here" ),
        <<setTooltip( "destination" ),
        <<setDropEnable( 1 ),
        <<setDropTrack(/* decide if dropping is allowed, before the drop.  The getSourceBox check makes sure the source of the drag-and-drop is my sibling, and not some other program */
            Function( {this, clickpt},
                If( !Is Empty( this << getSourceBox ) & this == (this << getSourceBox) << sib,
                    1, /*else*/0
                )
            )
        ),
        <<setDropCommit(/* accept the drop */Function( {this, clickpt, text},
                (this << child) << setText( text )
            )
        )
    )
);

Mousetrap

Syntax: Mousetrap( dragScript, <mouseUpScript> )

Description: Evaluates the dragScript expression repeatedly while the mouse is pressed within the graph and not handled by another graph object. Before running the script, the globals x and y are set to the mouse value and are restored to their original values afterward. The mouseUpScript expression is run after the mouse button is released.

JMP Version Added: Before version 14

New Window( "Example",
    exx = 20;
    exy = 50;,
    Graph Box(
        Frame Size( 200, 200 ),
        Mousetrap(
            exx = x;
            exy = y;
        );
        Circle( {0, 0}, Sqrt( exx * exx + exy * exy ) );
    )
);

Move Directory

Syntax: rc = Move Directory( from, to )

Description: Moves a directory from one place to another. Returns 1 if the directory was moved. Returns 0 if the directory was unable to be moved. Throws an error if the path is invalid or does not exist.

JMP Version Added: Before version 14

Delete Directory( "$TEMP/subB" );
Delete Directory( "$TEMP/Loss Function Templates" );
rc0 = Copy Directory( "$SAMPLE_DATA/Loss Function Templates", "$TEMP" );
Create Directory( "$TEMP/subB" );
rc1 = Move Directory( "$TEMP/Loss Function Templates", "$TEMP/subB" );
rc2 = Directory Exists( "$TEMP/Loss Function Templates" );
rc3 = Directory Exists( "$TEMP/subB" );
rc4 = Delete Directory( "$TEMP/subB" );
rc5 = Directory Exists( "$TEMP/subB" );
Char( rc0 ) || " " || Char( rc1 ) || " " || Char( rc2 ) || " " || Char( rc3 ) || " " ||
Char( rc4 ) || " " || Char( rc5 );/* 1 1 0 1 1 0 */

Move File

Syntax: rc = Move File( from, to )

Description: Moves a file from one place to another. Returns 1 if the file was moved. Returns 0 if the file was unable to be moved. Throws an error when the path is invalid or does not exist.

JMP Version Added: Before version 14

If( File Exists( "$TEMP/y.jmp" ),
    Delete File( "$TEMP/y.jmp" )
);
rc0 = Copy File( "$SAMPLE_DATA/Loss Function Templates/Normal.jmp", "$TEMP/x.jmp" );
rc1 = Move File( "$TEMP/x.jmp", "$TEMP/y.jmp" );
rc2 = File Exists( "$TEMP/x.jmp" );
rc3 = File Exists( "$TEMP/y.jmp" );
rc4 = Delete File( "$TEMP/y.jmp" );
rc5 = File Exists( "$TEMP/y.jmp" );
Char( rc0 ) || " " || Char( rc1 ) || " " || Char( rc2 ) || " " || Char( rc3 ) || " " ||
Char( rc4 ) || " " || Char( rc5 );/* 1 1 0 1 1 0 */

Move to Project

Syntax: Move to Project(<Source(project)>, <Destination(project)>, <Windows({list of windows to move})>)

Description: Moves one or more windows into a project, out of a project, or between projects. Only one of Source and Destination must be specified; the other will default to the current project. (Use only Source to move windows into the current project, and only Destination to move windows out of it.) A data table window will be moved together with its dependent reports, though only one need be specified in the Windows argument. If omitted, the Windows argument defaults to all open windows in the source project.

JMP Version Added: 14

Example 1

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
report = dt << Run Script( "Bivariate" );

project = New Project();

Move to Project( destination( project ), windows( {report} ) );

Example 2

project = Open( "$SAMPLE_PROJECTS/Sports.jmpprj" );
Move to Project( Source( project ) );
project << Close Window();

Moving Average

Syntax: y = Moving Average( x, weighting, <before=-1>, <after=0>, <partial window is missing=0> )

Description: Returns a matrix of moving averages for the input matrix. before and after determine the range ("window") of items to average, where before can be -1 to indicate all prior items. If weighting is 1, all items have equal weight. If weighting is 0, items have linearly incremental weights. Otherwise, weighting is the parameter for exponential weighting (EWMA). partial window is missing indicates whether averages are reported when not all neighbors are present, which can occur at the ends or near missing values. If partial window is missing is nonzero, missing values are reported instead for such partial windows.

JMP Version Added: Before version 14

Eval List(
    {Moving Average( [1 2 1 2 3 4 9 9 9 9 9], 1, 3 ),
    Moving Average( [1 2 1 2 3 4 9 9 9 9 9], 0, 2, 2 ),
    Moving Average( [1 2 1 2 . 4 9 9 9 9 9], 1, 1, 1, 1 ),
    Moving Average( [1 2 1 2 3 4 9 9 9 9 9], 0.5 )}
);

Multiple File Import

Syntax: mfiObj = Multiple File Import();

Description: Creates a Multiple File Import object; the object accepts messages to set a folder, filter files, and import. To bring up a dialog use the "Create Window" message. To immediately import use the "Import Data" message which will return a list of the tables that were created.

JMP Version Added: 14

Interactive example

// use the save-script-to-script-window button 
// in the MFI dialog to see more messages
// for filtering files and controlling the import
Multiple File Import(
    <<Set Folder( "$DESKTOP" ),
    <<Set Name Filter( "*.csv;" ),
    <<Set Name Enable( 1 )
) << Create Window;

Scripting example

mfi = Multiple File Import();
mfi << Set Folder( "$SAMPLE_IMPORT_DATA" );
mfi << Set Name Filter( "*.txt" );
mfi << Set Name Enable( 1 );
tables = mfi << Import Data();

Multiply

Syntax: y = x0 * x1; y = Multiply( x0, x1, ... )

Description: Multiplies all arguments, which can be numbers, matrices, or lists of numbers.

JMP Version Added: Before version 14

2 * Pi();

Multiply To

Syntax: y *= x; Multiply To( y, x )

Description: Multiplies a value to a variable or to a list of variables.

JMP Version Added: Before version 14

ex = 3;
ex *= 2;
ex;

Multivariate Normal Impute

Syntax: y = Multivariate Normal Impute( yVec, meanYvec, symCovMat, colMin, colMax )

Description: Returns a response vector with imputed values for the missing values in the yVec vector of responses. Imputations are based on a multivariate normal distribution with mean vector meanYvec and symmetric covariance matrix symCovMat. Optional arguments colMin and colMax are the respective vectors of column minimums and maximums. These arguments provide bounds for the imputations.

JMP Version Added: Before version 14

mat = [0.430735257211985 -0.935632420013493 . 0.424649913158299,
. -0.687720061441453 0.29665732536624 -1.94898001941576,
-0.0425472526673373 0.463229145080277 0.635619352779951 .];
cov = Covariance( mat, <<"Pairwise"/*, <<"shrink"*/ );
colMean = V Mean( mat );
colMin = V Min( mat );
colMax = V Max( mat );
For( it = 1, it <= N Row( mat ), it++,
    mat[it, 0] = Multivariate Normal Impute( mat[it, 0], colMean, cov, colMin, colMax )`
);
Print( mat );

Munger

Syntax: r = Munger( s, startPos, findStringOrNChars, <replaceString> )

Description: Searches the s argument for a substring or position depending on combination of arguments.

JMP Version Added: Before version 14

Eval List( {Munger( "over there", 1, "t", "" ), Munger( "17 June 2000", 4, 4, "March" )} );

N Arg

Syntax: n = N Arg( expr )

Description: Returns the number of arguments of the evaluated expression head.

JMP Version Added: Before version 14

N Arg( Expr( Sum( a, b, c ) ) );

N Arg Expr

Syntax: n = N Arg Expr( expr )

Description: Returns the number of arguments of the expression head. This function is deprecated. Please use N Arg() instead.

JMP Version Added: Before version 14

Example 1

// See Example 2 for the deprecated N Arg Expr() equivalent
N Arg( Expr( Sum( a, b, c ) ) );

Example 2

// Deprecated
N Arg Expr( Sum( a, b, c ) );

N Choose K

Syntax: m = N Choose K( n, k )

Description: Returns n! / (k! * (n - k)!), which is the number of ways to choose k items out of n, ignoring order.

JMP Version Added: Before version 14

N Choose K( 5, 3 );

N Col

Syntax: y = N Col(); y = N Col( dataTable ); y = N Col( matrix )

Description: Returns the number of columns in the current data table, a specified data table, or a matrix.

JMP Version Added: Before version 14

N Col( [11 22, 33 44] );

N Cols

Syntax: y = N Cols(); y = N Cols( dataTable ); y = N Col( matrix )

Description: Returns the number of columns in the current data table, a specified data table, or a matrix.

JMP Version Added: Before version 14

N Col( [11 22, 33 44] );

N Items

Syntax: y = N Items( x )

Description: Returns the number of items in a list, the number of elements in a matrix, the number of keys in an associative array, the number of functions and variables in a namespace, the number of methods and variables in a class object, or the number of children of a display box.

JMP Version Added: Before version 14

Example 1

N Items( {1, 2 + 3, [11 22]} );

Example 2

N Items( ["a" => 10, "b" => 3, => 0] );

Example 3

New Window( "boxes", hlist = H List Box( Button Box( "a" ), Button Box( "b" ) ) );
N Items( hlist );

N Missing

Syntax: y = N Missing( x1, x2, ... )

Description: Returns the number of missing values among arguments.

JMP Version Added: Before version 14

N Missing( 1, 2, ., 3, [11 22 . .], 4 );

N Row

Syntax: y = N Row(); y = N Row( dt ); y = N Row( matrix )

Description: Returns the number of rows in the current data table, a specified data table, or a matrix.

JMP Version Added: Before version 14

N Row( [11 22, 33 44] );

N Rows

Syntax: y = N Rows(); y = N Rows( dt ); y = N Rows( matrix )

Description: Returns the number of rows in the current data table, a specified data table, or a matrix.

JMP Version Added: Before version 14

N Rows( [11 22, 33 44] );

N Table

Syntax: n = N Table()

Description: Returns the number of currently open data tables.

JMP Version Added: Before version 14

Example 1

Open( "$SAMPLE_DATA/Big Class.jmp" );
N Table();

Example 2

Open( "$SAMPLE_DATA/Big Class.jmp" );
Open( "$SAMPLE_DATA/Cars.jmp" );
Open( "$SAMPLE_DATA/Solubility.jmp" );
d = {};
For( i = 1, i <= N Table(), i++,
    d[i] = Data Table( i ) << GetName
);
d;

Name

Syntax: Name(string)

Description: A name is simply something to call an item. Names are used for both variables and functions, and can be used directly in scripts as long as certain rules are followed. If the name begins with an alphabetic character or underscore, and continues with alphanumeric characters, whitespace, Unicode mathematical symbols and certain punctuation (apostrophes (’), percent signs (%), periods (.), backslashes (), and underscores (_)), then the name can be used directly in scripts. Names that do not follow these rules can be used by using the Name() keyword.

JMP Version Added: 14

Name( "taxable income(2011)" ) = 456000;
tax = .25;
Print( tax * Name( "taxable income(2011)" ) );

Name Expr

Syntax: y = Name Expr( x )

Description: Returns the value of a symbol, without evaluating it if it is an expression.

JMP Version Added: Before version 14

ex = Expr( 1 + 2 );
Eval List( {ex, Name Expr( ex )} );

Names Default To Here

Syntax: Names Default To Here( boolean )

Description: Determines where unresolved names are stored, either as a global/local ( 0 ) or in the Here: namespace ( 1 ).

JMP Version Added: Before version 14

/* Variable x will be stored in the Here: namespace by default */x = 1;
Show( x );

Namespace

Syntax: ns = Namespace( namespace reference )

Description: Return a reference to the namespace specified by the name argument.

JMP Version Added: Before version 14

New Namespace(
    "complex",
    {
        make = Function( {a, b},
            Index( a, b, b - a )
        ),
        add = Function( {x, y}, x + y ),
        sub = Function( {x, y}, x - y ),
        mul = Function( {x, y},
            local:z = J( 1, 2 );
            local:z[1] = x[1] * y[1] - x[2] * y[2];
            local:z[2] = x[1] * y[2] + x[2] * y[1];
            local:z;
        ),
        div = Function( {x, y},
            local:z = J( 1, 2 );
            local:d = (y[1] ^ 2 + y[2] ^ 2);
            local:z[1] = (x[1] * y[1] + x[2] * y[2]) / local:d;
            local:z[2] = (x[2] * y[1] - x[1] * y[2]) / local:d;
            local:z;
        ),
        write = Function( {x},
            Write( x[1], " + ", x[2], "i\!n" )
        )
    }
);
ns = Namespace( "complex" );
Show( ns );
ns << Delete;

Namespace Exists

Syntax: nsexists = Namespace Exists( namespace reference )

Description: Returns 1 if the namespace specified by the name argument exists; otherwise a 0 is returned.

JMP Version Added: Before version 14

ns = New Namespace(
    "complex",
    {
        make = Function( {a, b},
            Index( a, b, b - a )
        ),
        add = Function( {x, y}, x + y ),
        sub = Function( {x, y}, x - y ),
        mul = Function( {x, y},
            local:z = J( 1, 2 );
            local:z[1] = x[1] * y[1] - x[2] * y[2];
            local:z[2] = x[1] * y[2] + x[2] * y[1];
            local:z;
        ),
        div = Function( {x, y},
            local:z = J( 1, 2 );
            local:d = (y[1] ^ 2 + y[2] ^ 2);
            local:z[1] = (x[1] * y[1] + x[2] * y[2]) / local:d;
            local:z[2] = (x[2] * y[1] - x[1] * y[2]) / local:d;
            local:z;
        ),
        write = Function( {x},
            Write( x[1], " + ", x[2], "i\!n" )
        )
    }
);
nsexists = Namespace Exists( ns );
Show( nsexists );
ns << Delete;

NChooseK Matrix

Syntax: m = NChooseK Matrix( n, k )

Description: Creates a matrix of nChooseK(n,k) rows and k columns forming all the combinations of k integers from 1 to n.

JMP Version Added: Before version 14

Print( NChooseK Matrix( 5, 3 ) );

Neg Binomial Distribution

Syntax: cumprob = Neg Binomial Distribution( p, n, k )

Description: Returns the probability that a negative binomially distributed random variable is less than or equal to k, where the probability of success is p and the number of successes is n.

JMP Version Added: Before version 14

exnbdp = 0.5;
exnbdn = 10;
New Window( "Example: Neg Binomial Distribution",
    exnbdy = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -1, 41 ),
        Pen Color( "red" ),
        Pen Size( 2 );
        For( exnbdk = 0, exnbdk < 100, exnbdk++,
            H Line(
                exnbdk,
                exnbdk + 1,
                Neg Binomial Distribution( exnbdp, Round( exnbdn ), exnbdk )
            );
            V Line(
                exnbdk + 1,
                Neg Binomial Distribution( exnbdp, Round( exnbdn ), exnbdk ),
                Neg Binomial Distribution( exnbdp, Round( exnbdn ), exnbdk + 1 )
            );
        );
        Text( {30, 0.07}, "n=", Round( exnbdn ), " p=", Round( exnbdp, 2 ) );
    ),
    H List Box( Slider Box( 0, 1, exnbdp, exnbdy << reshow ), Text Box( " p" ) ),
    H List Box( Slider Box( 1, 20, exnbdn, exnbdy << reshow ), Text Box( " n" ) )
);

Neg Binomial Probability

Syntax: prob = Neg Binomial Probability( p, n, k )

Description: Returns the probability that a negative binomially distributed random variable is equal to k, where the probability of success is p and the number of successes is n.

JMP Version Added: Before version 14

exnbpp = 0.5;
exnbpn = 10;
New Window( "Example: Neg Binomial Probability",
    exnbpy = Graph Box(
        Y Scale( 0, 0.3 ),
        X Scale( -1, 41 ),
        Pen Color( "red" ),
        Pen Size( 2 );
        For( exnbpk = 0, exnbpk < 100, exnbpk++,
            V Line( exnbpk, 0, Neg Binomial Probability( exnbpp, exnbpn, exnbpk ) )
        );
        Text( {30, 0.27}, "n=", Round( exnbpn ), " p=", Round( exnbpp, 2 ) );
    ),
    H List Box( Slider Box( 0, 1, exnbpp, exnbpy << reshow ), Text Box( " p" ) ),
    H List Box( Slider Box( 0, 40, exnbpn, exnbpy << reshow ), Text Box( " n" ) )
);

Negative Binomial Distribution

Syntax: cumprob = Negative Binomial Distribution( k, lambda, sigma )

Description: Returns the probability that a Negative Binomial distributed random variable is less than or equal to k, where lambda is the location parameter, sigma is the scale parameter, and k is the count of interest.

JMP Version Added: 19

lambda = 20;
sigma = 2;
New Window( "Example: Negative Binomial Distribution",
    ppy = Graph Box(
        Y Scale( 0, 1.01 ),
        X Scale( -1, 40 ),
        Pen Color( "red" ),
        Pen Size( 1 );
        For( k = 0, k <= 40, k++,
            H Line( k, k + 1, Negative Binomial Distribution( k, lambda, sigma ) );
            V Line(
                k + 1,
                Negative Binomial Distribution( k, lambda, sigma ),
                Negative Binomial Distribution( k + 1, lambda, sigma )
            );
        );
        Text( {2, 0.95}, "\!U03BB=", Round( lambda, 2 ) );
        Text( {2, 0.87}, "\!U03C3=", Round( sigma, 2 ) );
    ),
    H List Box( Slider Box( 3, 40, lambda, ppy << reshow ), Text Box( " \!U03BB" ) ),
    H List Box( Slider Box( .01, 5, sigma, ppy << reshow ), Text Box( " \!U03C3" ) )
);

Negative Binomial Probability

Syntax: prob = Negative Binomial Probability( k, lambda, sigma )

Description: Returns the probability that a Negative Binomial distributed random variable is equal to k, where lambda is the location parameter, sigma is the scale parameter, and k is the count of interest.

JMP Version Added: 19

lambda = 5;
sigma = 2;
New Window( "Poisson and Negative Binomial",
    clty = Graph Box(
        Y Scale( 0, 0.3 ),
        X Scale( -1, 20.5 ),
        Pen Color( "red" ),
        Pen Size( 2 );
        For( x = 0, x <= 20, x++,
            Pen Color( "red" );
            V Line( x, 0, Poisson Probability( lambda, x ) );
            Pen Color( "blue" );
            V Line( x + 0.35, 0, Negative Binomial Probability( x, lambda, sigma ) );
        );
        Text( {1, 0.25}, "\!U03BB=", Round( lambda, 8 ), " \!U03C3=", Round( sigma, 8 ) );
        Text( {0, 0.28}, "Red = Poisson, Blue = Negative Binomial" );
    ),
    H List Box( Slider Box( 3, 10, lambda, clty << reshow ), Text Box( " \!U03BB" ) ),
    H List Box( Slider Box( .01, 5, sigma, clty << reshow ), Text Box( " \!U03C3" ) )
);

Negative Binomial Quantile

Syntax: q = Gamma Negative Binomial Quantile( lambda, sigma, cumprob )

Description: Returns the smallest integer quantile for which the cumulative probability of the Negative Binomial( lambda, sigma ) distribution is larger than or equal to cumprob.

JMP Version Added: 19

qexpl = 20;
qexps = 2;
qexpn = 40;
qexpq = 0.5;
New Window( "Example: Negative Binomial Quantile",
    qexpy = Graph Box(
        Y Scale( 0, 1.05 ),
        X Scale( -1, 41 ),
        Pen Color( "red" ),
        Pen Size( 2 );
        For( qexpk = 0, qexpk < Round( qexpn ), qexpk++,
            H Line( qexpk, qexpk + 1, Negative Binomial Distribution( qexpk, qexpl, qexps ) );
            V Line(
                qexpk + 1,
                Negative Binomial Distribution( qexpk, qexpl, qexps ),
                Negative Binomial Distribution( qexpk + 1, qexpl, qexps )
            );
        );
        Pen Color( "blue" );
        V Line( Negative Binomial Quantile( qexpl, qexps, qexpq ), 0, 1 );
        Text( {1, 0.9}, " \!U03BB=", Round( qexpl, 2 ), " \!U03C3=", Round( qexps, 2 ) );
        Text(
            {1, 0.8},
            " q=",
            Round( qexpq, 2 ),
            " quantile=",
            Round( Negative Binomial Quantile( qexpl, qexps, qexpq ) )
        );
    ),
    H List Box( Slider Box( 3, 40, qexpl, qexpy << reshow ), Text Box( " \!U03BB" ) ),
    H List Box( Slider Box( .01, 5, qexps, qexpy << reshow ), Text Box( " \!U03C3" ) ),
    H List Box( Slider Box( 0, 1, qexpq, qexpy << reshow ), Text Box( " q" ) )
);

Net Present Value

Syntax: x = Net Present Value( rate, values );x = Net Present Value( rate, value1, value2, <value3, ...> )

Description: Returns the net present value of an investment by using a discount rate and a series of future payments (negative values) and income (positive values). The values argument is a one dimensional matrix. Equivalent to the NPV function in Microsoft Excel. The second prototype of the function accepts all scalar arguments.

JMP Version Added: Before version 14

Net Present Value( .05, [-10000, 1000, 900, 9500] );
Net Present Value( .05, -10000, 1000, 900, 9500 );

New CAS Action

Syntax: action = New CAS Action(...)

Description: Creates a CAS Action.

JMP Version Added: 15

echo = [=> ];
echo["a"] = 1;
echo["b"] = JSON Literal( true );
echo["c"] = 3.141559;
action = New CAS Action( Action( "builtins.echo" ), JSON( echo ) );

New CAS DATA Step action

Syntax: action = New CAS DATA Step Action(...)

Description: Creates a CAS DATA step action.

JMP Version Added: 15

cas = Current CAS Connection();
code =
"\[
    data temp;
    x = 9.1; y = 6; z = sqrt(x**2 + y**2);
    A = "SAS"; B = "Statistics";
    put _ALL_;              /* display all variables and values */
    run;
]\";
action = New CAS DATA Step action( Code( code ) );
cas << Submit( action );

New CAS Server

Syntax: cas = New CAS Server(<...>)

Description: Creates a new CAS server.

JMP Version Added: 15

url = "http://myCasURL";
cas = New CAS Server( Connect( URL( url ), Prompt( IfNeeded ) ) );

New Clipboard

Syntax: clp = New Clipboard( <<<Get From OS> )

Description: Creates a new Clipboard, either empty or with access to the OS clipboard.

JMP Version Added: 19

clp = New Clipboard( <<Get From OS );
New Window( "Img", clp << Get Flavor Data( "Graphic" ) )
;

New Column

Syntax: dc = New Column( name, <"Numeric"|"Character"|"RowState"|"Expression">, <"Continuous"|"Ordinal"|"Nominal"|"Multiple Response"|"Unstructured Text"|"Vector"|"None">, <Width( n )|Format(format name, width, precision)>, <Like(:other column)>, <actions> )

Description: Creates a new column in the current data table. The optional actions arguments are any messages that data columns support.

JMP Version Added: Before version 14

Like

Open( "$SAMPLE_DATA/Big Class.jmp" );
New Column( "like name", Like( :name ) );

Simple

Open( "$SAMPLE_DATA/Big Class.jmp" );
New Column( "example", "Numeric", "Continuous", Width( 5 ), <<Set Each Value( 100 ) );

New Column by Text Matching

Syntax: dc = New Column by Text Matching( Column(:name), Set Regex(), <Output Column Name("Name")>, <Use Result(0 | 1)> )

Description: Creates a new column by performing a regular expression pattern match on an existing column.

JMP Version Added: 16

Open( "$SAMPLE_DATA/Aircraft Incidents.jmp" );
New Column by Text Matching(
    Column( :Narrative Cause ),
    Set Regex( Library( "Words" ), Library( "Time" ), Library( "Units" ) ),
    Output Column Name( "Match Output" ),
    Use Result( 1 )
);

New Custom Function

Syntax: f=New Custom Function(namespace, name, function definition)

Description: Create a new custom function object. A custom function will be colorized in the script editor and show up in the Scripting Index. The required information for a custom user function are a namespace (to prevent collisions with global functions), a name, and a function definition. Other help information can be added using messages. Use the Add Custom Functions command to publish the new function into the JMP environment.

JMP Version Added: 14

Example 1

myAdd = New Custom Function( "custom", "Add", Function( {x, y = 1}, x + y - 1 ) );

Example 2

/*Create a custom function that can be used as a format*/
Add Custom Functions(
    {New Custom Function(
        "custom",
        "User Defined Format Function",
        Function( {inches},
            Char( inches ) || " in"
        ),
        <<Custom Format Category( "Custom" ), 

    )}
);

Example 3

/*Create a custom function that can be used as a transform*/
Add Custom Functions(
    {New Custom Function(
        "custom",
        "User Defined Transform Function",
        Function( {inches},
            inches * 2.54
        ),
        <<Transform Category( "Custom" ), 

    )}
);

New Data Connector

Syntax: result = New Data Connector( Type( type ) | ID( id ) | File( path ) | Spec( string ) | Base( data connector ), < Option1( value1 ) >, ..., < OptionN( valueN ) > )

Description: Create a data connector configuration object.

JMP Version Added: 18

Example 1

// Create a data connector from scratch
dc = New Data Connector( Type( "ODBC" ), Database( "foo" ), Server( "bar.example.com" ) );
Show( dc << Get( Database ) );  // Overridden database value "foo"
Show( dc << Get( Driver ) );  // Default driver value . (missing)
dc << Set( Database( "foo2" ), Driver( "SQL Server" ) );
Show( dc << Get( Database ) );  // New database value "foo2"
Show( dc << Get( Driver ) );  // New driver value "SQL Server"

Example 2

// Launch Query Builder from a SQL Server data source
dc = New Data Connector(
    ID( "com.jmp.sql_server" ), 
    // All these example values need to be replaced with real ones
    Server( "database.example.com" ),
    Database( "MainDatabase" ),
    User( "username" ),
    Password( "password" )
);
New SQL Query( Connection( dc ) ) << Modify;

New Heat Image

Syntax: New Heat Image( Matrix, <Color Theme / gradient ( ... )>

Description: Creates a heat map image based on a matrix and color theme or gradient.

JMP Version Added: 16

nx = 20; // data is this size
ny = 15;
data = J( ny, nx, Random Normal() ); // ny=rows, nx=cols
// create a magnified matrix for seeing each value
magnify = 10;
big data = J( N Rows( data ) * magnify, N Cols( data ) * magnify );
big data = Transform Each( {z, {row, col}}, big data, 
    // and filling each value with one from the small matrix
    data[Floor( (row - 1) / magnify ) + 1, Floor( (col - 1) / magnify ) + 1]
);
New Window( "small and big",
    Lineup Box( N Col( 3 ),
        New Heat Image(
            data,
            gradient(
                {Color Theme( "Blue To Gray To Orange" ), Scale Type( "Standard Deviation" )}
            )
        ),
        New Heat Image(
            big data,
            gradient(
                {Color Theme( "Blue To Gray To Orange" ), Scale Type( "Standard Deviation" )}
            )
        ),
        New Heat Image(
            Abs( big data ),
            gradient(
                {Color Theme( "White to Black" ), Scale Values( [0 2] ),
                Reverse Gradient( 1 )}
            )
        )
    )
);

New HTTP Request

Syntax: obj = New HTTP Request(URL(...), Method(...), <Form(<Fields(...)>, <Files(...)>)> | <File(...)> | <Blob(...)> | <JSON(...)>, <QueryString(...)>, <Headers(...)>, <Username(...)>, <Password(...)>)

Description: Creates a request to send to a web service.

JMP Version Added: 14

getSentiment = Function( {text},
    {Default Local},
    fields = Associative Array();
    fields["text"] = text;
    s = New HTTP Request(
        URL( "http://text-processing.com/api/sentiment/" ),
        Method( "POST" ),
        Form( Fields( fields ) ),
        Headers( {"Accept: application/json"} )
    ) << Send;
    sAsList = Parse JSON( s );
    retval = Associative Array();
    retval["pos"] = sAsList["probability"]["pos"];
    retval["neg"] = sAsList["probability"]["neg"];
    retval["neutral"] = sAsList["probability"]["neutral"];
    retval["label"] = sAsList["label"];
    retval;
);

addSentimentColumns = Function( {dt, colname, bLabel, bValues},
    {Default Local},
    col = Column( dt, colname );
    colLabel = "Sentiment_Label(" || colname || ")";
    colValPos = "Sentiment_Pos(" || colname || ")";
    colValNeg = "Sentiment_Neg(" || colname || ")";
    colValNeutral = "Sentiment_Neutral(" || colname || ")";
    If( bLabel,
        dt << New Column( colLabel, Character )
    );
    If( bValues,
        dt << New Column( colValPos, Numeric );
        dt << New Column( colValNeg, Numeric );
        dt << New Column( colValNeutral, Numeric );
    );
    For( i = 1, i <= N Rows( dt ), i++,
        sentiment = getSentiment( col[i] );
        If( bLabel,
            Column( dt, colLabel )[i] = sentiment["label"]
        );
        If( bValues,
            Column( dt, colValPos )[i] = sentiment["pos"];
            Column( dt, colValNeg )[i] = sentiment["neg"];
            Column( dt, colValNeutral )[i] = sentiment["neutral"];
        );
    );
);

dt2 = Open( "$SAMPLE_DATA\Cereal.jmp" );
addSentimentColumns( dt2, "Name", 1, 1 );

New Image

Syntax: img = New Image()img = New Image( width, height )img = New Image( pathname )img = New Image( picture )img = New Image( matrix of JSL color pixels ) img = New Image( rgb|r|g|rgba, {i, i, i} )

Description: Returns a new image which can then be edited through JSL commands. If a path is specified to an existing image file, the file should be a .JPG, .PNG, .GIF, .BMP or .TIF file.

JMP Version Added: Before version 14

Example 1

image = New Image( "$SAMPLE_IMAGES/windmap.png" );
New Window( "new image", image );

Example 2

pic = Open( "$SAMPLE_IMAGES/windmap.png", png );
image2 = New Image( pic );
New Window( "new image", image2 );

Example 3

image3 = New Image();
mat = J( 256, 256 );
For( y = 0, y < 256, y++,
    For( x = 0, x < 256, x++,
        mat[y * 256 + x] = RGB Color( y / 255.0, 0.0, x / 255.0 )
    )
);
image3 << Set Pixels( mat );
New Window( "image", image3 );

New IP21 Client

Syntax: New IP21 Client(URL(base URL), <Authentication Method("None"|"Basic"|"NTLM"|"Kerberos")>, <Username(userid)>,<Password(password)>)

Description: Creates a new IP21 Client instance that can be used to import data from an AspenTech IP.21 server.

JMP Version Added: 19

New JMP Live

Syntax: New JMP Live(Connection("Connection Name"), <Prompt("No" | "If Needed")>)

Description: Start a connection to JMP Live using stored connection information. Connection is optional and defaults to the connection specified as the default in Connection Manager. If provided it looks up the connection by the name. Prompt is optional and defaults to "No". The valid values for prompt are "Yes", "No", and "If Needed". A value of "Yes" always prompts for login credentials. A value of "No" never prompts for login credentials, but could result in an authentication failure. A value of "If Needed" prompts for credentials only if the current stored credentials are not valid. Returns a JMP Live Connection object.

JMP Version Added: 15

Example 1

jmplive = New JMP Live();

Example 2

jmplive = New JMP Live( Connection( "MyJMPLive" ), Prompt( No ) );

Example 3

jmplive = New JMP Live( Connection( "MyJMPLive" ), Prompt( If Needed ) );

New JMP Live Content

Syntax: obj = New JMP Live Content(jmpreport|Image(path_to_image)|Data(jmpdatatable)|Map(jmpmap), <Title(...)>, <Description(...)>, <Publish Data(0|1)>, <Enable Warnings(0|1)>, <Optimization("Interactivity" | "Performance")>

Description: Creates interactive content for publishing on JMP Live.

The first parameter is required and specifies the data to use for the content. That data can be a report, a data table, a map or an image.

Title and Description are used to customize any type of content that is being published. The remaining parameters are optional and used to customize report content only.

Publish Data indicates whether the data used in the report is published to JMP Live. The data for the report is published by default.

Enable Warnings indicates whether Control Chart Warnings should be enabled for the report. Control Chart Warnings are disabled by default.

Optimization is used to customize the way the report is published to JMP Live. The report is published to enable greater interactivity by default.

JMP Version Added: 17

Example 1

bc = Open( "$SAMPLE_DATA/Big Class.jmp" );
dist = bc << Run Script( "Distribution" );

liveconnection = New JMP Live();
jmpliveresult = liveconnection << Create Folder(
    Parent Folder( "~" ),
    Title( "Folder for Sample Content" )
);
folder = jmpliveresult << As Scriptable;

content = New JMP Live Content(
    dist,
    Title( "Distribution Web Report" ),
    Description( "This report was created with the sample found in the Scripting Index" ),
    Publish Data( 1 ),
    Optimization( "Interactivity" )
);

jmpliveresult = liveconnection << Publish( content, Folder( folder ) );

Example 2

liveconnection = New JMP Live();
jmpliveresult = liveconnection << Create Folder(
    Parent Folder( "~" ),
    Title( "Folder for Data Content" )
);
folder = jmpliveresult << As Scriptable;

content = New JMP Live Content(
    Data( "$SAMPLE_DATA/Big Class.jmp" ),
    Title( "Big Class Sample Table" ),
    Description(
        "This data table was published with the sample found in the Scripting Index"
    )
);

jmpliveresult = liveconnection << Publish( content, Folder( folder ) );

Example 3

liveconnection = New JMP Live();
jmpliveresult = liveconnection << Create Folder(
    Parent Folder( "~" ),
    Title( "Folder for Map Content" )
);
folder = jmpliveresult << As Scriptable;

content = New JMP Live Content( Map( "$SAMPLE_DATA/S4-XY.jmp" ) );

jmpliveresult = liveconnection << Publish( content, Folder( folder ) );

Example 4

liveconnection = New JMP Live();
jmpliveresult = liveconnection << Create Folder(
    Parent Folder( "~" ),
    Title( "Folder for Image Content" )
);
folder = jmpliveresult << As Scriptable;

imageContent = New JMP Live Content(
    Image( "$SAMPLE_IMAGES/black rhino footprint.jpg" ),
    Title( "Rhino Footprint" ),
    Description( "An image of a rhino footprint from the Sample Data" )
);

jmpliveresult = liveconnection << Publish( imageContent, Folder( folder ) );

New Multi HTTP Request

Syntax: multi_request = New Multi HTTP Request()

Description: Sends or downloads multiple HTTP requests in parallel.

JMP Version Added: 17

requests = New Multi HTTP Request();
requests << Add(
    New HTTP Request(
        Method( "GET" ),
        URL(
            "http://cdimage.ubuntu.com/lubuntu/releases/20.04.3/release/lubuntu-20.04.3-desktop-amd64.iso"
        )
    )
);

requests << Add(
    New HTTP Request(
        Method( "GET" ),
        URL(
            "http://downloads.sourceforge.net/clonezilla/clonezilla-live-2.7.3-19-amd64.iso"
        )
    )
);

data = requests << Download( "show progress", "detailed" );
http_requests = requests << Get Requests();
For( i = 1, i <= N Items( http_requests ), i++,
    Show( http_requests[i] << Get Mime Type() )
);

New Namespace

Syntax: ns = New Namespace( <name>, <list of expressions> )

Description: Create a new namespace with the name specified by the name argument or with an anonymous name if name is not specified.

JMP Version Added: Before version 14

ns = New Namespace(
    "complex",
    {
        make = Function( {a, b},
            Index( a, b, b - a )
        ),
        add = Function( {x, y}, x + y ),
        sub = Function( {x, y}, x - y ),
        mul = Function( {x, y},
            local:z = J( 1, 2 );
            local:z[1] = x[1] * y[1] - x[2] * y[2];
            local:z[2] = x[1] * y[2] + x[2] * y[1];
            local:z;
        ),
        div = Function( {x, y},
            local:z = J( 1, 2 );
            local:d = (y[1] ^ 2 + y[2] ^ 2);
            local:z[1] = (x[1] * y[1] + x[2] * y[2]) / local:d;
            local:z[2] = (x[2] * y[1] - x[1] * y[2]) / local:d;
            local:z;
        ),
        write = Function( {x},
            Write( x[1], " + ", x[2], "i\!n" )
        )
    }
);
Show( ns );
ns << Delete;

New OAuth2

Syntax: oauth2 = New OAuth2()

Description: Creates a new OAuth2 authorization.

JMP Version Added: 15

/*
https://docs.microsoft.com/en-us/azure/active-directory/develop/v2-oauth2-auth-code-flow
*/

/*
Note: the "code" parameter is set automatically after the redirect occurs
*/
auth_url = "https://login.microsoftonline.com/common/oauth2/v2.0/authorize";
token_url = "https://login.microsoftonline.com/common/oauth2/v2.0/token";
redirect_url = "http://localhost/myapp/";
client_id = "6731de76-14a6-49ae-97bc-6eba6914391e";
client_secret = "JqQX2PNo9bpM0uEihUPzyrh";
scope = "openid offline_access https://graph.microsoft.com/user.read";
auth_fields = [=> ];
token_fields = [=> ];

oauth2 = New OAuth2();
oauth2 << Grant Type( "Authorization Code" );
oauth2 << Auth URL( auth_url );
oauth2 << Token URL( token_url );
oauth2 << Redirect URL( redirect_url );

auth_fields["scope"] = scope;
auth_fields["client_id"] = client_id;
token_fields["client_secret"] = client_secret;

oauth2 << Auth Fields( auth_fields );
oauth2 << Token Fields( token_fields );

auth_header = oauth2 << Get Auth Header();
request = New HTTP Request(
    URL( "https://graph.microsoft.com/v1.0/me" ),
    Headers( {auth_header} ),
    Method( "GET" )
);
data = request << Send;

New OAuth2 Token

Syntax: token = New OAuth2 Token( Account("jmpgoogldev@gmail.com"), Client ID("test"), Client Secret("test 2"), Refresh Token(""), Token URL(""))

Description: Creates an OAuth2 Token for securely accessing data across many different web APIs.

JMP Version Added: 15

token = New OAuth2 Token(
    Account( "jmpgoogldev@gmail.com" ),
    Client ID( "test" ),
    Client Secret( "test 2" ),
    Refresh Token( "" ),
    Token URL( "" )
);

New Object

Syntax: New Object( "class name" | class name | class reference( constructor arguments* ) )

Description: Creates an instance object of a class.

JMP Version Added: 14

Define Class(
    "complex",
    real = 0;
    imag = 0;
    _init_ = Method( {a, b},
        real = a;
        imag = b;
    );
    Add = Method( {y},
        New Object( complex( real + y:real, imag + y:imag ) )
    );
    Sub = Method( {y},
        New Object( complex( real - y:real, imag - y:imag ) )
    );
    Mul = Method( {y},
        New Object( complex( real * y:real - imag * y:imag, imag * y:real + real * y:imag ) )
    );
    Div = Method( {y},
        t = New Object( complex( 0, 0 ) );
        mag2 = y:Magsq();
        t:real = real * y:real + imag * y:imag;
        t:imag = imag * y:real + real * y:imag;
        t:real = t:real / mag2;
        t:imag = t:imag / mag2;
        t;
    );
    Magsq = Method( {},
        real * real + imag * imag
    );
    Mag = Method( {},
        Sqrt( real * real + imag * imag )
    );
    _to string_ = Method( {},
        Char( real ) || " + " || Char( imag ) || "i"
    );
    _show_ = _to string_;
);
cl = New Object( complex( 1, 2 ) );
cl << Delete;
Delete Classes( "complex" );

New PI Client

Syntax: New Pi Client(URL(base URL), <Authentication Method("None"|"Basic"|"NTLM"|"Kerberos")>, <Username(userid)>,<Password(password)>)

Description: Creates a new PI Client instance that can be used to import data from a PI server.

JMP Version Added: 17

Example 1

/* Import raw data */
client = New PI Client(
    URL( "https://myserver.com/piwebapi" ),
    Authentication Method( "basic" ),
    Username( "myuserid" ),
    Password( "mypassword" )
);
importer = client << Importer(
    AF Path( "\\myserver\PIData\Atlanta Data Center\Server Rack1\ION 6200 Power Meter1|I A" ), /* Asset Framework path */
    Series( "raw" ),
    Start Time( "*-1d" ), /* PI time string */
    End Time( "*" ),      /* PI time string */
    Boundary Type( "inside" ), /* choices are "inside", "outside", "interpolated" */
    UTC( 0 ), /* whether specified start/end times are based on UTC - default is zero */
    Max Count( 5000 ), /* Max. number of values to fetch - default is 5000 */
    Filter( "" ), /* Optional filter */
    Retrieve Attribute Status( 0 ) /* Whether to retrieve value attributes (i.e. "good", "questionable", "substituted", "annotated") - default is 0 */
);
importer << Run;

Example 2

/* Import plot data using Kerberos for authentication */
client = New PI Client(
    URL( "https://myserver.com/piwebapi" ),
    Authentication Method( "kerberos" )
);
importer = client << Importer(
    AF Path( "\\myserver\PIData\Atlanta Data Center\Server Rack1\ION 6200 Power Meter1|I A" ),
    Series( "plot" ),
    Start Time( "*-1d" ),
    End Time( "*" ),
    UTC( 0 ),
    Intervals( 24 )
); /* No of time intervals to fetch*/
importer << Run;

Example 3

/* Import interpolated data from a server that does not require authentication */
client = New PI Client(
    URL( "https://myserver.com/piwebapi" ),
    Authentication Method( "none" )
);
importer = client << Importer(
    AF Path( "\\myserver\PIData\Atlanta Data Center\Server Rack1\ION 6200 Power Meter1|I A" ),
    Series( "interpolated" ),
    Start Time( "*-1d" ),
    End Time( "*" ),
    UTC( 0 ),
    Sync Time Boundary Type( "inside" ),   /*  choices are "inside", "outside" */
    Interval( "1h" ),            /* interval period */
    Sync Time( "01JUL2021" ),    /* optional sync point - ie. intervals begin from this point */
    Filter( "" )
);
importer << Run;

New Project

Syntax: project = new Project( <project messages> )

Description: Creates a new empty project window. One or more project messages can be included as arguments in order to create a project in one step.

JMP Version Added: Before version 14

Example 1

project = New Project();

Example 2

project = New Project(
    Run Script(
        dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
        dt << Run Script( "Bivariate" );
    )
);

Example 3

project = New Project(
    Run Script(
        Open( "$SAMPLE_DATA/Big Class.jmp" );
        New Window( "Big Class - Bivariate of weight by height",
            Bivariate( Y( :weight ), X( :height ) )
        );
    )
);

Example 4

project = New Project(
    Set Bookmarks(
        {File( "$SAMPLE_DATA/Animals.jmp" ), File( "$SAMPLE_DATA/Big Class.jmp" )}
    ),
    Run Script(
        Open( "$SAMPLE_DATA/Big Class.jmp" );
        New Window( "Big Class - Bivariate of weight by height",
            Bivariate( Y( :weight ), X( :height ) )
        );
    )
);

Example 5

project = New Project(
    Run Script( Open( "$SAMPLE_SCRIPTS/demoCorr.jsl", Set Window ID( "demoCorr" ), Script ) ),
    Set Layout(
        H Splitter Box(
            <<Set Sizes( {0.15, 0.85} ),
            Tab Page Box( Title( "Window List" ), Window ID( "Windows" ) ),
            V Splitter Box(
                <<Set Sizes( {0.7, 0.3} ),
                Tab Page Box( Title( "demoCorr" ), Window ID( "demoCorr" ) ),
                Tab Page Box( Title( "Log" ), Window ID( "Log" ) )
            )
        )
    )
);

New SQL Query

Syntax: obj = New SQL Query( Connection( "ODBC:my_connection_string" ), Select( Column( "mycolumn", "t1" ) ), From( Table( "my_table", Schema( "my_schema" ), Alias( "t1" ) ) ) ); obj = New SQL Query( Connection( "ODBC:my_connection_string;" ), CustomSQL( "SELECT c1, c2, c3 FROM my_table;" ) )

Description: Creates an SQL Query object for the connection, columns and table specified, or for the custom SQL query specified. Use Query Builder to generate scripts that create queries.

JMP Version Added: Before version 14

obj = New SQL Query(
    Connection( "ODBC:DSN=mydsn" ),
    Select(),
    From( Table( "my_table", Schema( "my_schema" ), Alias( "t1" ) ) )
);

New Table

Syntax: dt = New Table( name, <visibility("private"|"invisible"|"visible")>, <Enable Filter Views(bool)>, <actions> )

Description: Creates a new data table. "Invisible" hides the data table from view but lists it in the JMP Home Window. "Private" hides the table completely. "Visible" is the default, and creates a normal table that is visible and listed in the JMP Home Window. The optional actions arguments are any messages that data tables support.

JMP Version Added: Before version 14

New Table( "Little Class",
    Add Rows( 3 ),
    New Column( "name", Character, Nominal, Set Values( {"KATIE", "LOUISE", "JANE"} ) ),
    New Column( "age", Nominal, Set Values( [12, 13, 13] ) ),
    New Column( "weight", Continuous, Set Values( [95, 123, 74] ) )
);

New Web Report

Syntax: obj = New Web Report(...)

Description: Creates an interactive HTML report.

JMP Version Added: 14

Open( "$SAMPLE_DATA/Big Class.jmp", Invisible );
webreport = New Web Report(
    Add Report(
        Distribution(
            Continuous Distribution( Column( :weight ) ),
            Nominal Distribution( Column( :age ) )
        ),
        Title( "Distribution Web Report" ),
        Description( "This report was created with the sample found in the Scripting Index" )
    ),
    Add Report(
        Bivariate(
            Y( :weight ),
            X( :height ),
            Automatic Recalc( 1 ),
            Fit Line( {Line Color( {213, 72, 87} )} ),
            Local Data Filter( Add Filter( columns( :sex ) ) )
        )
    )
);
webreport << Index( Title( "Big Class Report" ) );
file = webreport << Save( "$TEMP" );
If( !Is Empty( file ),
    Web( file )
);

New Window

Syntax: w = New Window( title, < <<Type("Report" | "Dialog" | "Modal Dialog" | "Journal" | "Launcher" | "Script")>, < << Return Result>, < << On Open(expr | function | method)>, < << On Close(expr | function | method)>, < <<On Validate(expr | function | method)>, < <<Show Menu(0 | 1)>, < <<Show Toolbars(0 | 1)>, < <<Suppress AutoHide(0 | 1)>, < <<Window View("Visible" | "Invisible")>, < <<Language("C" | "JavaScript" | "JSL" | "JSON" | "Python" | "R" | "SAS" | "SQL" | "Text" | "XML")>, < <<Size(x, y)>, displayBox | script)

Description: Creates a window containing the specified display box or script. A report window is created by default, unless the Type option is specified. A window of Type("Modal Dialog") halts execution until the dialog is responded to. On Open, On Validate, and Return Result are available only for modal windows. On Open() evaluates its expression, function, or class method when the window is created. If On Close() returns false, the window is prevented from closing. On Validate() runs its expression, function, or class method when the OK button is clicked. If the expression returns true, the window is closed. Otherwise, the window remains open. Return Result changes the window's return value when it closes to match that of the deprecated Dialog() function. For window types that support toolbars, use Show Toolbars to specify changes from the default behavior. The options Show Menu and Suppress AutoHide are Windows only. The Window View("Invisible") option can be used for any window other than a Modal Dialog. A window of Type("Script") creates a JSL document unless the <<Language option is specified.

JMP Version Added: Before version 14

[Win] Toolbars and Menus

// Compare settings for toolbars and menus
// Suppress AutoHide is Windows only
g = Graph Box(
    Frame Size( 300, 300 ),
    Marker( Marker State( 3 ), [11 44 77], [75 25 50] );
    Pen Color( "Blue" );
    Line( [10 30 70], [88 22 44] );
);
New Window( "Default - menu and toolbars", g );
New Window( "Menu, no toolbars, suppress autohide",
    Suppress AutoHide( 1 ),
    Show Toolbars( 0 ),
    g
);
New Window( "Toolbars, no menu", Show Menu( 0 ), g );
New Window( "No menu, no toolbars", Show Menu( 0 ), Show Toolbars( 0 ), g );

Dialog

ex = New Window( "Dialog example",
    <<Type( "Dialog" ),
    V List Box(
        Panel Box( "Sample data dialog",
            Button Box( "Open Sample Data", Open( "$SAMPLE_DATA/Big Class.jmp" ) )
        ),
        H List Box( Button Box( "Close", Try( ex << CloseWindow ) ) )
    )
);

Invisible

g = Graph Box(
    Frame Size( 300, 300 ),
    Marker( Marker State( 3 ), [11 44 77], [75 25 50] );
    Pen Color( "Blue" );
    Line( [10 30 70], [88 22 44] );
);
w = New Window( "My Window's Title", <<WindowView( "Invisible" ), g );
p = w << Get Picture();
w << Close Window;
psize = p << Size;
New Window( "picture", Outline Box( "picture size: " || Char( psize ), p ) );

Modal Dialog

ex = New Window( "Modal Dialog example",
    <<Type( "Modal Dialog" ),
    <<Return Result,
    <<On Validate(
        num = myEditBox << Get;
        If( num >= 1 & num <= 100, // in range
            myEditBox << Background Color( "Background" ); // this field does not need attention
            1; //the number is good, validate
        , // else out of range
            myEditBox << Background Color( "Light Yellow" ); // this field needs attention
            0; // the number is bad, do not validate
        ) // the result of this if(...) is the OnValidate( ) answer, 0 or 1
        ;
    ),
    V List Box(
        Text Box( "Enter a value between [1,100]:" ),
        H List Box( myEditBox = Number Edit Box( 42 ) ),
        H List Box( Button Box( "OK" ), Button Box( "Cancel" ) )
    )
);

//  the Modal window must be closed before the following code runs

If(
    ex["button"] == 1 // not canceled
, // then show the value
    Write( ex["myEditBox"] ); // note: myEditBox is the name of the variable holding the text edit box
, // else report no selection
    Write( "CANCEL" ); // cancel button or red X was pressed
);

Python script

pyscript = "\[import numpy as np
a = np.arange(15).reshape(3, 5)]\";
ex = New Window( "Script example", <<Type( "Script" ), <<Language( "Python" ), pyscript );

Report

g = Graph Box(
    Frame Size( 300, 300 ),
    Marker( Marker State( 3 ), [11 44 77], [75 25 50] );
    Pen Color( "Blue" );
    Line( [10 30 70], [88 22 44] );
);
New Window( "My Window's Title", g );

Script

script = JSL Quote(Names Default To Here(1);
dt=Open("$SAMPLE_DATA/Big Class.jmp");
dt << Run Script("Bivariate");
);
ex = New Window( "Script example", <<Type( "Script" ), script );

Normal Biv Distribution

Syntax: y = Normal Biv Distribution( x, y, r, <mu1=0>, <s1=1>, <mu2=0>, <s2=1> )

Description: Computes the probability that an observation (X, Y) is less than or equal to (x, y) with correlation coefficient r where X is marginally normally distributed with mean mu1 and standard deviation s1 and Y is marginally normally distributed with mean mu2 and standard deviation s2. If mu1, s1, mu2, and s2 are not given, the function assumes the standard normal bivariate distribution with mu1=0, s1=1, mu2=0, and s2=1.

JMP Version Added: Before version 14

Normal Biv Distribution( -2, -2, .5, 1, 1.5, -1, 2 );

Normal Contour

Syntax: Normal Contour( prob, meanMatrix, stdMatrix, corrMatrix, <colorsMatrix>, <fill=0> )

Description: Draws normal probability contour(s) for k populations and two variables. The prob argument can be either a scalar probability or a matrix of probabilities. The meanMatrix and stdsMatrix arguments are k by 2 matrices, and the corrMatrix argument is a k by 1 vector. The colorsMatrix argument specifies the color(s) for the k contour(s); colors must be specified as JSL colors (either JSL color integer values or return values of JSL color functions such as the RGB Color() or HLS Color() functions). The fill argument specifies the amount of transparency for the contour fill color.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Fill Color( "blue" );
        Normal Contour( 0.95, [40 40], [15 5], [0.5], Empty(), 0.1 );,
        Normal Contour(
            0.95,
            [40 40, 60 50],
            [15 5, 10 10],
            [-0.9, -0.5],
            Matrix( {RGB Color( {0.1, 0.9, 0.1} ), 3} ),
            0.2
        )
    )
);

Normal Density

Syntax: y = Normal Density( q, <mu=0>, <sigma=1> )

Description: Returns the density at q of a Normal distribution with mean mu and standard deviation sigma.

JMP Version Added: Before version 14

New Window( "Example: Normal Density",
    y = Graph Box(
        Y Scale( 0, 0.45 ),
        X Scale( -4, 4 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Normal Density( q ), q );
    )
);

Normal Distribution

Syntax: p = Normal Distribution( q, <mu=0>, <sigma=1> )

Description: Returns the probability that a normally distributed random variable is less than q.

JMP Version Added: Before version 14

New Window( "Example: Normal Distribution",
    y = Graph Box(
        Y Scale( 0, 1 ),
        X Scale( -4, 4 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Normal Distribution( q ), q );
    )
);

Normal Integrate

Syntax: {mean, var} = Normal Integrate( muVector, sigmaMatrix, expr, x, NStrata, NSim )

Description: Returns the result of radial-spherical integration for smooth functions of multivariate normal variables. The basic idea is the same as one method in Genz and Monahan(1996). But Radau-Gauss-Laguerre type quadrature is used for the radial direction.

JMP Version Added: Before version 14

Normal Integrate(
    J( 3, 1, 0 ),
    Identity( 3 ),
    ex[1] ^ 4 * ex[2] ^ 2 * ex[3] ^ 2,
    ex,
    2,
    5000
);

Normal Log CDistribution

Syntax: y = Normal Log CDistribution( x, <mean=0>, <std dev=1> )

Description: Returns the log of 1 - Normal distribution at x with mean mu and standard deviation sigma.

JMP Version Added: Before version 14

New Window( "Example: Normal Log CDistribution",
    nlcdiy = Graph Box(
        Y Scale( -10, 0.05 ),
        X Scale( -4, 4 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Normal Log CDistribution( q ), q );
    )
);

Normal Log Density

Syntax: y = Normal Log Density( x, <mu=0>, <sigma=1>)

Description: Returns the log of the Normal probability density at x with mean mu and standard deviation sigma.

JMP Version Added: Before version 14

New Window( "Example: Normal Log Density",
    nldey = Graph Box(
        Y Scale( -9, 0.05 ),
        X Scale( -4, 4 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Normal Log Density( q ), q );
    )
);

Normal Log Distribution

Syntax: y = Normal Log Distribution( x, <mean=0>, <std dev=1> )

Description: Returns the log of the Normal distribution at x with mean mu and standard deviation sigma.

JMP Version Added: Before version 14

New Window( "Example: Normal Log Distribution",
    nldiy = Graph Box(
        Y Scale( -10, 0.05 ),
        X Scale( -4, 4 ),
        XName( "q" ),
        Pen Color( "red" );
        Y Function( Normal Log Distribution( q ), q );
    )
);

Normal Mixture Density

Syntax: y = Normal Mixture Density(q, meanvec, sdvec, probvec)

Description: Returns the density at q of a normal mixture distribution with group means meanvec, group standard deviations sdvec, and group probabilities probvec. Here meanvec, sdvec, and probvec are all vectors of the same size.

JMP Version Added: Before version 14

mu1 = -2;
mu2 = 2;
sigma1 = 1;
sigma2 = 4;
p1 = .5;
t1 = mu1 |/ mu2;
t2 = sigma1 |/ sigma2;
t3 = p1 |/ (1 - p1);
New Window( "Univariate Normal Mixture Density",
    clty = Graph Box(
        Y Scale( 0, 0.4 ),
        X Scale( -8, 8 ),
        Pen Color( "red" ),
        Pen Size( 2 );
        t1 = mu1 |/ mu2;
        t2 = sigma1 |/ sigma2;
        t3 = p1 |/ (1 - p1);
        Y Function(
            Normal Mixture Density( y, mu1 |/ mu2, sigma1 |/ sigma2, p1 |/ (1 - p1) ),
            y
        );
        Text( {-7, .37}, "Mean1=", Round( mu1, 2 ) );
        Text( {-2, .37}, "Mean2=", Round( mu2, 2 ) );
        Text( {-7, .34}, "SD1=", Round( sigma1, 2 ) );
        Text( {-2, .34}, "SD2=", Round( sigma2, 2 ) );
        Text( {-7, .31}, "P1=", Round( p1, 2 ) );
        Text( {-2, .31}, "P2=", Round( 1 - p1, 2 ) );
    ),
    H List Box( Slider Box( -3, 3, mu1, clty << reshow ), Text Box( " Mean 1" ) ),
    H List Box( Slider Box( -3, 3, mu2, clty << reshow ), Text Box( " Mean 2" ) ),
    H List Box( Slider Box( .1, 9, sigma1, clty << reshow ), Text Box( " Std Dev 1" ) ),
    H List Box( Slider Box( .1, 9, sigma2, clty << reshow ), Text Box( " Std Dev 2" ) ),
    H List Box( Slider Box( 0, 1, p1, clty << reshow ), Text Box( " P 1" ) ), 

);

Normal Mixture Distribution

Syntax: y = Normal Mixture Distribution(q, meanvec, sdvec, probvec)

Description: Returns the probability that a normal mixture distributed variable with group means meanvec, group standard deviations sdvec, and group probabilities probvec is less than q. Here meanvec, sdvec, and probvec are all vectors of the same size.

JMP Version Added: Before version 14

mu1 = -2;
mu2 = 2;
sigma1 = 1;
sigma2 = 4;
p1 = .5;
New Window( "Univariate Normal Mixture Distribution",
    clty = Graph Box(
        Y Scale( 0, 1.05 ),
        X Scale( -8, 8 ),
        Pen Color( "red" ),
        Pen Size( 2 );
        Y Function(
            Normal Mixture Distribution( y, mu1 |/ mu2, sigma1 |/ sigma2, p1 |/ (1 - p1) ),
            y
        );
        Text( {-7, .95}, "Mean1=", Round( mu1, 2 ) );
        Text( {-2, .95}, "Mean2=", Round( mu2, 2 ) );
        Text( {-7, .85}, "SD1=", Round( sigma1, 2 ) );
        Text( {-2, .85}, "SD2=", Round( sigma2, 2 ) );
        Text( {-7, .75}, "P1=", Round( p1, 2 ) );
        Text( {-2, .75}, "P2=", Round( 1 - p1, 2 ) );
    ),
    H List Box( Slider Box( -3, 3, mu1, clty << reshow ), Text Box( " Mean 1" ) ),
    H List Box( Slider Box( -3, 3, mu2, clty << reshow ), Text Box( " Mean 2" ) ),
    H List Box( Slider Box( .1, 9, sigma1, clty << reshow ), Text Box( " Std Dev 1" ) ),
    H List Box( Slider Box( .1, 9, sigma2, clty << reshow ), Text Box( " Std Dev 2" ) ),
    H List Box( Slider Box( 0, 1, p1, clty << reshow ), Text Box( " P 1" ) ), 

);

Normal Mixture Quantile

Syntax: q = Normal Mixture Quantile(p, meanvec, sdvec, probvec)

Description: Returns the quantile from a normal mixture distribution, the values for which the probability is p that a random value would be lower.

JMP Version Added: Before version 14

extqdf = 1;
extqqq = 0.5;
mu1 = -1;
mu2 = 1;
sigma1 = 1;
sigma2 = 4;
p1 = .3;
New Window( "Example: Normal Mixture Quantile",
    extqgr = Graph Box(
        Y Scale( 0, 1.05 ),
        X Scale( -5, 5 ),
        XName( "q" ),
        Pen Color( "red" );
        Pen Size( 2 );
        Y Function(
            Normal Mixture Distribution( q, mu1 |/ mu2, sigma1 |/ sigma2, p1 |/ (1 - p1) ),
            q
        );
        Pen Color( "blue" );
        V Line(
            Normal Mixture Quantile( extqqq, mu1 |/ mu2, sigma1 |/ sigma2, p1 |/ (1 - p1) ),
            0,
            1
        );
        Text( {-4.5, 0.9}, " quantile=", Round( extqqq, 2 ) );
    ),
    H List Box( Slider Box( 0.01, 0.99, extqqq, extqgr << reshow ), Text Box( " quantile" ) ),
    H List Box( Slider Box( -3, 3, mu1, extqgr << reshow ), Text Box( " Mean 1" ) ),
    H List Box( Slider Box( -3, 3, mu2, extqgr << reshow ), Text Box( " Mean 2" ) ),
    H List Box( Slider Box( .1, 9, sigma1, extqgr << reshow ), Text Box( " Std Dev 1" ) ),
    H List Box( Slider Box( .1, 9, sigma2, extqgr << reshow ), Text Box( " Std Dev 2" ) ),
    H List Box( Slider Box( 0, 1, p1, extqgr << reshow ), Text Box( " P 1" ) ), 

);

Normal Quantile

Syntax: q = Normal Quantile( p, <mu=0>, <sigma=1> ); q = Probit( p )

Description: Returns the quantile from a Normal distribution, the value for which the probability is p that a random value would be lower.

JMP Version Added: Before version 14

Normal Quantile( 0.9 );

Normal Tolerance Factor

Syntax: q = Normal Tolerance Factor( 1-alpha, p, n, <One Sided> )

Description: Computes the tolerance factor for constructing a 1-alpha confidence interval to contain proportion p of the means with sample size n from the normal distribution. There is an option to request the factor for a one-sided tolerance interval.

JMP Version Added: 19

n = 15;
New Window( "Example: Tolerance Factor()",
    tdig = Graph Box(
        Y Scale( 0, 5 ),
        X Scale( 0.05, 0.95 ),
        Yname( "Tolerance Factor" ),
        Xname( "p" ),
        Pen Color( "red" );
        Y Function( Normal Tolerance Factor( 0.95, p, n ), p );
        Text( {0.1, 4}, "n=", Round( n ) );
    ),
    H List Box( Text Box( "n" ), Slider Box( 5, 25, n, tdig << reshow ) )
);

Not

Syntax: y = !x; y = Not( x )

Description: Returns the logical NOT of x: 1 if x is zero, missing if x is missing, and 0 otherwise.

JMP Version Added: Before version 14

!(1 < 2);

Not Equal

Syntax: z = x != y != ...; z = Not Equal( x, y, ... )

Description: Returns 1 if each argument is not equal to the next argument; returns 0 otherwise.

JMP Version Added: Before version 14

1 != 2 != 1;

Notebook

Syntax: nb = Notebook( name|number )

Description: Returns a reference to the specified notebook.

JMP Version Added: 19

Nth Day Of Week in the Month

Syntax: n = Nth Day Of Week in the Month( datetime )

Description: Returns an integer that represents the number of instances of the day of the week of the datetime argument that have occurred in the month. For example, November 28, 2019 is the 4th Thursday of the month, so the function returns 4.

JMP Version Added: 16

Nth Day Of Week in the Month( Date MDY( 11, 28, 2019 ) );

Num

Syntax: y = Num( s, < <<Use Locale( use=1 ) >, < <<Restrict > )

Description: Converts s to a number using any built-in format, including date and currency formats. Returns missing if the conversion fails. The optional <<Restrict only allows conversion using integer, decimal, and scientific formats.

JMP Version Added: Before version 14

Example 1

Show( Num( "3.1e6" ), Num( "1989-10-04" ), Num( "5%" ), Num( "£23" ) );

Example 2

Show(
    Num( "3.1e6", <<Restrict ),
    Num( "1989-10-04", <<Restrict ),
    Num( "5%", <<Restrict ),
    Num( "£23", <<Restrict )
);

Num Deriv

Syntax: y = Num Deriv( f( x, ... ), <parnum>)

Description: Returns the numerical derivative of the f( x,... ) function with respect to one of its arguments. You can specify that argument as the second argument in the Num Deriv function. If no second argument is specified, the derivative is taken with respect to the function's first argument. The derivative is evaluated using numeric values specified in the f( x,... ) function expression.

JMP Version Added: Before version 14

f = Function( {x, y}, x ^ 2 + y );
Num Deriv( f( 2, 1 ) );
Num Deriv( f( 2, 1 ), 2 );

Num Deriv2

Syntax: y = Num Deriv2( f( x, ... ) )

Description: Returns the numerical second derivative of the f( x,... ) function with respect to x. The derivative is evaluated using numeric values specified in the f( x,... ) function expression.

JMP Version Added: Before version 14

f = Function( {x}, x ^ 3 );
Num Deriv2( f( 2 ) );

Number

Syntax: y = Number( x1, ... )

Description: Returns the number of non-missing arguments or values within a single matrix or list argument.

JMP Version Added: Before version 14

Eval List( {Number( 12, ., 11, 0, -42 ), Number( [33 . -42 . 0 . -30] )} );

Number Col Box

Syntax: y = Number Col Box( title, numbers )

Description: Returns a display box to show the numbers specified by the numbers argument, which can be a list or matrix.

JMP Version Added: Before version 14

New Window( "Example",
    Outline Box( "Table",
        Table Box(
            String Col Box( "names", {"x", "y", "z"} ),
            Number Col Box( "values", {11, 22, 33} ),
            Plot Col Box( "values", {11, 22, 33} )
        )
    )
);

Number Col Edit Box

Syntax: y = Number Col Edit Box( title, numbers )

Description: Returns a display box to show the numbers specified by the numbers argument, which can be a list or matrix.

JMP Version Added: Before version 14

x = y = z = 0;
New Window( "Example",
    Modal,
    <<Return Result,
    Outline Box( "Table", Table Box( neb = Number Col Edit Box( "values", {x, y, z} ) ) )
);

Number Edit Box

Syntax: y = Number Edit Box( initValue, <width> )

Description: Returns an edit box that accepts only numeric input. Specify the optional width argument to set the width of the box in characters.

JMP Version Added: Before version 14

New Window( "Example", neb = Number Edit Box( 5 ) );
x = neb << get;

Number of Periods

Syntax: x = Number of Periods( rate, pmt, pv, <fv=0>, <type=0> )

Description: Returns the number of periods for an investment based on periodic, constant payments and a constant interest rate. The type argument is 0 for end-of-period payments and 1 for beginning-of-period payments. Equivalent to the NPER function in Microsoft Excel.

JMP Version Added: Before version 14

Number of Periods( .05 / 12, -2000, 100000 );

Open

Syntax: Open( filePath, <data table options | Excel import options | text import options | SAS import options | HTML import options | esriShapeFile import options | PDF import options | other file options > )

Description: Returns a reference to a data table or other JMP file or object created from a file. If no path is specified, the Open dialog appears. If a folder path is specified, the system file browser is opened and no object is returned. Refer to the Syntax Reference for a complete description of available options.

JMP Version Added: Before version 14

Add-In

/* Installing Add-In:
Open( Add-In to open,
    <Check For Updates( "never" | "startup" | "always")>, // "always" will check for updates at startup and while jmp is running
    <Update Prompt(0|1)>) // whether or not the add-in will silently update or prompt first */
Open( "$downloads\test.jmpaddin", Check For Updates( "always" ), Update Prompt( 1 ) );

Data Table

/* Data tables, other JMP files, external files:
   Open( filePath,
     <Invisible | Private>,
     <Select Columns( "col", ... )>,
     <Ignore Columns( "col", ... )>,
     <Add to Recent Files(bool)>,
     <Quarantine Action("Allow Scripts"|"Block Scripts"|"Do Not Open"|"Show Dialog")>
     <Force Refresh>,
     <Enable Filter Views(bool)>,
     <"file type">
   )
*/
//Basic data table open
dt1 = Open( "$SAMPLE_DATA/Big Class.jmp" );
//Data table open with some options
dt2 = Open( "$SAMPLE_DATA/Fitness.jmp", Select Columns( "Name", "Sex", "Age", "Weight" ) );

Excel

/* Excel files imported into a data table:
   Open( excelFilePath,
     <Worksheets( "sheet name" | {"sheet name", "sheet name", ...} | "n" )>,
     <Use for all sheets(0|1)>,
     <Concatenate Worksheets(0|1)>,
     <Create Concatenation Column(0|1)>,
     <Worksheet Settings( 0|1,
       Has Column Headers(0|1),
       Number of Rows in Headers(n),
       Headers Start on Row(n),
       Data Starts on Row(n),
       Data Starts on Column(n),
       Data Ends on Row(n),
       Data Ends on Column(n),
       Replicated Spanned Rows(0|1),
       Suppress Hidden Rows(0|1),
       Suppress Hidden Columns(0|1),
       Treat as Hierarchy(0|1)
     )>,
     <Invisible | Private>
   )
*/

/* Using the Excel Wizard dialog:
   Open("$SAMPLE_IMPORT_DATA/Bigclass.xlsx", "Excel Wizard");  
*/

dt = Open(
    "$SAMPLE_IMPORT_DATA/Team Results.xlsx",
    Worksheets( "Ungrouped Team Results" ),
    Worksheet Settings( Headers Start on Row( 3 ), Data Starts on Row( 4 ) )
);

Folder

/* Open of folder launches file browser */
Open( "$SAMPLE_DATA" );

Other

/* Other options:
   SAS File imported as a data table:
   Open( sasFilePath,
     <Invisible | Private>,
     <Use Labels for Var Names(0|1)>,
     <Password( "password" )>
   )

   SAS Transport File imported as a data table, members are separate tables within the larger file:
   Open( sasTransportFilePath,
     <Use Labels for Var Names(0|1)>,
     <Members({"Table1", "Table2"})>
   )

   HTML file imported as a data table:
   Open( htmlFilePath,
     <Invisible | Private>,
     <HTML Table(n, <ColumnNames(n)>, DataStarts(n)>)>
   )

   Get column names as a list for a JMP Data Table without opening the table:
   Open( jmpDataTableFilePath, 
     "Column Names Only"
   )

   esriShapeFile opened for use as a map shape data table:
   Open( esriShapeFilePath,
     <Invisible | Private>,
     Columns( Shape=numeric(n),
     Part=numeric(n),
     X=numeric(n),
     Y=numeric(n) ),
              Polygon Import Options(Simplification Factor(f), Geodesic(g))
   )
*/
//SAS Example:
dt1 = Open( "$SAMPLE_IMPORT_DATA/Bigclass.sas7bdat", Use Labels for Var Names( 1 ) );

// HTML Example:
dt2 = Open(
    "https://en.wikipedia.org/wiki/Black_Mountains_(North_Carolina)",
    HTML Table( 3, Column Names( 1 ), Data Starts( 2 ) )
);

// Column Names Only Example: 
colNames = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp", "Column Names Only" );

// SHP Shapefile Example with polygon simplification: 
Open(
    "$SAMPLE_IMPORT_DATA/parishes.shp",
    Polygon Import Options( Simplification Factor( 200 ), Geodesic( 1 ) )
);

PDF

/* PDF file imported as one or multiple data tables
open(pdfFilePath,
    PDF Tables(Table(<Name(name)>, Add Rows(Page(n | {page list}), <Header Rows(n)>, Rect(top, left, right, bottom), <RowBorders(n, ...)>, <Column Borders(n, ....)>), ...)) |
    PDF All Tables(< Combine(All | Matching Headers | None)>, <Minimum Rows(n)>, <Minimum Columns(n)>) |
    PDF Text(<Pages(n, ...)>, <sort>) |
    PDF Wizard
);*/
dt = Open( "$SAMPLE_DATA\big class.jmp" );
w = New Window( "test", Data Table Box( dt ) );
w << save picture( "$DOCUMENTS\test.pdf", pdf );
pdftable = Open( "$DOCUMENTS\test.pdf", PDF All Tables( Combine( all ) ) ); // just some of the rows
pdftable2 = Open(
    "$DOCUMENTS\test.pdf",
    PDF Tables( Table( Table Name( "test" ), Add Rows( Page( 1 ), Rect( 0, 0, 5, 3 ) ) ) )
);

Picture

/* Picture file imported as a picture object */
pic = Open( "$SAMPLE_IMAGES/tile.jpg", jpg );
New Window( "Picture", Outline Box( "Picture", Picture Box( pic ) ) );

Text

/* Text files imported into a data table:
   Open( textFilePath,
     <Invisible | Private>,
     CharSet("option") // "Best Guess", "utf-8", "utf-16", "us-ascii", "windows-1252", "x-max-roman", "x-mac-japanese", "shift-jis", "euc-jp", "utf-16be", "gb2312"
     <Number of Columns(n)>,
     <Columns(colName=colType(colWidth),... )>,// colType is Character|Numeric and colWidth is an integer specifying the width of the column
     <End Of Field (Tab|Space|Comma|Semicolon|Other|None)>,
     <EOF Other ("char")>,
     <End Of Line (CRLF|CR|LF|Semicolon|Other)>,
     <EOL Other ("char")>,
     <Strip Quotes|Strip Enclosing Quotes (0|1)>,
     <Labels|Table Contains Column Headers (0|1)>,
     <Year Rule|Two digit year rule ("decade start")>, // For example, if the earliest date is 1979, use "1970". If the earliest date is 2001, use "20xx".
     Treat Empty Columns as Numeric(0|1)
     Scan Whole File(0|1) // 1 means scan the whole file and 0 means scan for 5 seconds.
     <Column Names Start|Column Names are on line (n)>,
     <Data Starts|Data starts on line (n)>,
     <Lines to Read>, // a number
     <Use Apostrophe as Quotation Mark>,
     <CompressNumericColumns(0|1)>,
     <CompressCharacterColumns(0|1)>,
     <CompressAllowListCheck(0|1)>
   )
*/
dt = Open( "$SAMPLE_IMPORT_DATA/EOF_comma.txt", Table Contains Column Headers( 0 ) );

Open Database

Syntax: dt = Open Database( dataSourceName|"Connect Dialog", "SELECT ..."|"SQLFILE=..."|tableName, <invisible | private>, <outputTableName> )

Description: Opens a database using ODBC, runs the given SQL, and puts data into a data table with the given output table name.

JMP Version Added: Before version 14

Open Database(
    "DSN=dBASE Files;DBQ=C:/Program Files/JMP/JMPPRO/19/Samples/Import Data/;",
    "SELECT HEIGHT, WEIGHT FROM Bigclass",
    "hw"
);

Open Datafeed

Syntax: y = Open Datafeed( ... )

Description: Creates an object and window you can send messages to manage real-time data feeds.

JMP Version Added: Before version 14

exfeed = Open Datafeed(/*Connect( Port( "com3" ), Baud( 4800 ), DataBits( 8 ) ),*/
    Set Script(
        ex = exfeed << getLine;
        Show( ex );
    )
);
For( exi = 0, exi < 5, exi++, /* this is just a way to test a feed when the real data source is not available...*/
    exfeed << Queue Line( Char( exi ) );
    Wait( .5 );
);

Open Help

Syntax: w = Open Help( "Help" | "Scripting Index", ... )

Description: Opens the online JMP help or the Scripting Index.

JMP Version Added: Before version 14

Example 1

Open Help( "Help" );

Example 2

Open Help(
    "Scripting Index",
    Search( Term( "Open" ), Match( {"Contains Terms", "Match All Terms", "Ignore Case"} ) ),
    IndexContext( Category( "Functions" ) )
);

Example 3

Open Help(
    "Scripting Index",
    Search( Term( "alpha" ), Match( {"Contains Terms", "Match All Terms", "Ignore Case"} ) ),
    IndexContext(
        Category( "All Categories" ),
        Object( "Search results" ),
        Method( "Get Alpha" )
    )
);

Open Log

Syntax: Open Log( <bring window to top> )

Description: Open the log window

JMP Version Added: Before version 14

Example 1

Open Log();
Show( Is Log Open() );

Example 2

/* Bring Log Windows to the Top */
Open Log( 1 );
Show( Is Log Open() );

Or

Syntax: y = x1 | x2; y = Or( x1, x2, ... )

Description: Returns the logical OR of all arguments: 1 if any arguments are nonzero and 0 otherwise.

JMP Version Added: Before version 14

1 < 2 | 3 < 2;

OrMZ

Syntax: y = OrMZ( x1, x2, ... )

Description: Returns the logical OR of all arguments with missing values treated as zeros: 1 if any arguments are nonzero and 0 otherwise.

JMP Version Added: Before version 14

OrMZ( 1 < 2, 3 < 2 );

Ortho

Syntax: L = Ortho( A, <Centered( 0 )>, <Scaled( 1 )> )

Description: Orthogonalizes the columns of a matrix. Center option makes them sum to zero. Scale option makes them unit length.

JMP Version Added: Before version 14

Ortho( [1 1, 1 -1] );

Ortho Poly

Syntax: L = Ortho Poly( V, order )

Description: Returns orthogonal polynomials of vector V up to order specified by the order argument. The V argument can be a row or column vector. Scale option makes them unit length.

JMP Version Added: Before version 14

Ortho Poly( 1 :: 10, 2 );

Outline Box

Syntax: y = Outline Box( title, <command script pairs list>, displayBox, ... )

Description: Creates an outline element in the report, returning the display box reference. To include a menu in the outline node, specify the command script pairs list, a list specifying menu commands and associated scripts.

JMP Version Added: Before version 14

New Window( "Example",
    Outline Box( "Picker",
        {"Show label value", Show( teb << get text )},
        H List Box( Text Box( "Label:" ), teb = Text Edit Box( Char( 213 ) ) )
    )
);

Oval

Syntax: Oval( left, top, right, bottom, <fill=0> )

Description: Draws an oval within the specified rectangle, filled if fill is nonzero.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Pen Color( "Green" );
        Pen Size( 2 );
        Fill Color( "Red" );
        Oval( 15, 75, 65, 55, 1 );
        Oval( 10, 80, 70, 50 );
    )
);

P Spline Coef

Syntax: coef = P Spline Coef( x, Internal Knot Grid, <degree = 3>, <KnotEndPoints = min(x) || max(x)> )

Description: Returns the matrix of P-Spline coefficients. Internal Knot Grid is either the number of desired knot points based on percentiles of x or a vector specifying the internal knot points. Optional parameter degree specifies the degree of the P-splines with a default of 3.

JMP Version Added: 14

P Spline Coef( [0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10], 2 );
P Spline Coef( [0, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10], [3, 7] );

Page Break Box

Syntax: Page Break Box()

Description: Creates a display box that forces a page break.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Frame Size( 300, 300 ),
        Marker( Marker State( 3 ), [11 44 77], [75 25 50] );
        Pen Color( "Blue" );
        Line( [10 30 70], [88 22 44] );
    ),
    Page Break Box(),
    Graph Box(
        Frame Size( 300, 300 ),
        Marker( Marker State( 3 ), [77 44 11], [75 25 50] );
        Pen Color( "Red" );
        Line( [70 30 10], [88 22 44] );
    )
);

Panel Box

Syntax: y = Panel Box( title, displayBoxArgs )

Description: Returns a display box to label and enclose the argument display box.

JMP Version Added: Before version 14

New Window( "Example",
    Tab Box(
        "alpha",
        Panel Box( "panel", Text Box( "text" ) ),
        "beta",
        Popup Box( {"x", ex = 1, "y", ex = 2} )
    )
);

Parallel Assign

Syntax: tf = ParallelAssign( { thread_local_var = global_var, ... }, m[ a, b ] = expression using a and b )

Description: Use multiple threads to assign values to the matrix. If any thread throws an exception, a message will be printed to the log and the return value will be 0. If all threads complete without error, the return value will be 1. Functions that launch platforms, create or use data tables, or access the graphics subsystem are only supported on the main thread, and will throw an exception if called from a worker thread.

JMP Version Added: Before version 14

m = J( 3, 2, -1 );
If( Parallel Assign( {/*no locals */ }, m[a/* 1,2,3 */, b/* 1,2 */ ] = a * a + b ) == 0,
    Throw( "thread failed" )
);
m;/* 1*1+1  1*1+2, 2*2+1  2*2+2, 3*3+1  3*3+2 */

Parameter

Syntax: y = Parameter( {name=value, ...}, model expression )

Description: Defines formula parameters for models for the Nonlinear platform.

JMP Version Added: Before version 14

Parameter( {a = 1}, a + 1 );

Parse

Syntax: y = Parse( s )

Description: Parses the string and returns the resulting JSL expression.

JMP Version Added: Before version 14

Parse( "x+y" );

Parse Date

Syntax: dt = In Format( s, formatString, < <<Use Locale(b=1)>, < <<Restrict > )dt = In Format( s, "Format Pattern", pattern, < <<Use Locale(b=1)> )

Description: Parses a string of a given format. If the format is a date-time format, the value is expressed as if surrounded by As Date(), returning the date in ddMonyyyy format. The optional <<Restrict used with the "Best" formatString only allows conversion using integer, decimal, and scientific formats.

JMP Version Added: Before version 14

Example 1

Informat( "07152000", "MMDDYYYY" );

Example 2

Informat( "07.15.2000", "Format Pattern", "<MM>.<DD>.<YYYY>" );

Example 3

Informat( "86.8287° W", "Longitude DDD" );

Example 4

Informat( "123.45%", "Percent" );

Example 5

Show(
    Informat( "1.23e4", "Best" ),
    Informat( "1.23e4", "Best", <<Restrict ),
    Informat( "1989-10-04", "Best" ),
    Informat( "1989-10-04", "Best", <<Restrict )
);

Parse JSON

Syntax: l = Parse JSON( jsonstring )

Description: Convert JSON text to a JSL list or associative array representing the structure specified by the JSON data.

JMP Version Added: 14

l = Parse JSON(
    "[ { \!"name\!": \!"KATIE\!", \!"age\!": 12, \!"sex\!": \!"F\!", \!"height\!": 59, \!"weight\!": 95 }, { \!"name\!": \!"LOUISE\!", \!"age\!": 12, \!"sex\!": \!"F\!", \!"height\!": 61, \!"weight\!": 123 }, { \!"name\!": \!"JANE\!", \!"age\!": 12, \!"sex\!": \!"F\!", \!"height\!": 55, \!"weight\!": 74 } ]"
);
Show( l );

Parse XML

Syntax: Parse XML( string, OnElement( tagname, StartTag( expr ), EndTag( expr ) ), ... )

Description: Parses an XML expression using the OnElement expressions for specified XML tags.

JMP Version Added: Before version 14

Example 1

/*See example two for more details*/
ex =
"<table name='fromxml'><col name='x'>[1 2 3]</col><col name='y'>[11 22 33]</col></table>";
Parse XML( ex,
    On Element( "table", Start Tag( New Table( XML Attr( "name" ) ) ) ),
    On Element(
        "col",
        End Tag( New Column( XML Attr( "name" ), Set Values( Parse( XML Text() ) ) ) )
    )
);

Example 2

doc =
"
<a title='one'>
    WWWa
    <b>BB<c>ZZZ</c>B1</b>
    XXXa
    <b>BBB2</b>
    YYYa
    <c>CCC</c>
</a>";
// doc, above, has tags a, b, and c. The c tags are not handled by the parser, below,
// to show why text should be collected by Text(...) and then processed by EndTag(...)
// Text(...) captures the BB ZZZ B1 while using EndTag(...) only captures the final snippet.
docname = "undefined";
doctext = "";
recordtext = "";
records = {};
NestLevel = 0; // not really used here, but shows how to use Start/End Tag to track nesting level
Parse XML( doc,
    On Element(
        "a",
        Start Tag(
            docname = XML Attr( "title" );
            NestLevel++;
        ), 
        // decide here to trim the CRLF and blanks and use a single blank
        Text( doctext = doctext || Trim( XML Text() ) || " " ),
        End Tag( NestLevel-- )
    ),
    On Element(
        "b",
        Start Tag( NestLevel++ ), 
        // comment out the next line and...
        Text( recordtext = recordtext || Trim( XML Text() ) || " " ),
        End Tag(
            // ...uncomment the next line and observe the "B1" vs "BB ZZZ B1 " value in records
            // recordtext = XMLText();
            Insert Into( records, recordtext );
            recordtext = "";
            NestLevel--;
        )
    )
);

Show( docname, doctext, records, NestLevel );

Pat Abort

Syntax: Pat Abort()

Description: Generates a pattern value that causes the entire match to fail immediately with no further backup and retry.

JMP Version Added: Before version 14

source = "xxxxx";
n = 0;
pattern = Pat Succeed() + Pat Arb() >> xs + Expr(
    Show( xs );
    n = n + 1;
    If( n > 16,
        Pat Abort(),
        Pat Fail()
    );
);
rc = Pat Match( source, pattern, NULL, FULLSCAN );

Pat Altern

Syntax: Pat Altern( pat1, pat2, ... )

Description: Generates a pattern value that matches any one of the supplied patterns. Generally written as pat1 | pat2 | ....

JMP Version Added: Before version 14

Pat Match(
    "123456789",
    ((Pat Pos( 2 ) + "1") | (Pat Pos( 1 ) + "2") | (Pat Pos( 0 ) + "3")) >> result
);
result;

Pat Any

Syntax: Pat Any( string )

Description: Generates a pattern value that will match any one character in the string.

JMP Version Added: Before version 14

operators = Pat Any( "*+-/" );
text = "abc+def";
Pat Match( text, operators >> op );
op;

Pat Arb

Syntax: Pat Arb( pattern )

Description: Generates a pattern value that matches zero or more characters.

JMP Version Added: Before version 14

Pat Match(
    "123nonnumeric456",
    Pat Span( "0123456789" ) + Pat Arb() >> result + Pat Span( "0123456789" )
);
result;

Pat Arb No

Syntax: Pat Arb No( pattern )

Description: Generates a pattern value that matches its argument zero or more times. Same as patRepeat(pattern,0,infinity,RELUCTANT); (*? in regex).

JMP Version Added: Before version 14

Pat Match(
    "xyz aaaaabbbbbb@ccc no c is matched because reluctant",
    Pat Arb No( "a" ) >> a + Pat Arb No( "b" ) >> b + "@" + Pat Arb No( "c" ) >> c
);
" a=" || a || " b=" || b || " c=" || c;

Pat At

Syntax: Pat At( variable )

Description: Generates a pattern value that matches zero characters and assigns the current cursor position to variable. Generally written as patpos()>>variable.

JMP Version Added: Before version 14

Pat Match( "123456789", Pat Len( 2 ) + Pat At( result ) );
result;

Pat Break

Syntax: Pat Break( string )

Description: Generates a pattern value that matches zero or more characters not in the string, stopping before a (required) character in the string.

JMP Version Added: Before version 14

b = "- ";
Pat Match( "one two three-", Pat Repeat( Pat Break( b ) >> word + Pat Any( b ) ) );
word;

Pat Concat

Syntax: Pat Concat( pat1, pat2, ... )

Description: Generates a pattern value that matches each of the supplied patterns in turn. Generally written as pat1 + pat2 + ....

JMP Version Added: Before version 14

num = Pat Break( "," );
sep = ",";
Pat Match( "1.3,7.9,8.66", num + sep + num >> result + sep + num );
result;

Pat Conditional

Syntax: Pat Conditional( pattern, variable )

Description: Generates a pattern value that matches the supplied pattern and stores the matched text in variable on success. Generally written as pattern >? variable.

JMP Version Added: Before version 14

a = "unchanged";
b = "unchanged";
Pat Match( "123456789", (Pat Len( 2 ) >? a | Pat Len( 1 ) >? b) + "2" );
" a=" || a || " b=" || b;

Pat Fail

Syntax: Pat Fail()

Description: Generates a pattern value that always fails to match going forward, forcing the matcher to retry alternatives.

JMP Version Added: Before version 14

source = "xxxxx";
n = 0;
pattern = Pat Succeed() + Pat Arb() >> xs + Expr(
    Show( xs );
    n = n + 1;
    If( n > 16,
        Pat Abort(),
        Pat Fail()
    );
);
rc = Pat Match( source, pattern, NULL, FULLSCAN );

Pat Fence

Syntax: Pat Fence()

Description: Generates a pattern value that matches zero characters going forwards and fails when backing up, causing the match to fail. Also used to trim down the pattern backup stack.

JMP Version Added: Before version 14

rc = Pat Match( "123456789", (Pat Len( 1 ) | Pat Len( 2 )) >> result + Pat Fence() + "3" );
"rc=" || Char( rc ) || " result=" || result;

Pat Immediate

Syntax: Pat Immediate( pattern, variable )

Description: Generates a pattern value that matches the supplied pattern and immediately stores the matched text in variable. Generally written as pattern >> variable.

JMP Version Added: Before version 14

a = "unchanged";
b = "unchanged";
Pat Match( "123456789", (Pat Len( 2 ) >> a | Pat Len( 1 ) >> b) + "2" );
" a=" || a || " b=" || b;

Pat Len

Syntax: Pat Len( n )

Description: Generates a pattern value that matches n characters.

JMP Version Added: Before version 14

Pat Match( "123456789", Pat Len( 2 ) + Pat Len( 3 ) >> result );
result;

Pat Look Ahead

Syntax: Pat Look Ahead( pattern, <0|1> )

Description: A zero width pattern match after the current position. The second optional argument defaults to 0. 1 designates a negative match, or a non-match.

JMP Version Added: Before version 14

Example 1

Test = "These are Bob's sons' nails.";
While( /* repeat the match until it fails */Pat Match(
        Test,
        "s" + Pat Look Ahead( "'" ),
        "z"
    ), /* find an s that IS followed by an apostrophe and replace it with z */
    Print( test )
);

Example 2

Test = "These are Bob's sons' nails.";
While( /* repeat the match until it fails */Pat Match(
        Test,
        "s" + Pat Look Ahead( "'", 1 ),
        "z"
    ), /* find an s that is NOT followed by an apostrophe and replace it with z */
    Print( test )
);

Example 3

Test = "a bb ccc dddd";
While( /* keep repeating the match until it won't match */
    Pat Match(
        Test,
        Pat Len( 1 ) >> xxx/* find any character */
        + Pat Look Behind( Expr( xxx ) + Expr( xxx ) ) /* back up 2 positions, which includes the character just found */
        + Pat Look Ahead( Expr( xxx ) /* and look ahead one position */ ),
        "@" /* replacement for the middle character of a triple */
    ),
    Print( test ) /* show each intermediate result */
);

Pat Look Behind

Syntax: Pat Look Behind( pattern, <0|1> )

Description: A zero width pattern match before the current position. The second optional argument defaults to 0. 1 designates a negative match, or a non-match.

JMP Version Added: Before version 14

Example 1

Test = "These are Bob's sons' nails.";
While( /* repeat the match until it fails */Pat Match(
        Test,
        Pat Look Behind( "'" ) + "s",
        "z"
    ), /* find an s that IS preceded by an apostrophe and replace it with z */Print( test )
);

Example 2

Test = "These are Bob's sons' nails.";
While( /* repeat the match until it fails */Pat Match(
        Test,
        Pat Look Behind( "'", 1 ) + "s",
        "z"
    ), /* find an s that is NOT preceded by an apostrophe and replace it with a z */
    Print( test )
);

Example 3

Test = "a bb ccc dddd";
While( /* keep repeating the match until it won't match */
    Pat Match(
        Test,
        Pat Len( 1 ) >> xxx/* find any character */
        + Pat Look Behind( Expr( xxx ) + Expr( xxx ) ) /* back up 2 positions, which includes the character just found */
        + Pat Look Ahead( Expr( xxx ) /* and look ahead one position */ ),
        "@" /* replacement for the middle character of a triple */
    ),
    Print( test ) /* show each intermediate result */
);

Pat Match

Syntax: Pat Match( source, pattern, <replacement> )

Description: Executes the pattern match in the pattern variable against the string in the source variable; optional replacement text replaces the matched text.

JMP Version Added: Before version 14

string = "John Smith";
Pat Match(
    string,
    Pat Break( " " ) >> first + Pat Span( " " ) + Pat Rem() >> last,
    last || ", " || first
);
string;

Pat Not Any

Syntax: Pat Not Any( string )

Description: Generates a pattern value that will match any one character not in the string.

JMP Version Added: Before version 14

delimiter = ";,-";
text = "fish,dog,cat,";
Pat Match( text, Pat Repeat( Pat Not Any( delimiter ) ) >> word + Pat Any( delimiter ) );
word;

Pat Pos

Syntax: Pat Pos( n )

Description: Generates a pattern value that matches zero characters if the cursor is at position n. With no argument, the Pat Pos() function returns the cursor position for >> or >? assignment: patpos()>>variable.

JMP Version Added: Before version 14

Pat Match(
    "ab3defghi",
    Pat Pos( 2 ) + Pat Len( 1 ) >> v/*v=3*/+ Expr( Pat Len( v ) )
    +Pat Pos( /* no argument returns current position = 6 */ ) >> result
);
result;

Pat R Pos

Syntax: Pat R Pos( n )

Description: Generates a pattern value that matches zero characters if the cursor is n characters from the end.

JMP Version Added: Before version 14

Pat Match( "quick brown fox", Pat R Pos( 3 ) + Pat Rem() >> result );
result;

Pat R Tab

Syntax: Pat R Tab( n )

Description: Generates a pattern value that matches zero or more characters to move the cursor forward to n characters before the end.

JMP Version Added: Before version 14

Pat Match( "123456789", "23" + Pat R Tab( 2 ) >> result );
result;

Pat Regex

Syntax: Pat Regex( string )

Description: Generates a pattern value that matches the regular expression in the string.

JMP Version Added: Before version 14

string = "John Smith";
Regex Match( string, Pat Regex( "([^ ]+)([ ]+)([^ ]+)" ), "\3, \1" );
string;

Pat Rem

Syntax: Pat Rem()

Description: Generates a pattern value that matches the remainder of the text.

JMP Version Added: Before version 14

Pat Match( "the quick fox", Pat R Pos( 3 ) + Pat Rem() >> result );
result;

Pat Repeat

Syntax: Pat Repeat( pattern, <min=1>, <max=infinity>, <GREEDY or RELUCTANT=GREEDY> )

Description: Generates a pattern value that matches the supplied pattern between min and max times.

JMP Version Added: Before version 14

Pat Match(
    "xyz aaaaabbbbbbccc 3 c is matched because greedy",
    Pat Repeat( "a" ) >> a + Pat Repeat( "b" ) >> b + Pat Repeat( "c" ) >> c
);
" a=" || a || " b=" || b || " c=" || c;

Pat Span

Syntax: Pat Span( string )

Description: Generates a pattern value that matches one or more characters in the string.

JMP Version Added: Before version 14

sp = Pat Span( "0123456789.-" );
Pat Match( "junk=-33.44e33", sp >> result );
result;

Pat String

Syntax: Pat String( string )

Description: Generates a pattern value that matches the string. Generally the string can be used without using the Pat String() function.

JMP Version Added: Before version 14

x = Pat String( "a" || "b" );
Pat Match(
    "acbdbababc",
    Pat Arb() >> before + Pat Repeat( x ) >> match + Pat Rem() >> after
);
"before=" || before || " match=" || match || " after=" || after;

Pat Succeed

Syntax: Pat Succeed()

Description: Generates a pattern value that always matches zero characters, even when backing up.

JMP Version Added: Before version 14

source = "xxxxx";
n = 0;
pattern = Pat Succeed() + Pat Arb() >> xs + Expr(
    Show( xs );
    n = n + 1;
    If( n > 16,
        Pat Abort(),
        Pat Fail()
    );
);
rc = Pat Match( source, pattern, NULL, FULLSCAN );

Pat Tab

Syntax: Pat Tab( n )

Description: Generates a pattern value that matches zero or more characters to move the cursor forward to position n.

JMP Version Added: Before version 14

Pat Match( "123456789", "23" + Pat Tab( 6 ) >> result );
result;

Pat Test

Syntax: Pat Test( expression )

Description: Generates a pattern value that matches zero characters if the expression is nonzero. The expression is re-evaluated during each test, as if Expr() was used.

JMP Version Added: Before version 14

nCats = 0;
whichCat = 3;
string = "catch a catnapping cat in a catsup factory";
rc = Pat Match(
    string,
    "cat" + Pat Test(
        nCats = nCats + 1;
        nCats == whichCat;
    ),
    "dog"
);
string;

Path

Syntax: Path( pathMatrix|pathText, <fill=0> )

Description: Draws a stroke along the given path if fill is 0, or paints the interior of the given path if fill is not 0. The path can be specified with an N x 3 matrix or with a text representation. A path matrix has three columns for x, y, and flags for each point in the path. The flag values are 0 for control, 1 for move, 2 for line segment, 3 for cubic Bézier segment, and are negative if the point also closes the path. Path text supports SVG syntax.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Fill Color( "blue" );
        Path( [10 10 1, 10 70 0, 70 70 0, 70 10 -3], 1 );
        Path( "M20,20 C20,60 60,60 60,20 Z", 0 );
    )
);

Path To Char

Syntax: s = Path To Char( pathMatrix )

Description: Converts a path specification from matrix form to character form.

JMP Version Added: Before version 14

Path To Char( [10 10 1, 10 70 0, 70 70 0, 70 10 -3] );

Payment

Syntax: x = Payment( rate, nper, pv, <fv=0>, <type=0> )

Description: Returns the payment for a loan based on constant payments and a constant interest rate. The type argument is 0 for end-of-period payments and 1 for beginning-of-period payments. Equivalent to the PMT function in Microsoft Excel.

JMP Version Added: Before version 14

Payment( .05 / 12, 30 * 12, 100000 ) - Interest Payment( .05 / 12, 13, 30 * 12, 100000 )
-Principal Payment( .05 / 12, 13, 30 * 12, 100000 );

Pdf Page Count

Syntax: Pdf Page Count( file name)

Description: Returns the number of pages in a PDF file.

JMP Version Added: Before version 14

pageCount = Pdf Page Count( "$documents\myfile.pdf" );

Pen Color

Syntax: Pen Color( <name|index|rgbList> )

Description: Sets the color for drawing lines.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Pen Color( {.3, .5, .7} );
        Circle( {20, 20}, 10 );
    )
);

Pen Size

Syntax: Pen Size( <x> )

Description: Sets the pen size in pixels for drawing lines.

JMP Version Added: Before version 14

New Window( "Example",
    Graph Box(
        Pen Size( 4 );
        Line( [10 30 90], [88 22 44] );
    )
);

Pi

Syntax: y = Pi()

Description: Returns the mathematical constant π, accurate to approximately 15 decimal digits: 3.1415926535....

JMP Version Added: Before version 14

Char( Pi(), 5 );

Pick Color

Syntax: color = Pick Color( <window title>, <name|index|rgbList> )

Description: Returns a color that was selected with the standard color picker.

JMP Version Added: 14

pickedColor = Pick Color( "Pick a Line Color", "Red" );
New Window( "Example",
    Graph Box(
        Frame Size( 300, 300 ),
        Marker( Marker State( 3 ), [11 44 77], [75 25 50] );
        Pen Color( pickedColor );
        Line( [10 30 70], [88 22 44] );
    )
);

Pick Color Theme

Syntax: theme = Pick Color Theme( <window title>, <Color Theme(name|specification)>, <Type("Continuous" | "Sequential" | "Bad to Good" | "Categorical")>)

Description: Returns a color theme that was selected with the standard color theme picker. The initial theme can be specified explicitly or by specifying a Type to use the themes from preferences.

JMP Version Added: 17

Graph Builder

theme = Pick Color Theme( "Choose a color theme", Type( "Bad to Good" ) );
dt = Open( "$SAMPLE_DATA/SATByYear.jmp" );
gb = dt << Graph Builder(
    Show Control Panel( 0 ),
    Variables( Color( :SAT Math ), Shape( :State ) ),
    Elements( Map Shapes( Legend( 2 ) ) )
);
server = gb << Get Legend Server;
item = server << Get Legend Item( 2, 1 );
item << Set Properties( {Gradient( {Color Theme( theme )} )} );

Row Legend

pickedTheme = Pick Color Theme( "Pick a Color Theme" );
biv = Open( "$SAMPLE_DATA/Big Class.jmp" ) << Run Script( "Bivariate" );
Report( biv )[FrameBox( 1 )] << Row Legend( "age", Color Theme( pickedTheme ) );

Pick Directory

Syntax: path = Pick Directory( <prompt>, <path>, <Show Files( boolean )> )

Description: Prompts the user with an Open Directory window, returning the pathname of the chosen directory. The optional prompt string is shown at the top of the window. Show Files can be any of the three arguments, and takes a Boolean argument. 1 shows files in the Pick Directory window, 0 does not. The default value is 0. The path string specifies the directory that the Pick Directory window initially displays. If you use the path string, it must follow the prompt string, but Show Files can be between them.

JMP Version Added: Before version 14

Show Files

Pick Directory( "Select a directory", "$DOCUMENTS", Show Files( 1 ) );

Simple

Pick Directory( "Select a directory" );

Pick File

Syntax: path = Pick File( <prompt>, <initial directory>, <filterList>, <first filter>, <saveFlag=0|1>, <default file>, <multiple> )

Description: Prompts the user with an Open window, returning the pathname of the chosen file. The filterList argument is a list of strings of the form: "Label|suffix1;suffix2;...". The first filter argument specifies which filter is initially shown. The fifth argument indicates whether the window should function as a save (saveFlag = 1) or open (saveFlag = 0) window. The default file argument specifies the file that is initially selected. The multiple argument allows multiple files to be selected if saveFlag is 0.

JMP Version Added: Before version 14